ast.scm

   1 (load "utils.scm")
   2
   3 (define (ast-type x)
   4   (define (builtin? x)
   5     (case x
   6       ('+ #t)
   7       ('- #t)
   8       ('* #t)
   9       ('! #t)
  10       ('= #t)
  11       ('bool->int #t)
  12       ('print #t)
  13       (else #f)))
  14   (cond
  15    ((list? x)
  16     (case (car x)
  17       ('if 'if)
  18       ('let 'let)
  19       ('lambda 'lambda)
  20       ('closure 'closure) ; only available in codegen
  21       ('static-string 'static-string) ; only available in codegen
  22       ('stack 'stack) ; only available in codegen (tag that value is passed via stack)
  23       (else 'app)))
  24    ((builtin? x) 'builtin)
  25    ((symbol? x) 'var)
  26    ((integer? x) 'int-literal)
  27    ((boolean? x) 'bool-literal)
  28    ((string? x) 'string-literal)))
  29
  30 (define (ast-traverse f x)
  31   (case (ast-type x)
  32     ('let `(let ,(map (lambda (x) (list (car x) (f (cadr x))))
  33                       (let-bindings x))
  34              ,@(map f (let-body x))))
  35     ('app (map f x))
  36     ('lambda `(lambda ,(lambda-args x) ,(f (lambda-body x))))
  37     ('if `(if ,@(map f (cdr x))))
  38     ('stack `(stack ,(cadr x) ,(f (caddr x))))
  39     (else x)))
  40
  41 (define (ast-collect f x)
  42   (define (inner y) (ast-collect f y))
  43   (case (ast-type x)
  44     ['let (append (f x)
  45                   (flat-map inner (let-bindings x))
  46                   (flat-map inner (let-body x)))]
  47     ['app (append (f x)
  48                   (flat-map inner x))]
  49     ['lambda (append (f x)
  50                      (inner (lambda-body x)))]
  51     ['if (append (f x)
  52                  (flat-map inner (cdr x)))]
  53     ['stack (append (f x)
  54                     (inner (caddr x)))]
  55     [else (f x)]))
  56
  57 (define (ast-find p x)
  58   (define (inner y) (ast-find p y))
  59   (define (any p x) (fold-left
  60                      (lambda (acc y) (if acc #t (p y)))
  61                      #f
  62                      x))
  63   (define (either . fs)
  64     (if (null? fs) #f
  65         (if (car fs) (car fs)
  66             (apply either (cdr fs)))))
  67
  68   (case (ast-type x)
  69     ['let (either (p x)
  70                   (any inner (let-bindings x))
  71                   (any inner (let-body x)))]
  72     ['app (either (p x)
  73                   (any inner x))]
  74     ['lambda (either (p x)
  75                      (inner (lambda-body x)))]
  76     ['if (either (p x) (any inner (cdr x)))]
  77     ['stack (either (p x) (inner (caddr x)))]
  78     [else (p x)]))
  79
  80 (define let-bindings cadr)
  81 (define let-body cddr)
  82
  83                                         ; (let ([(foo a b) (foo 123 345)]) a)
  84                                         ;   |
  85                                         ;   v
  86                                         ; (let ([a (foo~0 (foo 123 345)]
  87                                         ;       [b (foo~1 (foo 123 345)]) a)
  88 (define (expand-pattern-matches program)
  89   (define (go x)
  90     (define (pattern-match binding)
  91       (let ([binding-name (car binding)]
  92             [body (cadr binding)])
  93         (if (eqv? (ast-type binding-name) 'var)
  94             (list (list binding-name body))
  95
  96             (let* ([sum-name (car binding-name)]
  97                    [destructor (lambda (i) (dtor-name sum-name i))]
  98                    [products (cdr binding-name)]
  99
 100                    [data-layouts (program-data-layouts program)]
 101
 102                    [type (data-tor-type data-layouts sum-name)]
 103
 104                    [sums (cdr (assoc type data-layouts))]
 105                    [sum (assoc sum-name sums)]
 106
 107                    [expected-number (length (cdr sum))])
 108
 109                                         ; assert that we only do a let pattern match on an ADT with exactly one sum
 110               (when (not (= 1 (length sums)))
 111                 (error #f (format "Cannot pattern match a ~a in a let since it has ~a possible constructors"
 112                                   type
 113                                   (length sums))))
 114
 115                                         ; assert that there is the correct number of bindings
 116               (when (not (= (length products)
 117                             expected-number))
 118                 (error #f (format "Got ~a bindings: expected ~a for ~a"
 119                                (length products)
 120                                expected-number
 121                                binding)))
 122
 123               (flat-map (lambda (y i)
 124                           (pattern-match (list y `(,(destructor i) ,body))))
 125                         products
 126                         (range 0 (length products)))))))
 127     (case (ast-type x)
 128       ['let `(let ,(flat-map pattern-match (let-bindings x))
 129                ,@(map go (let-body x)))]
 130       [else (ast-traverse go x)]))
 131   (program-map-exprs go program))
 132
 133 (define (lambda? x)
 134   (and (list? x) (eq? (car x) 'lambda)))
 135
 136 (define (statement-type x)
 137   (cond
 138    [(and (list? x)
 139          (eqv? (car x) 'data)) 'data]
 140    [(and (list? x)
 141          (eqv? (car x) 'define)) 'define]
 142    [else 'expr]))
 143
 144
 145                                         ; (A ((foo (Int Bool))
 146                                         ;     (bar (Bool)))
 147 (define (program-data-layouts program)
 148   (map (lambda (x) (cons (car x) (cdr x))) ; convert to assoc list
 149        (map cdr (filter (lambda (x) (eqv? (statement-type x) 'data))
 150                         program))))
 151
 152 (define (program-defines program)
 153   (filter (lambda (x) (eqv? (statement-type x) 'defines))
 154           program))
 155
 156 (define (program-map-exprs f program)
 157   (map (lambda (x)
 158          (case (statement-type x)
 159            ['expr (f x)]
 160            [else x]))
 161        program))
 162
 163 (define (program-body program)
 164   ; hack to have multi-expression bodies
 165   `(let ()
 166      ,@(filter (lambda (x) (eqv? (statement-type x) 'expr))
 167                program)))
 168
 169 (define (data-tor-type data-layouts tor)
 170   (let* ([tors (flat-map data-tors data-layouts)]
 171          [info (cadr (assoc tor tors))])
 172     (car info)))
 173
 174                                         ; a data tor is either a constructor or destructor for an ADT
 175                                         ; data-tors returns constructors and destructors for a data-layout
 176                                         ; (data A (foo Int Bool)
 177                                         ;         (bar Bool))
 178                                         ;        |
 179                                         ;        v
 180                                         ; (foo   . ((A foo constructor) . (abs Int (abs Bool A))))
 181                                         ; (foo~0 . ((A foo 0)           . (abs A Int)))
 182                                         ; (foo~1 . ((A foo 1)           . (abs A Bool)))
 183                                         ; (bar   . ((A bar constructor) . (abs Bool A)))
 184                                         ; (bar~0 . ((A bar 0)           . (abs A Bool)))
 185                                         ;  ------+-------------------------------------
 186                                         ;  tor   | info                 | type
 187
 188 (define (data-tors data-layout)
 189   (define (constructor-type t products)
 190     (fold-right (lambda (x acc) `(abs ,x ,acc)) t products))
 191
 192   (define (destructor ctor-name prod-type part-type index)
 193     (let ([name (dtor-name ctor-name index)])
 194       (cons name (cons (list prod-type ctor-name index) `(abs ,prod-type ,part-type)))))
 195
 196   (let ([type-name (car data-layout)]
 197         [ctors (cdr data-layout)])
 198     (fold-right
 199      (lambda (ctor acc)
 200        (let* ([ctor-name (car ctor)]
 201               [products (cdr ctor)]
 202
 203               [maker (cons ctor-name (cons (list type-name ctor-name 'constructor) (constructor-type type-name products)))]
 204
 205               [dtors (map (lambda (t i) (destructor ctor-name type-name t i))
 206                           products
 207                           (range 0 (length products)))])
 208          (cons maker (append dtors acc))))
 209      '()
 210      ctors)))
 211
 212                                         ; creates a type environment for a given adt definition
 213 (define (data-tors-type-env data-layout)
 214   (map (lambda (x) (cons (car x) (cddr x))) (data-tors data-layout)))
 215
 216 (define (dtor-name ctor-name index)
 217   (string->symbol
 218    (string-append (symbol->string ctor-name)
 219                   "~"
 220                   (number->string index))))
 221
 222 ; for use in normalized form
 223 (define lambda-arg caadr)
 224 ; for use elsewhere
 225 (define lambda-args cadr)
 226 (define lambda-body caddr)
 227
 228 (define (references prog)
 229   (ast-collect
 230    (lambda (x)
 231      (case (ast-type x)
 232        ['var (list x)]
 233        [else '()]))
 234    prog))
 235
 236 (define (graph bs)
 237   (define (go bs orig-bs)
 238     (if (null? bs)
 239         '(() . ())
 240         (let* [(bind (car bs))
 241
 242                (vert (car bind))
 243                (refs (filter ; only count a reference if its a binding
 244                       (lambda (x) (assoc x orig-bs))
 245                       (references (cdr bind))))
 246                (edges (map (lambda (x) (cons vert x))
 247                            refs))
 248
 249                (rest (if (null? (cdr bs))
 250                          (cons '() '())
 251                          (go (cdr bs) orig-bs)))
 252                (total-verts (cons vert (car rest)))
 253                (total-edges (append edges (cdr rest)))]
 254           (cons total-verts total-edges))))
 255   (go bs bs))
 256
 257 (define (successors graph v)
 258   (define (go v E)
 259     (if (null? E)
 260         '()
 261         (if (eqv? v (caar E))
 262             (cons (cdar E) (go v (cdr E)))
 263             (go v (cdr E)))))
 264   (go v (cdr graph)))
 265
 266                                         ; takes in a graph (pair of vertices, edges)
 267                                         ; returns a list of strongly connected components
 268
 269                                         ; ((x y w) . ((x . y) (x . w) (w . x))
 270
 271                                         ; =>
 272                                         ; .->x->y
 273                                         ; |  |
 274                                         ; |  v
 275                                         ; .--w
 276
 277                                         ; ((x w) (y))
 278
 279                                         ; this uses tarjan's algorithm, to get reverse
 280                                         ; topological sorting for free
 281 (define (sccs graph)
 282
 283   (let* ([indices (make-hash-table)]
 284          [lowlinks (make-hash-table)]
 285          [on-stack (make-hash-table)]
 286          [current 0]
 287          [stack '()]
 288          [result '()])
 289
 290     (define (index v)
 291       (get-hash-table indices v #f))
 292     (define (lowlink v)
 293       (get-hash-table lowlinks v #f))
 294
 295     (letrec
 296         ([strong-connect
 297           (lambda (v)
 298             (begin
 299               (put-hash-table! indices v current)
 300               (put-hash-table! lowlinks v current)
 301               (set! current (+ current 1))
 302               (push! stack v)
 303               (put-hash-table! on-stack v #t)
 304
 305               (for-each
 306                (lambda (w)
 307                  (if (not (hashtable-contains? indices w))
 308                                         ; successor w has not been visited, recurse
 309                      (begin
 310                        (strong-connect w)
 311                        (put-hash-table! lowlinks
 312                                         v
 313                                         (min (lowlink v) (lowlink w))))
 314                                         ; successor w has been visited
 315                      (when (get-hash-table on-stack w #f)
 316                        (put-hash-table! lowlinks v (min (lowlink v) (index w))))))
 317                (successors graph v))
 318
 319               (when (= (index v) (lowlink v))
 320                 (let ([scc
 321                        (let new-scc ()
 322                          (let ([w (pop! stack)])
 323                            (put-hash-table! on-stack w #f)
 324                            (if (eqv? w v)
 325                                (list w)
 326                                (cons w (new-scc)))))])
 327                   (set! result (cons scc result))))))])
 328       (for-each
 329        (lambda (v)
 330          (when (not (hashtable-contains? indices v)) ; v.index == -1
 331            (strong-connect v)))
 332        (car graph)))
 333     result))