typecheck.scm

   1 (load "ast.scm")
   2
   3 (define (abs? t)
   4   (and (list? t) (eq? (car t) 'abs)))
   5
   6 (define (tvar? t)
   7   (and (not (list? t))
   8        (not (concrete? t))
   9        (symbol? t)))
  10
  11 (define (concrete? t)
  12   (and (symbol? t)
  13        (char-upper-case? (string-ref (symbol->string t) 0))))
  14
  15 (define (pretty-type t)
  16   (cond ((abs? t)
  17          (string-append
  18           (if (abs? (cadr t))
  19               (string-append "(" (pretty-type (cadr t)) ")")
  20               (pretty-type (cadr t)))
  21           " -> "
  22           (pretty-type (caddr t))))
  23         (else (symbol->string t))))
  24
  25 (define (pretty-constraints cs)
  26   (string-append "{"
  27                  (fold-left string-append
  28                             ""
  29                             (map (lambda (c)
  30                                    (string-append
  31                                     (pretty-type (car c))
  32                                     ": "
  33                                     (pretty-type (cdr c))
  34                                     ", "))
  35                                  cs))
  36                  "}"))
  37
  38                                         ; ('a, ('b, 'a))
  39 (define (env-lookup env n)
  40   (if (null? env) (error #f "empty env" env n)                  ; it's a type equality
  41       (if (eq? (caar env) n)
  42           (cdar env)
  43           (env-lookup (cdr env) n))))
  44
  45 (define (env-insert env n t)
  46   (cons (cons n t) env))
  47
  48 (define abs-arg cadr)
  49
  50 (define cur-tvar 0)
  51 (define (fresh-tvar)
  52   (begin
  53     (set! cur-tvar (+ cur-tvar 1))
  54     (string->symbol
  55      (string-append "t" (number->string (- cur-tvar 1))))))
  56
  57 (define (last xs)
  58   (if (null? (cdr xs))
  59       (car xs)
  60       (last (cdr xs))))
  61
  62 (define (normalize prog) ; (+ a b) -> ((+ a) b)
  63   (case (ast-type prog)
  64     ('lambda
  65                                         ; (lambda (x y) (+ x y)) -> (lambda (x) (lambda (y) (+ x y)))
  66         (if (> (length (lambda-args prog)) 1)
  67             (list 'lambda (list (car (lambda-args prog)))
  68                   (normalize (list 'lambda (cdr (lambda-args prog)) (caddr prog))))
  69             (list 'lambda (lambda-args prog) (normalize (caddr prog)))))
  70     ('app
  71      (if (null? (cddr prog))
  72          `(,(normalize (car prog)) ,(normalize (cadr prog))) ; (f a)
  73          (normalize `(,(list (normalize (car prog)) (normalize (cadr prog)))
  74                       ,@(cddr prog))))) ; (f a b)
  75     ('let
  76         (append (list 'let
  77                       (map (lambda (x) `(,(car x) ,(normalize (cadr x))))
  78                            (let-bindings prog)))
  79                 (map normalize (let-body prog))))
  80     (else (ast-traverse normalize prog))))
  81
  82 (define (builtin-type x)
  83   (case x
  84     ('+ '(abs Int (abs Int Int)))
  85     ('- '(abs Int (abs Int Int)))
  86     ('* '(abs Int (abs Int Int)))
  87     ('! '(abs Bool Bool))
  88     ('= '(abs Int (abs Int Bool)))
  89     ('bool->int '(abs Bool Int))
  90     ('print '(abs String Void))
  91     (else (error #f "Couldn't find type for builtin" x))))
  92
  93 (define (check-let dls env x)
  94
  95   ; acc is a pair of (env . annotated bindings)
  96   (define (process-component acc comps)
  97     (let*
  98                                         ; create a new env with tvars for each component
  99                                         ; e.g. scc of (x y)
 100                                         ; scc-env = ((x . t0) (y . t1))
 101         ([scc-env
 102           (fold-left
 103            (lambda (acc c)
 104              (env-insert acc c (fresh-tvar)))
 105            (car acc) comps)]
 106                                         ; typecheck each component
 107          [type-results
 108           (map
 109            (lambda (c)
 110              (let ([body (cadr (assoc c (let-bindings x)))])
 111                (check dls scc-env body)))
 112            comps)]
 113                                         ; collect all the constraints in the scc
 114          [cs
 115           (fold-left
 116            (lambda (acc res c)
 117              (constraint-merge
 118               (constraint-merge
 119                                         ; unify with tvars from scc-env
 120                                         ; result ~ tvar
 121                (~ (env-lookup scc-env c) (cadr res))
 122                (car res))
 123               acc))
 124            '() type-results comps)]
 125                                         ; substitute *only* the bindings in this scc
 126          [new-env
 127           (map (lambda (x)
 128                  (if (memv (car x) comps)
 129                      (cons (car x) (substitute cs (cdr x)))
 130                      x))
 131                scc-env)]
 132
 133          [annotated-bindings (append (cdr acc) ; the previous annotated bindings
 134                                      (map list
 135                                           comps
 136                                           (map caddr type-results)))])
 137       (cons new-env annotated-bindings)))
 138                                         ; takes in the current environment and a scc
 139                                         ; returns new environment with scc's types added in
 140   (let* ([components (reverse (sccs (graph (let-bindings x))))]
 141          [results (fold-left process-component (cons env '()) components)]
 142          [new-env (car results)]
 143          [annotated-bindings (cdr results)]
 144
 145          [body-results (map (lambda (body) (check dls new-env body)) (let-body x))]
 146          [let-type (cadr (last body-results))]
 147          [cs (fold-left (lambda (acc cs) (constraint-merge acc cs)) '() (map car body-results))]
 148
 149          [annotated `((let ,annotated-bindings ,@(map caddr body-results)) : ,let-type)])
 150     (list cs let-type annotated)))
 151
 152 (define (check-app dls env x)
 153   (if (eqv? (car x) (cadr x))
 154                                         ; recursive function (f f)
 155                                         ; TODO: what about ((f a) f)????
 156       (let* ([func-type (env-lookup env (car x))]
 157              [return-type (fresh-tvar)]
 158              [other-func-type `(abs ,func-type ,return-type)]
 159              [cs (~ func-type other-func-type)]
 160              [resolved-return-type (substitute cs return-type)]
 161
 162              [annotated `(((,(car x) : ,func-type)
 163                            (,(cadr x) : ,func-type)) : ,resolved-return-type)])
 164         (list cs resolved-return-type annotated)))
 165
 166                                         ; regular function
 167   (let* ([arg-type-res (check dls env (cadr x))]
 168          [arg-type (cadr arg-type-res)]
 169          [func-type-res (check dls env (car x))]
 170          [func-type (cadr func-type-res)]
 171
 172                                         ; f ~ a -> t0
 173          [func-c (~
 174                   (substitute (car arg-type-res) func-type)
 175                   `(abs ,arg-type ,(fresh-tvar)))]
 176          [cs (constraint-merge
 177               (constraint-merge func-c (car arg-type-res))
 178               (car func-type-res))]
 179
 180          [resolved-func-type (substitute cs func-type)]
 181          [resolved-return-type (caddr resolved-func-type)]
 182
 183          [annotated `((,(caddr func-type-res)
 184                        ,(caddr arg-type-res)) : ,resolved-return-type)])
 185
 186     (if (abs? resolved-func-type)
 187         (let ((return-type (substitute cs (caddr resolved-func-type))))
 188           (list cs return-type annotated))
 189         (error #f "not a function"))))
 190
 191 (define (check-case dls env x)
 192
 193   (define (check-match switch-type x)
 194
 195     (define (get-bindings product-types pattern)
 196       (define (go product-type product)
 197         (case (ast-type product)
 198           ['var (list (cons product product-type))]
 199                                         ; an inner pattern match
 200           ['app (let* ([inner-sum (car product)]
 201                        [inner-sums (cdr (assoc product-type dls))]
 202                        [inner-product-types (cdr (assoc inner-sum inner-sums))])
 203                   (get-bindings inner-product-types product))]
 204           [else '()]))
 205       (flat-map go product-types (cdr pattern)))
 206
 207
 208     (let ([pattern (car x)]
 209           [expr (cadr x)])
 210       (case (ast-type pattern)
 211         ['app
 212                                         ; a pattern match with bindings
 213           (let ([sum (assoc (car pattern) (cdr (assoc switch-type dls)))])
 214             (unless sum (error #f "can't pattern match ~a with ~a" switch-type pattern))
 215             (let* ([names (cdr pattern)]
 216                    [product-types (cdr sum)]
 217                    [new-env (append (get-bindings product-types pattern) env)])
 218
 219               (check dls new-env expr)))]
 220                                         ; pattern match with binding and no constructor
 221         ['var (check dls (env-insert env pattern switch-type) expr)]
 222                                         ; a pattern match without bindings
 223         [else (check dls env expr)])))
 224
 225   (let* ([switch-type-res (check dls env (case-switch x))]
 226          [switch-type (cadr switch-type-res)]
 227
 228          [case-expr-type-res (map (lambda (x) (check-match switch-type x)) (case-cases x))]
 229          [case-expr-types (map cadr case-expr-type-res)]
 230
 231          [case-expr-equality-cs (fold-left constraint-merge '()
 232                                            (map (lambda (t) (~ t (car case-expr-types)))
 233                                                 (cdr case-expr-types)))]
 234
 235          [resolved-type (substitute case-expr-equality-cs (car case-expr-types))]
 236
 237          [annotated `((case ,(caddr switch-type-res)
 238                         ,@(map (lambda (c e et)
 239                                  `(,c ((,e : ,et))))
 240                                (map car (case-cases x))
 241                                (map cadr (case-cases x))
 242                                case-expr-types)) : ,resolved-type)]
 243
 244          [cs (fold-left constraint-merge '()
 245                         (cons (car switch-type-res) case-expr-equality-cs))])
 246     (list cs resolved-type annotated)))
 247
 248 ; returns a list (constraints type annotated)
 249 (define (check dls env x)
 250   (define (make-result cs type)
 251     (list cs type `(,x : ,type)))
 252   ;; (display "check: ")
 253   ;; (display x)
 254   ;; (display "\n\t")
 255   ;; (display env)
 256   ;; (newline)
 257   (let
 258       ((res
 259         (case (ast-type x)
 260           ('int-literal (make-result '() 'Int))
 261           ('bool-literal (make-result '() 'Bool))
 262           ('string-literal (make-result '() 'String))
 263           ('builtin (make-result '() (builtin-type x)))
 264
 265           ('if
 266            (let* ((cond-type-res (check dls env (cadr x)))
 267                   (then-type-res (check dls env (caddr x)))
 268                   (else-type-res (check dls env (cadddr x)))
 269                   (then-eq-else-cs (~ (cadr then-type-res)
 270                                       (cadr else-type-res)))
 271                   (cs (constraint-merge
 272                        (car then-type-res)
 273                        (constraint-merge (~ (cadr cond-type-res) 'Bool)
 274                                          (constraint-merge (car else-type-res)
 275                                                            then-eq-else-cs))))
 276                   (return-type (substitute cs (cadr then-type-res)))
 277                   [annotated `((if ,(caddr cond-type-res)
 278                                    ,(caddr then-type-res)
 279                                    ,(caddr else-type-res)) : ,return-type)])
 280              (list cs return-type annotated)))
 281
 282           ('var (make-result '() (env-lookup env x)))
 283           ('let (check-let dls env x))
 284
 285
 286           ('lambda
 287               (let* ([new-env (env-insert env (lambda-arg x) (fresh-tvar))]
 288
 289                      [body-type-res (check dls new-env (lambda-body x))]
 290                      [cs (car body-type-res)]
 291                      [subd-env (substitute-env (car body-type-res) new-env)]
 292                      [arg-type (env-lookup subd-env (lambda-arg x))]
 293                      [resolved-arg-type (substitute cs arg-type)]
 294
 295                      [lambda-type `(abs ,resolved-arg-type ,(cadr body-type-res))]
 296
 297                      [annotated `((lambda (,(lambda-arg x)) ,(caddr body-type-res)) : ,lambda-type)])
 298
 299                 (list (car body-type-res) ; constraints
 300                       lambda-type  ; type
 301                       annotated)))
 302
 303
 304           ('app (check-app dls env x))
 305           ['case (check-case dls env x)])))
 306
 307
 308     ;; (display "result of ")
 309     ;; (display x)
 310     ;; (display ":\n\t")
 311     ;; (display (pretty-type (cadr res)))
 312     ;; (display "\n\t[")
 313     ;; (display (pretty-constraints (car res)))
 314     ;; (display "]\n")
 315     res))
 316
 317 (define (init-adts-env prog)
 318   (flat-map data-tors-type-env (program-data-layouts prog)))
 319
 320                                         ; we typecheck the lambda calculus only (only single arg lambdas)
 321 (define (typecheck prog)
 322   (let ([expanded (expand-pattern-matches prog)])
 323     (cadr (check (program-data-layouts prog)
 324                  (init-adts-env expanded)
 325                  (normalize (program-body expanded))))))
 326
 327
 328                                         ; before passing annotated types onto codegen
 329                                         ; we need to restore the pre-normalization structure
 330                                         ; (this is important for function arity etc)
 331 (define (denormalize orig normed)
 332
 333   (define (collapse-lambdas n x)
 334     (case n
 335       [0 x]
 336       [else
 337        (let* ([inner-lambda (lambda-body (ann-expr x))]
 338               [arg (lambda-arg (ann-expr x))]
 339               [inner-collapsed (ann-expr (collapse-lambdas (- n 1) inner-lambda))])
 340          `((lambda ,(cons arg (lambda-args inner-collapsed))
 341              ,(lambda-body inner-collapsed)) : ,(ann-type x)))]))
 342
 343   (define (collapse-apps n x)
 344     (case n
 345       [-1 (error #f "nullary functions not handled yet")]
 346       [0 x]
 347       [else
 348        (let* ([inner-app (car (ann-expr x))]
 349               [inner-collapsed (collapse-apps (- n 1) inner-app)])
 350          `(,(append (ann-expr inner-collapsed) (cdr (ann-expr x))) : ,(ann-type x)))]))
 351
 352   (case (ast-type orig)
 353     ['lambda
 354         (let ([collapsed (collapse-lambdas (- (length (lambda-args orig)) 1) normed)])
 355           `((lambda ,(lambda-args (ann-expr collapsed))
 356               ,(denormalize (lambda-body orig)
 357                             (lambda-body (ann-expr collapsed)))) : ,(ann-type collapsed)))]
 358     ['app
 359      (let ([collapsed (collapse-apps (- (length orig) 2) normed)])
 360        `(,(map (lambda (o n) (denormalize o n)) orig (ann-expr collapsed))
 361          : ,(ann-type collapsed)))]
 362     ['let
 363         `((let ,(map (lambda (o n) (list (car o) (denormalize (cadr o) (cadr n))))
 364                      (let-bindings orig)
 365                      (let-bindings (ann-expr normed)))
 366             ,@(map denormalize
 367                    (let-body orig)
 368                    (let-body (ann-expr normed)))) : ,(ann-type normed))]
 369     ['if `((if ,@(map denormalize (cdr orig) (cdr (ann-expr normed))))
 370            : ,(ann-type normed))]
 371     ['case `((case ,(denormalize (case-switch orig) (case-switch (ann-expr normed)))
 372                ,@(map (lambda (o n) (cons (car o) (denormalize (cadr o) (cadr n))))
 373                       (case-cases orig) (case-cases (ann-expr normed))))
 374              : ,(ann-type normed))]
 375     [else normed]))
 376
 377 (define ann-expr car)
 378 (define ann-type caddr)
 379
 380                                         ; prerequisites: expand-pattern-matches
 381 (define (annotate-types prog)
 382   (denormalize
 383    (program-body prog)
 384    (caddr (check (program-data-layouts prog)
 385                  (init-adts-env prog)
 386                  (normalize (program-body prog))))))
 387
 388
 389                                         ; returns a list of constraints
 390 (define (~ a b)
 391   (let ([res (unify? a b)])
 392     (if res
 393         res
 394         (error #f
 395                (format "couldn't unify ~a ~~ ~a" a b)))))
 396
 397 (define (unify? a b)
 398   (cond [(eq? a b) '()]
 399         [(tvar? a) (list (cons a b))]
 400         [(tvar? b) (list (cons b a))]
 401         [(and (abs? a) (abs? b))
 402          (let* [(arg-cs (unify? (cadr a) (cadr b)))
 403                 (body-cs (unify? (substitute arg-cs (caddr a))
 404                                  (substitute arg-cs (caddr b))))]
 405            (constraint-merge body-cs arg-cs))]
 406         [else #f]))
 407
 408 (define (substitute cs t)
 409   (cond
 410    [(tvar? t)
 411     (if (assoc t cs)
 412         (cdr (assoc t cs))
 413         t)]
 414    [(abs? t) `(abs ,(substitute cs (cadr t))
 415                    ,(substitute cs (caddr t)))]
 416    [else t]))
 417
 418                                         ; applies substitutions to all variables in environment
 419 (define (substitute-env cs env)
 420   (map (lambda (x) (cons (car x) (substitute cs (cdr x)))) env))
 421
 422                                         ; composes constraints a onto b and merges, i.e. applies a to b
 423                                         ; a should be the "more important" constraints
 424 (define (constraint-merge a b)
 425   (define (f cs constraint)
 426     (cons (car constraint)
 427           (substitute cs (cdr constraint))))
 428
 429   (define (most-concrete a b)
 430     (cond
 431      [(tvar? a) b]
 432      [(tvar? b) a]
 433      [(and (abs? a) (abs? b))
 434       `(abs ,(most-concrete (cadr a) (cadr b))
 435             ,(most-concrete (caddr a) (caddr b)))]
 436      [(abs? a) b]
 437      [(abs? b) a]
 438      [else a]))
 439
 440                                         ; for any two constraints that clash, e.g. t1 ~ abs t2 t3
 441                                         ; and t1 ~ abs int t3
 442                                         ; prepend the most concrete version of the type to the
 443                                         ; list of constraints
 444   (define (clashes)
 445     (define (gen acc x)
 446       (if (assoc (car x) a)
 447           (cons (cons (car x) (most-concrete (cdr (assoc (car x) a))
 448                                              (cdr x)))
 449                 acc)
 450           acc))
 451     (fold-left gen '() b))
 452
 453   (define (union p q)
 454     (append (filter (lambda (x) (not (assoc (car x) p)))
 455                     q)
 456             p))
 457   (append (clashes) (union a (map (lambda (z) (f a z)) b))))
 458
 459
 460 ;;                                      ; a1 -> a2 ~ a3 -> a4;
 461 ;;                                      ; a1 -> a2 !~ Bool -> Bool
 462 ;;                                      ; basically can the tvars be renamed
 463 (define (types-equal? x y)
 464   (let ([cs (unify? x y)])
 465     (if (not cs) #f
 466         (let*
 467             ([test (lambda (acc c)
 468                      (and acc
 469                           (tvar? (car c)) ; the only substitutions allowed are tvar -> tvar
 470                           (tvar? (cdr c))))])
 471           (fold-left test #t cs)))))
 472
 473                                         ; input: a list of binds ((x . y) (y . 3))
 474                                         ; returns: pair of verts, edges ((x y) . (x . y))
 475