codegen.scm

   1 (load "typecheck.scm")
   2 (load "ast.scm")
   3
   4 (define target 'darwin)
   5
   6 (define (emit . s)
   7   (begin
   8     (apply printf s)
   9     (display "\n")))
  10
  11 (define (codegen-add xs si env)
  12   (define (go ys)
  13     (if (null? ys)
  14         (emit "movq ~a(%rbp), %rax" si)
  15         (begin
  16           (let ((y (car ys)))
  17             (if (integer? y)
  18                 (emit "addq $~a, ~a(%rbp)" y si)
  19                 (begin
  20                   (codegen-expr y (- si wordsize) env)
  21                   (emit "addq %rax, ~a(%rbp)" si))))
  22           (go (cdr ys)))))
  23   (begin
  24                                         ; use si(%rbp) as the accumulator
  25     (emit "movq $0, ~a(%rbp)" si)
  26     (go xs)))
  27
  28 (define (codegen-binop opcode)
  29   (lambda (a b si env)
  30     (codegen-expr b si env)
  31     (emit "movq %rax, ~a(%rbp)" si)
  32     (codegen-expr a (- si wordsize) env)
  33     (emit "~a ~a(%rbp), %rax" opcode si)))
  34
  35 (define codegen-sub (codegen-binop "sub"))
  36
  37 (define codegen-mul (codegen-binop "imul"))
  38
  39 (define (codegen-not x si env)
  40   (codegen-expr x si env)
  41   (emit "notq %rax")
  42   (emit "andq $1, %rax"))
  43
  44 (define (codegen-eq a b si env)
  45   (codegen-expr a si env)
  46   (emit "movq %rax, ~a(%rbp)" si)
  47   (codegen-expr b (- si wordsize) env)
  48   (emit "subq ~a(%rbp), %rax" si)
  49   (emit "not %rax")
  50   (emit "andq $1, %rax"))
  51
  52                                         ; 'write file handle addr-string num-bytes
  53
  54 (define (codegen-print x si env)
  55   (codegen-expr x si env) ; x should be a static-string, producing a label
  56
  57                                         ; make a copy of string address since %rax and %rdi are clobbered
  58   (emit "mov %rax, %rbx")
  59
  60                                         ; get the length of the null terminated string
  61   (emit "mov %rax, %rdi")
  62   (emit "xor %al, %al")   ; set %al to 0
  63   (emit "mov $-1, %rcx") ; max search length = max int = -1
  64   (emit "cld")           ; clear direction flag, search up in memory
  65   (emit "repne scasb")   ; scan string, %rcx = -strlen - 1 - 1
  66
  67   (emit "not %rcx")      ; -%rcx = strlen + 1
  68   (emit "dec %rcx")
  69
  70   (case target
  71     ('darwin
  72      (emit "movq %rbx, %rsi") ; string addr
  73      (emit "movq %rcx, %rdx") ; num bytes
  74      (emit "movq $1, %rdi")   ; file handle (stdout)
  75      (emit "movq $0x2000004, %rax")) ; syscall 4 (write)
  76     ('linux
  77      (emit "mov %rbx, %rsi")  ; string addr
  78      (emit "mov %rcx, %rdx")  ; num bytes
  79      (emit "mov $1, %rax")    ; file handle (stdout)
  80      (emit "mov $1, %rdi"))) ; syscall 1 (write)
  81   (emit "syscall"))
  82
  83 (define (range s n)
  84   (if (= 0 n) '()
  85       (append (range s (- n 1))
  86               (list (+ s (- n 1))))))
  87
  88 (define wordsize 8)
  89
  90 (define (codegen-let bindings body si env)
  91   (let* ((stack-offsets (map (lambda (x) (- si (* x wordsize)))
  92                              (range 0 (length bindings))))
  93          (inner-si (- si (* (length bindings) wordsize)))
  94          (names (map car bindings))
  95          (exprs (map cadr bindings))
  96
  97                                         ; recursive let bindings: build environment as we go
  98          (inner-env (fold-left
  99                      (lambda (env name expr offset)
 100                        (codegen-expr expr inner-si env)
 101                        (emit "movq %rax, ~a(%rbp)" offset)
 102                        (cons (cons name offset) env))
 103                      env names exprs stack-offsets)))
 104     (for-each (lambda (form)
 105                 (codegen-expr form inner-si inner-env))
 106               body)))
 107
 108 (define (codegen-var name si env)
 109   (when (not (assoc name env))
 110     (error #f (format "Variable ~a is not bound" name)))
 111   (let ((offset (cdr (assoc name env))))
 112     (emit "movq ~a(%rbp), %rax" offset)))
 113
 114 (define cur-lambda 0)
 115 (define (fresh-lambda)
 116   (set! cur-lambda (+ 1 cur-lambda))
 117   (format "_lambda~a" (- cur-lambda 1)))
 118
 119                                         ; a closure on the heap looks like:
 120                                         ; 0    8         16        24
 121                                         ; addr var1....  var2....  var3....
 122
 123 (define (codegen-closure label captured si env)
 124   (let* ((heap-offsets (map (lambda (i) (+ 8 (* 8 i)))
 125                             (range 0 (length captured))))) ; 4, 12, 20, etc.
 126
 127     (emit "movq heap_start@GOTPCREL(%rip), %rbx")
 128
 129     (emit "movq (%rbx), %rax")          ; %rax = heap addr of closure
 130
 131
 132     ; point heap_start to next space
 133     (emit "addq $~a, (%rbx)" (+ 8 (* 8 (length captured))))
 134
 135                                         ; store the address to the lambda code
 136     (emit "movq ~a@GOTPCREL(%rip), %rbx" label)
 137     (emit "movq %rbx, 0(%rax)")
 138
 139                                         ; store the captured vars
 140     (for-each
 141      (lambda (var-name new-offset)
 142        (emit "movq ~a(%rbp), ~a(rax)"
 143              (cdr (assoc var-name env))
 144              new-offset))
 145      captured
 146      heap-offsets)))
 147
 148                                         ; for now we can only call closures
 149 (define (codegen-call f args si env)
 150   (codegen-expr f si env)
 151
 152   (emit "## starting call")
 153
 154   (emit "movq %rax, ~a(%rbp)" si) ; store address of closure first on stack
 155
 156                                         ; codegen the arguments, store them intermediately
 157   (for-each
 158    (lambda (e i)
 159      (begin
 160        (emit "## arg no. ~a" (- i 1))
 161        (codegen-expr e (- si (* wordsize i)) env)
 162                                         ; store intermediate result on stack
 163        (emit "movq %rax, ~a(%rbp)" (- si (* wordsize i)))))
 164
 165    args (range 1 (length args)))
 166
 167                                         ; now that we have everything we need on the stack,
 168                                         ; move them into the param registers
 169
 170   (emit "## moving args into place")
 171   (for-each
 172    (lambda (i) (emit "movq ~a(%rbp), ~a"
 173                      (- si (* wordsize i))
 174                      (param-register i)))
 175    (range 1 (length args)))
 176
 177                                         ; todo: can this be made more efficient
 178   (emit "movq ~a(%rbp), %rax" si)       ; load back pointer to closure
 179
 180   (emit "## moving captives into place")
 181
 182                                         ; move captives into first argument
 183   (emit "movq %rax, %rbx")
 184   (emit "addq $8, %rbx")
 185   (emit "movq %rbx, ~a" (param-register 0))
 186
 187   (emit "## performing call")
 188
 189   (emit "addq $~a, %rsp" si) ; adjust the stack pointer to account all the stuff we put in the env
 190   (emit "callq *(%rax)")                ; call closure function
 191   (emit "subq $~a, %rsp" si))
 192
 193                                         ; LAMBDAS:
 194                                         ; 1st param: pointer to captured args
 195                                         ; 2nd param: 1st arg
 196                                         ; 3rd param: 2nd arg, etc.
 197
 198 (define (codegen-lambda l)
 199   (let* ((label (car l))
 200          (stuff (cdr l))
 201          (captured (car stuff))
 202          (args (cadr stuff))
 203          (body (caddr stuff))
 204                                         ; params = what actually gets passed
 205          (params (append captured args))
 206
 207          (stack-offsets (map (lambda (i)
 208                                (* (- wordsize) i))
 209                              (range 1 (length params))))
 210
 211          (env (map cons params stack-offsets)))
 212     (emit "~a:" label)
 213
 214     (display "## lambda captives: ")
 215     (display captured)
 216     (newline)
 217     (display "## lambda args: ")
 218     (display args)
 219     (newline)
 220     (display "## lambda body: ")
 221     (display body)
 222     (newline)
 223
 224     (emit "push %rbp") ; preserve caller's base pointer
 225     (emit "movq %rsp, %rbp") ; set up our own base pointer
 226
 227                                         ; load the captured vars onto the stack
 228     (for-each
 229      (lambda (i)
 230        (emit "movq ~a(~a), ~a(%rbp)"
 231              i (param-register 0) (* (- wordsize) i)))
 232        (range 0 (length captured)))
 233
 234                                         ; load the args onto the stack
 235     (for-each
 236      (lambda (i)
 237        (emit "movq ~a, ~a(%rbp)"
 238              (param-register i) (* (- wordsize) i)))
 239      (range 1 (length args)))
 240
 241     (codegen-expr body (* (- wordsize) (+ 1 (length params))) env)
 242
 243     (emit "pop %rbp") ; restore caller's base pointer
 244     (emit "ret")))
 245
 246 (define (codegen-string label)
 247   (case target
 248     ('darwin (emit "movq ~a@GOTPCREL(%rip), %rax" label))
 249     ('linux  (emit "lea $~a, %rax" label))))
 250
 251 (define cur-label 0)
 252 (define (fresh-label)
 253   (set! cur-label (+ 1 cur-label))
 254   (format "label~a" (- cur-label 1)))
 255
 256 (define (codegen-if cond then else si env)
 257   (codegen-expr cond si env)
 258   (emit "cmpq $0, %rax")
 259   (let ((exit-label (fresh-label))
 260         (else-label (fresh-label)))
 261     (emit "je ~a" else-label)
 262     (codegen-expr then si env)
 263     (emit "jmp ~a" exit-label)
 264     (emit "~a:" else-label)
 265     (codegen-expr else si env)
 266     (emit "~a:" exit-label)))
 267
 268 (define (codegen-expr e si env)
 269   (case (ast-type e)
 270     ('closure (codegen-closure (cadr e) (caddr e) si env))
 271     ('app
 272      (case (car e)
 273        ('+ (codegen-add (cdr e) si env))
 274        ('- (codegen-sub (cadr e) (caddr e) si env))
 275        ('* (codegen-mul (cadr e) (caddr e) si env))
 276        ('! (codegen-not (cadr e) si env))
 277        ('= (codegen-eq  (cadr e) (caddr e) si env))
 278        ('bool->int (codegen-expr (cadr e) si env))
 279        ('print (codegen-print (cadr e) si env))
 280        (else (codegen-call (car e) (cdr e) si env))))
 281
 282     ; this is a builtin being passed around as a variable
 283     ('builtin (emit "movq $~a, %rax" (builtin-id e)))
 284
 285     ('let (codegen-let (let-bindings e)
 286                        (let-body e)
 287                        si
 288                        env))
 289
 290     ('var (codegen-var e si env))
 291
 292     ('if (codegen-if (cadr e) (caddr e) (cadddr e) si env))
 293
 294     ('bool-literal (emit "movq $~a, %rax" (if e 1 0)))
 295     ('int-literal (emit "movq $~a, %rax" e))
 296
 297     ('static-string (codegen-string (cadr e)))
 298
 299     (else (error #f "don't know how to codegen this"))))
 300
 301
 302 (define (fold-map f x) (fold-left append '() (map f x)))
 303
 304 (define (free-vars prog)
 305   (define bound '())
 306   (define (collect e)
 307     (case (ast-type e)
 308       ('builtin '()) ; do nothing
 309       ('var (if (memq e bound) '() (list e)))
 310       ('lambda
 311           (set! bound (append (lambda-args e) bound))
 312         (collect (lambda-body e)))
 313
 314       ('app (fold-map collect e))
 315       ('let
 316           (let ((bind-fvs (fold-map (lambda (a)
 317                                       ((set! bound (cons (car a) bound))
 318                                        (collect (cdr a))))
 319                                     (let-bindings cadr)))
 320                 (body-fvs (fold-map collect (let-body e))))
 321             (append bind-fvs body-fvs)))
 322       (else '())))
 323   (collect prog))
 324
 325                                         ; ((lambda (x) (+ x y)) 42) => ((closure lambda1 (y)) 42)
 326                                         ;                              [(lambda1 . ((y), (x), (+ x y))]
 327                                         ; for builtins, this generates a closure if it is used
 328                                         ; outside of an immediate app
 329                                         ; but only one closure for each builtin
 330
 331 (define (extract-lambdas program)
 332   (define lambdas '())
 333   (define (add-lambda e)
 334     (let* ((label (fresh-lambda))
 335            (args (lambda-args e))
 336            (captured (free-vars e))
 337            (body (extract (lambda-body e)))
 338            (new-lambda (cons label (list captured args body))))
 339       (set! lambdas (cons new-lambda lambdas))
 340       `(closure ,label ,captured))) ; todo: should we string->symbol?
 341
 342   (define (find-builtin-lambda e)
 343     (let [(l (assq (builtin-name e) lambdas))]
 344       (if l `(closure ,(car l) ,(caadr l)) #f)))
 345
 346   (define (builtin-name e)
 347     (case e
 348       ('+ "_add")
 349       ('- "_sub")
 350       ('* "_mul")
 351       ('bool->int "_bool2int")
 352       (else (error #f "fill this out"))))
 353   (define (builtin-args e)
 354     (case e
 355       ('+ '(x y))
 356       ('- '(x y))
 357       ('* '(x y))
 358       ('bool->int '(x))
 359       (else (error #f "fill this out"))))
 360
 361   (define (add-builtin-lambda e)
 362     (let* [(label (builtin-name e))
 363            (captured '())
 364            (args (builtin-args e))
 365            (body `(,e ,@args))
 366            (new-lambda (cons label (list captured args body)))]
 367       (set! lambdas (cons new-lambda lambdas))
 368       `(closure ,label ,captured)))
 369
 370   (define (extract e)
 371     (case (ast-type e)
 372       ('lambda (add-lambda e))
 373       ('let `(let ,(map extract (let-bindings e))
 374                ,@(map extract (let-body e))))
 375       ('app (append
 376                                         ; if a builtin is used as a function, don't generate lambda
 377              (if (eqv? 'builtin (ast-type (car e)))
 378                  '()
 379                  (list (extract (car e))))
 380              (map extract (cdr e))))
 381
 382       ('builtin
 383        (if (find-builtin-lambda e)
 384            (find-builtin-lambda e)
 385            (add-builtin-lambda e)))
 386
 387
 388       (else (ast-traverse extract e))))
 389   (let ((transformed (extract program)))
 390     (cons lambdas transformed)))
 391
 392 (define (extract-strings program)
 393   (let ((cur-string 0)
 394         (strings '())) ; assoc list of labels -> string
 395     (define (fresh-string)
 396       (set! cur-string (+ cur-string 1))
 397       (format "string~a" (- cur-string 1)))
 398     (define (extract e)
 399       (case (ast-type e)
 400         ('string-literal
 401          (let ((label (fresh-string)))
 402            (set! strings (cons (cons label e) strings))
 403            `(static-string ,label)))
 404         (else (ast-traverse extract e))))
 405     (let ((transformed (extract program)))
 406       (cons strings transformed))))
 407
 408 (define (emit-string-data s)
 409   (emit "~a:" (car s))
 410   (emit "\t.string \"~a\"" (cdr s)))
 411
 412 ;; (define (amd64-abi f)
 413 ;;                                      ; preserve registers
 414 ;;   (emit "push %rbp")
 415 ;;   ;; (emit "push %rbx")
 416 ;;   ;; (for-each (lambda (i)
 417 ;;   ;;               (emit (string-append
 418 ;;   ;;                      "push %r"
 419 ;;   ;;                      (number->string i))))
 420 ;;   ;;             '(12 13 14 15))
 421
 422 ;;   (emit "movq %rsp, %rbp")              ; set up the base pointer
 423
 424 ;;   (f) ; call stuff
 425 ;;                                      ; restore preserved registers
 426 ;;   ;; (for-each (lambda (i)
 427 ;;   ;;               (emit (string-append
 428 ;;   ;;                      "pop %r"
 429 ;;   ;;                      (number->string i))))
 430 ;;   ;;             '(15 14 13 12))
 431 ;;   ;; (emit "pop %rbx")
 432 ;;   (emit "pop %rbp")
 433 ;;   (emit "ret"))
 434
 435                                         ; 24(%rbp) mem arg 1
 436                                         ; 16(%rbp) mem arg 0          prev frame
 437                                         ; -----------------------
 438                                         ;  8(%rbp) return address     cur frame
 439                                         ;  0(%rbp) prev %rbp
 440                                         ; -8(%rbp) do what you want
 441                                         ;  ...     do what you want
 442                                         ;  0(%rsp) do what you want
 443
 444 (define (param-register n)
 445   (case n
 446     (0 "%rdi")
 447     (1 "%rsi")
 448     (2 "%rdx")
 449     (3 "%rcx")
 450     (4 "%r8")
 451     (5 "%r9")
 452     (else (error #f "need to test out the below"))
 453     (else (format "~a(%rsp)" (- n 6)))))
 454
 455 (define (initialize-heap)
 456   (let ((mmap
 457          (case target
 458            ('darwin "0x20000c5")
 459            ('linux "9"))))
 460                                         ; allocate some heap memory
 461     (emit "mov $~a, %rax" mmap) ; mmap
 462     (emit "xor %rdi, %rdi")  ; addr = null
 463     (emit "movq $1024, %rsi")   ; length = 1kb
 464     (emit "movq $0x3, %rdx") ; prot = read | write = 0x2 | 0x1
 465                                         ;    flags = anonymous | private
 466     (case target
 467       ('darwin (emit "movq $0x1002, %r10")) ; anon = 0x1000, priv = 0x02
 468       ('linux (emit "movq $0x22, %r10")))   ; anon = 0x20,   priv = 0x02
 469     (emit "movq $-1, %r8") ; fd = -1
 470     (emit "xor %r9, %r9") ; offset = 0
 471     (emit "syscall")
 472                                         ; %rax now contains pointer to the start of the heap
 473                                         ; keep track of it
 474
 475     (emit "movq heap_start@GOTPCREL(%rip), %rsi")
 476     (emit "movq %rax, (%rsi)")))
 477
 478 (define (codegen program)
 479   (let* ((extract-res-0 (extract-strings program))
 480          (strings (car extract-res-0))
 481          (extract-res-1 (extract-lambdas (cdr extract-res-0)))
 482          (lambdas (car extract-res-1))
 483          (xform-prog (cdr extract-res-1)))
 484
 485     (emit "\t.global _start")
 486     (emit "\t.text")
 487                                         ;    (emit ".p2align 4,,15") is this needed?
 488
 489     (for-each codegen-lambda lambdas)
 490
 491     (emit "_start:")
 492
 493     (initialize-heap)
 494
 495     (emit "movq %rsp, %rbp")            ; set up the base pointer
 496     (codegen-expr xform-prog 0 '())
 497
 498                                         ; exit syscall
 499     (emit "mov %rax, %rdi")
 500     (case target
 501       ('darwin (emit "movq $0x2000001, %rax"))
 502       ('linux (emit "mov $60, %rax")))
 503     (emit "syscall")
 504
 505     (emit ".data")
 506
 507     (emit "heap_start:")
 508     (emit "\t.quad 0")
 509
 510     (for-each emit-string-data strings)))
 511
 512 (define (compile-to-binary program output t)
 513   (set! target t)
 514   (when (not (eq? (typecheck program) 'int)) (error #f "not an int"))
 515   (let ([tmp-path "/tmp/a.s"])
 516     (when (file-exists? tmp-path) (delete-file tmp-path))
 517     (with-output-to-file tmp-path
 518       (lambda () (codegen program)))
 519
 520     (case target
 521       ('darwin
 522        (system "as /tmp/a.s -o /tmp/a.o")
 523        (system (format "ld /tmp/a.o -e _start -macosx_version_min 10.14 -static -o ~a" output)))
 524       ('linux
 525        (system "as /tmp/a.s -o /tmp/a.o")
 526        (system (format "ld /tmp/a.o -o ~a" output))))))
 527
 528 ; NOTES
 529 ; syscalls in linux and darwin use the following arguments for syscall instruction:
 530 ; %rax = syscall #
 531 ; %rdi = 1st arg
 532 ; %rsi = 2nd arg
 533 ; %rdx = 3rd arg
 534 ; %r10 = 4th arg
 535 ; %r8  = 5th arg
 536 ; %r9  = 6th arg
 537
 538 ; on darwin, the syscall is offset by 0x2000000
 539 ; https://opensource.apple.com/source/xnu/xnu-2782.20.48/bsd/kern/syscalls.master
 540 ; documentation for most syscalls: /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX.sdk/usr/include/sys