codegen.scm

   1 (load "typecheck.scm")
   2 (load "ast.scm")
   3 (load "platform.scm")
   4
   5 (define target host-os)
   6
   7 (define (emit . s)
   8   (begin
   9     (apply printf s)
  10     (display "\n")))
  11
  12 (define (codegen-add xs si env)
  13   (define (go ys)
  14     (if (null? ys)
  15         (emit "movq ~a(%rbp), %rax" si)
  16         (begin
  17           (let ((y (car ys)))
  18             (if (integer? y)
  19                 (emit "addq $~a, ~a(%rbp)" y si)
  20                 (begin
  21                   (codegen-expr y (- si wordsize) env)
  22                   (emit "addq %rax, ~a(%rbp)" si))))
  23           (go (cdr ys)))))
  24   (begin
  25                                         ; use si(%rbp) as the accumulator
  26     (emit "movq $0, ~a(%rbp)" si)
  27     (go xs)))
  28
  29 (define (codegen-binop opcode)
  30   (lambda (a b si env)
  31     (codegen-expr b si env)
  32     (emit "movq %rax, ~a(%rbp)" si)
  33     (codegen-expr a (- si wordsize) env)
  34     (emit "~a ~a(%rbp), %rax" opcode si)))
  35
  36 (define codegen-sub (codegen-binop "sub"))
  37
  38 (define codegen-mul (codegen-binop "imul"))
  39
  40 (define (codegen-not x si env)
  41   (codegen-expr x si env)
  42   (emit "notq %rax")
  43   (emit "andq $1, %rax"))
  44
  45 (define (codegen-eq a b si env)
  46   (codegen-expr a si env)
  47   (emit "movq %rax, ~a(%rbp)" si)
  48   (codegen-expr b (- si wordsize) env)
  49   (emit "## ~a = ~b" a b)
  50   (emit "cmpq ~a(%rbp), %rax" si)
  51   (emit "sete %al"))
  52
  53                                         ; 'write file handle addr-string num-bytes
  54
  55 (define (codegen-print x si env)
  56   (codegen-expr x si env) ; x should be a static-string, producing a label
  57
  58                                         ; make a copy of string address since %rax and %rdi are clobbered
  59   (emit "mov %rax, %rbx")
  60
  61                                         ; get the length of the null terminated string
  62   (emit "mov %rax, %rdi")
  63   (emit "xor %al, %al")   ; set %al to 0
  64   (emit "mov $-1, %rcx") ; max search length = max int = -1
  65   (emit "cld")           ; clear direction flag, search up in memory
  66   (emit "repne scasb")   ; scan string, %rcx = -strlen - 1 - 1
  67
  68   (emit "not %rcx")      ; -%rcx = strlen + 1
  69   (emit "dec %rcx")
  70
  71   (emit "movq %rbx, %rsi") ; string addr
  72   (emit "movq %rcx, %rdx") ; num bytes
  73   (emit "movq $1, %rdi")   ; file handle (stdout)
  74   (case target
  75     ('darwin (emit "mov $0x2000004, %rax")) ; syscall 4 (write)
  76     ('linux  (emit "mov $1, %rax"))) ; syscall 1 (write)
  77   (emit "syscall"))
  78
  79 (define (range s n)
  80   (if (= 0 n) '()
  81       (append (range s (- n 1))
  82               (list (+ s (- n 1))))))
  83
  84 (define wordsize 8)
  85
  86 (define (codegen-let bindings body si env)
  87   (let* ((stack-offsets (map (lambda (x) (- si (* x wordsize)))
  88                              (range 0 (length bindings))))
  89          (inner-si (- si (* (length bindings) wordsize)))
  90          (names (map car bindings))
  91          (exprs (map cadr bindings))
  92
  93                                         ; recursive let bindings: build environment as we go
  94          (inner-env (fold-left
  95                      (lambda (env name expr offset)
  96                        (codegen-expr expr inner-si env)
  97                        (emit "movq %rax, ~a(%rbp)" offset)
  98                        (cons (cons name offset) env))
  99                      env names exprs stack-offsets)))
 100     (for-each (lambda (form)
 101                 (codegen-expr form inner-si inner-env))
 102               body)))
 103
 104 (define (codegen-var name si env)
 105   (when (not (assoc name env))
 106     (error #f (format "Variable ~a is not bound" name)))
 107   (let ((offset (cdr (assoc name env))))
 108     (emit "movq ~a(%rbp), %rax" offset)))
 109
 110 (define cur-lambda 0)
 111 (define (fresh-lambda)
 112   (set! cur-lambda (+ 1 cur-lambda))
 113   (format "_lambda~a" (- cur-lambda 1)))
 114
 115                                         ; a closure on the heap looks like:
 116                                         ; 0    8         16        24
 117                                         ; addr var1....  var2....  var3....
 118
 119 (define (codegen-closure label captured si env)
 120   (let* ((heap-offsets (map (lambda (i) (+ 8 (* 8 i)))
 121                             (range 0 (length captured))))) ; 4, 12, 20, etc.
 122
 123     (emit "## creating closure")
 124
 125     (emit "movq heap_start@GOTPCREL(%rip), %rbx")
 126
 127     (emit "movq (%rbx), %rax")          ; %rax = heap addr of closure
 128
 129
 130     ; point heap_start to next space
 131     (emit "addq $~a, (%rbx)" (+ 8 (* 8 (length captured))))
 132
 133     (emit "## storing address to lambda")
 134                                         ; store the address to the lambda code
 135     (emit "movq ~a@GOTPCREL(%rip), %rbx" label)
 136     (emit "movq %rbx, 0(%rax)")
 137
 138     (emit "## storing captives")
 139                                         ; store the captured vars
 140     (for-each
 141      (lambda (var-name new-offset)
 142        (begin
 143          (emit "movq ~a(%rbp), %rbx" (cdr (assoc var-name env)))
 144          (emit "movq %rbx, ~a(%rax)" new-offset)))
 145      captured
 146      heap-offsets)))
 147
 148                                         ; for now we can only call closures
 149 (define (codegen-call f args si env)
 150   (codegen-expr f si env)
 151
 152   (emit "## starting call")
 153
 154   (emit "movq %rax, ~a(%rbp)" si) ; store address of closure first on stack
 155
 156                                         ; codegen the arguments, store them intermediately
 157   (for-each
 158    (lambda (e i)
 159      (begin
 160        (emit "## arg no. ~a" (- i 1))
 161        (codegen-expr e (- si (* wordsize i)) env)
 162                                         ; store intermediate result on stack
 163        (emit "movq %rax, ~a(%rbp)" (- si (* wordsize i)))))
 164
 165    args (range 1 (length args)))
 166
 167                                         ; now that we have everything we need on the stack,
 168                                         ; move them into the param registers
 169
 170   (emit "## moving args into place")
 171   (for-each
 172    (lambda (i) (emit "movq ~a(%rbp), ~a"
 173                      (- si (* wordsize i))
 174                      (param-register i)))
 175    (range 1 (length args)))
 176
 177                                         ; todo: can this be made more efficient
 178   (emit "movq ~a(%rbp), %rax" si)       ; load back pointer to closure
 179
 180   (emit "## moving captives into place")
 181
 182                                         ; move captives into first argument
 183   (emit "movq %rax, %rbx")
 184   (emit "addq $8, %rbx")
 185   (emit "movq %rbx, ~a" (param-register 0))
 186
 187   (emit "## performing call")
 188
 189   (emit "addq $~a, %rsp" si) ; adjust the stack pointer to account all the stuff we put in the env
 190   (emit "callq *(%rax)")                ; call closure function
 191   (emit "subq $~a, %rsp" si))
 192
 193                                         ; LAMBDAS:
 194                                         ; 1st param: pointer to captured args
 195                                         ; 2nd param: 1st arg
 196                                         ; 3rd param: 2nd arg, etc.
 197
 198 (define (codegen-lambda l)
 199   (let* ((label (car l))
 200          (stuff (cdr l))
 201          (captured (car stuff))
 202          (args (cadr stuff))
 203          (body (caddr stuff))
 204                                         ; params = what actually gets passed
 205          (params (append captured args))
 206
 207          (stack-offsets (map (lambda (i)
 208                                (* (- wordsize) i))
 209                              (range 0 (length params))))
 210
 211          (env (map cons params stack-offsets)))
 212     (emit "~a:" label)
 213
 214     (display "## lambda captives: ")
 215     (display captured)
 216     (newline)
 217     (display "## lambda args: ")
 218     (display args)
 219     (newline)
 220     (display "## lambda body: ")
 221     (display body)
 222     (newline)
 223
 224     (emit "push %rbp") ; preserve caller's base pointer
 225
 226     (emit "movq %rsp, %rbp") ; set up our own base pointer
 227     (emit "subq $8, %rbp")
 228
 229                                         ; load the captured vars onto the stack
 230     (for-each
 231      (lambda (i)
 232        (begin
 233          (emit "movq ~a(~a), %rbx" i (param-register 0))
 234          (emit "movq %rbx, ~a(%rbp)" (* (- wordsize) i))))
 235      (range 0 (length captured)))
 236
 237                                         ; load the args onto the stack
 238     (for-each
 239      (lambda (i)
 240        (begin
 241          (emit "movq ~a, %rbx" (param-register (+ 1 i)))
 242          (emit "movq %rbx, ~a(%rbp)"
 243                (* (- wordsize)
 244                   (+ (length captured) i)))))
 245      (range 0 (length args)))
 246
 247     (codegen-expr body (* (- wordsize) (+ 1 (length params))) env)
 248
 249     (emit "pop %rbp") ; restore caller's base pointer
 250     (emit "ret")))
 251
 252 (define cur-label 0)
 253 (define (fresh-label)
 254   (set! cur-label (+ 1 cur-label))
 255   (format "label~a" (- cur-label 1)))
 256
 257 (define (codegen-if cond then else si env)
 258   (codegen-expr cond si env)
 259   (emit "cmpq $0, %rax")
 260   (let ((exit-label (fresh-label))
 261         (else-label (fresh-label)))
 262     (emit "je ~a" else-label)
 263     (codegen-expr then si env)
 264     (emit "jmp ~a" exit-label)
 265     (emit "~a:" else-label)
 266     (codegen-expr else si env)
 267     (emit "~a:" exit-label)))
 268
 269 (define (codegen-expr e si env)
 270   (case (ast-type e)
 271     ('closure (codegen-closure (cadr e) (caddr e) si env))
 272     ('app
 273      (case (car e)
 274        ('+ (codegen-add (cdr e) si env))
 275        ('- (codegen-sub (cadr e) (caddr e) si env))
 276        ('* (codegen-mul (cadr e) (caddr e) si env))
 277        ('! (codegen-not (cadr e) si env))
 278        ('= (codegen-eq  (cadr e) (caddr e) si env))
 279        ('bool->int (codegen-expr (cadr e) si env))
 280        ('print (codegen-print (cadr e) si env))
 281        (else (codegen-call (car e) (cdr e) si env))))
 282
 283                                         ; this is a builtin being passed around as a variable
 284     ('builtin (emit "movq $~a, %rax" (builtin-id e)))
 285
 286     ('let (codegen-let (let-bindings e)
 287                        (let-body e)
 288                        si
 289                        env))
 290
 291     ('var (codegen-var e si env))
 292
 293     ('if (codegen-if (cadr e) (caddr e) (cadddr e) si env))
 294
 295     ('bool-literal (emit "movq $~a, %rax" (if e 1 0)))
 296     ('int-literal (emit "movq $~a, %rax" e))
 297
 298     ('static-string (emit "movq ~a@GOTPCREL(%rip), %rax"
 299                           (cadr e)))
 300
 301     (else (error #f "don't know how to codegen this"))))
 302
 303
 304
 305 (define (free-vars prog)
 306   (define bound '())
 307   (define (collect e)
 308     (case (ast-type e)
 309       ('builtin '()) ; do nothing
 310       ('var (if (memq e bound) '() (list e)))
 311       ('lambda
 312           (set! bound (append (lambda-args e) bound))
 313         (collect (lambda-body e)))
 314
 315       ('app (fold-map collect e))
 316       ('let
 317           (let ((bind-fvs (fold-map (lambda (a)
 318                                       ((set! bound (cons (car a) bound))
 319                                        (collect (cdr a))))
 320                                     (let-bindings cadr)))
 321                 (body-fvs (fold-map collect (let-body e))))
 322             (append bind-fvs body-fvs)))
 323       (else '())))
 324   (collect prog))
 325
 326                                         ; ((lambda (x) (+ x y)) 42) => ((closure lambda1 (y)) 42)
 327                                         ;                              [(lambda1 . ((y), (x), (+ x y))]
 328                                         ; for builtins, this generates a closure if it is used
 329                                         ; outside of an immediate app
 330                                         ; but only one closure for each builtin
 331
 332 (define (extract-lambdas program)
 333   (define lambdas '())
 334   (define (add-lambda e)
 335     (let* ((label (fresh-lambda))
 336            (args (lambda-args e))
 337            (captured (free-vars e))
 338            (body (extract (lambda-body e)))
 339            (new-lambda (cons label (list captured args body))))
 340       (set! lambdas (cons new-lambda lambdas))
 341       `(closure ,label ,captured))) ; todo: should we string->symbol?
 342
 343   (define (find-builtin-lambda e)
 344     (let [(l (assq (builtin-name e) lambdas))]
 345       (if l `(closure ,(car l) ,(caadr l)) #f)))
 346
 347   (define (builtin-name e)
 348     (case e
 349       ('+ "_add")
 350       ('- "_sub")
 351       ('* "_mul")
 352       ('! "_not")
 353       ('= "_eq")
 354       ('bool->int "_bool2int")
 355       ('print "_print")
 356       (else (error #f "don't know this builtin"))))
 357   (define (builtin-args e)
 358     (case e
 359       ('+ '(x y))
 360       ('- '(x y))
 361       ('* '(x y))
 362       ('! '(x))
 363       ('= '(x y))
 364       ('bool->int '(x))
 365       ('print '(x))
 366       (else (error #f "don't know this builtin"))))
 367
 368   (define (add-builtin-lambda e)
 369     (let* [(label (builtin-name e))
 370            (captured '())
 371            (args (builtin-args e))
 372            (body `(,e ,@args))
 373            (new-lambda (cons label (list captured args body)))]
 374       (set! lambdas (cons new-lambda lambdas))
 375       `(closure ,label ,captured)))
 376
 377   (define (extract e)
 378     (case (ast-type e)
 379       ('lambda (add-lambda e))
 380       ('let `(let ,(map extract (let-bindings e))
 381                ,@(map extract (let-body e))))
 382       ('app (append
 383                                         ; if a builtin is used as a function, don't generate lambda
 384              (if (eqv? 'builtin (ast-type (car e)))
 385                  (list (car e))
 386                  (list (extract (car e))))
 387              (map extract (cdr e))))
 388
 389       ('builtin
 390        (if (find-builtin-lambda e)
 391            (find-builtin-lambda e)
 392            (add-builtin-lambda e)))
 393
 394
 395       (else (ast-traverse extract e))))
 396   (let ((transformed (extract program)))
 397     (cons lambdas transformed)))
 398
 399 (define (extract-strings program)
 400   (let ((cur-string 0)
 401         (strings '())) ; assoc list of labels -> string
 402     (define (fresh-string)
 403       (set! cur-string (+ cur-string 1))
 404       (format "string~a" (- cur-string 1)))
 405     (define (extract e)
 406       (case (ast-type e)
 407         ('string-literal
 408          (let ((label (fresh-string)))
 409            (set! strings (cons (cons label e) strings))
 410            `(static-string ,label)))
 411         (else (ast-traverse extract e))))
 412     (let ((transformed (extract program)))
 413       (cons strings transformed))))
 414
 415 (define (emit-string-data s)
 416   (emit "~a:" (car s))
 417   (emit "\t.string \"~a\"" (cdr s)))
 418
 419 ;; (define (amd64-abi f)
 420 ;;                                      ; preserve registers
 421 ;;   (emit "push %rbp")
 422 ;;   ;; (emit "push %rbx")
 423 ;;   ;; (for-each (lambda (i)
 424 ;;   ;;               (emit (string-append
 425 ;;   ;;                      "push %r"
 426 ;;   ;;                      (number->string i))))
 427 ;;   ;;             '(12 13 14 15))
 428
 429 ;;   (emit "movq %rsp, %rbp")              ; set up the base pointer
 430
 431 ;;   (f) ; call stuff
 432 ;;                                      ; restore preserved registers
 433 ;;   ;; (for-each (lambda (i)
 434 ;;   ;;               (emit (string-append
 435 ;;   ;;                      "pop %r"
 436 ;;   ;;                      (number->string i))))
 437 ;;   ;;             '(15 14 13 12))
 438 ;;   ;; (emit "pop %rbx")
 439 ;;   (emit "pop %rbp")
 440 ;;   (emit "ret"))
 441
 442                                         ; 24(%rbp) mem arg 1
 443                                         ; 16(%rbp) mem arg 0          prev frame
 444                                         ; -----------------------
 445                                         ;  8(%rbp) return address     cur frame
 446                                         ;  0(%rbp) prev %rbp
 447                                         ; -8(%rbp) do what you want
 448                                         ;  ...     do what you want
 449                                         ;  0(%rsp) do what you want
 450
 451 (define (param-register n)
 452   (case n
 453     (0 "%rdi")
 454     (1 "%rsi")
 455     (2 "%rdx")
 456     (3 "%rcx")
 457     (4 "%r8")
 458     (5 "%r9")
 459     (else (error #f "need to test out the below"))
 460     (else (format "~a(%rsp)" (- n 6)))))
 461
 462 (define (initialize-heap)
 463   (let ((mmap
 464          (case target
 465            ('darwin "0x20000c5")
 466            ('linux "9"))))
 467                                         ; allocate some heap memory
 468     (emit "mov $~a, %rax" mmap) ; mmap
 469     (emit "xor %rdi, %rdi")  ; addr = null
 470     (emit "movq $1024, %rsi")   ; length = 1kb
 471     (emit "movq $0x3, %rdx") ; prot = read | write = 0x2 | 0x1
 472                                         ;    flags = anonymous | private
 473     (case target
 474       ('darwin (emit "movq $0x1002, %r10")) ; anon = 0x1000, priv = 0x02
 475       ('linux (emit "movq $0x22, %r10")))   ; anon = 0x20,   priv = 0x02
 476     (emit "movq $-1, %r8") ; fd = -1
 477     (emit "xor %r9, %r9") ; offset = 0
 478     (emit "syscall")
 479                                         ; %rax now contains pointer to the start of the heap
 480                                         ; keep track of it
 481
 482     (emit "movq heap_start@GOTPCREL(%rip), %rsi")
 483     (emit "movq %rax, (%rsi)")))
 484
 485 (define (codegen program)
 486   (let* ((extract-res-0 (extract-strings program))
 487          (strings (car extract-res-0))
 488          (extract-res-1 (extract-lambdas (cdr extract-res-0)))
 489          (lambdas (car extract-res-1))
 490          (xform-prog (cdr extract-res-1)))
 491
 492     (emit "\t.global _start")
 493     (emit "\t.text")
 494                                         ;    (emit ".p2align 4,,15") is this needed?
 495
 496     (for-each codegen-lambda lambdas)
 497
 498     (emit "_start:")
 499
 500     (initialize-heap)
 501
 502     (emit "movq %rsp, %rbp")            ; set up the base pointer
 503     (codegen-expr xform-prog 0 '())
 504
 505                                         ; exit syscall
 506     (emit "mov %rax, %rdi")
 507     (case target
 508       ('darwin (emit "movq $0x2000001, %rax"))
 509       ('linux (emit "mov $60, %rax")))
 510     (emit "syscall")
 511
 512     (emit ".data")
 513
 514     (emit "heap_start:")
 515     (emit "\t.quad 0")
 516
 517     (for-each emit-string-data strings)))
 518
 519 (define (compile-to-binary program output t)
 520   (set! target t)
 521   (when (not (eq? (typecheck program) 'int)) (error #f "not an int"))
 522   (let ([tmp-path "/tmp/a.s"])
 523     (when (file-exists? tmp-path) (delete-file tmp-path))
 524     (with-output-to-file tmp-path
 525       (lambda () (codegen program)))
 526
 527     (case target
 528       ('darwin
 529        (system "as /tmp/a.s -o /tmp/a.o")
 530        (system (format "ld /tmp/a.o -e _start -macosx_version_min 10.14 -static -o ~a" output)))
 531       ('linux
 532        (system "as /tmp/a.s -o /tmp/a.o")
 533        (system (format "ld /tmp/a.o -o ~a" output))))))
 534
 535 ; NOTES
 536 ; syscalls in linux and darwin use the following arguments for syscall instruction:
 537 ; %rax = syscall #
 538 ; %rdi = 1st arg
 539 ; %rsi = 2nd arg
 540 ; %rdx = 3rd arg
 541 ; %r10 = 4th arg
 542 ; %r8  = 5th arg
 543 ; %r9  = 6th arg
 544
 545 ; on darwin, the syscall is offset by 0x2000000
 546 ; https://opensource.apple.com/source/xnu/xnu-2782.20.48/bsd/kern/syscalls.master
 547 ; documentation for most syscalls: /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX.sdk/usr/include/sys