ast.scm

   1 (define (ast-type x)
   2   (define (builtin? x)
   3     (case x
   4       ('+ #t)
   5       ('- #t)
   6       ('* #t)
   7       ('! #t)
   8       ('= #t)
   9       ('bool->int #t)
  10       ('print #t)
  11       (else #f)))
  12   (cond
  13    ((list? x)
  14     (case (car x)
  15       ('if 'if)
  16       ('let 'let)
  17       ('lambda 'lambda)
  18       ('closure 'closure) ; only available in codegen
  19       ('static-string 'static-string) ; only available in codegen
  20       ('stack 'stack) ; only available in codegen (tag that value is passed via stack)
  21       (else 'app)))
  22    ((builtin? x) 'builtin)
  23    ((symbol? x) 'var)
  24    ((integer? x) 'int-literal)
  25    ((boolean? x) 'bool-literal)
  26    ((string? x) 'string-literal)))
  27
  28 (define (ast-traverse f x)
  29   (case (ast-type x)
  30     ('let `(let ,(map (lambda (x) (list (car x) (f (cadr x))))
  31                       (let-bindings x))
  32              ,@(map f (let-body x))))
  33     ('app (map f x))
  34     ('lambda `(lambda ,(lambda-args x) ,(f (lambda-body x))))
  35     ('if `(if ,@(map f (cdr x))))
  36     ('stack `(stack ,(cadr x) ,(map f (caddr x))))
  37     (else x)))
  38
  39 (define (ast-collect f x)
  40   (define (inner y) (ast-collect f y))
  41   (case (ast-type x)
  42     ['let (append (f x)
  43                   (flat-map inner (let-bindings x))
  44                   (flat-map inner (let-body x)))]
  45     ['app (append (f x)
  46                   (flat-map inner x))]
  47     ['lambda (append (f x)
  48                      (inner (lambda-body x)))]
  49     ['if (append (f x)
  50                  (flat-map inner (cdr x)))]
  51     ['stack (append (f x)
  52                     (inner (caddr x)))]
  53     [else (f x)]))
  54
  55 (define (ast-find p x)
  56   (define (inner y) (ast-find p y))
  57   (define (any p x) (fold-left
  58                      (lambda (acc y) (if acc #t (p y)))
  59                      #f
  60                      x))
  61   (define (either . fs)
  62     (if (null? fs) #f
  63         (if (car fs) (car fs)
  64             (apply either (cdr fs)))))
  65
  66   (case (ast-type x)
  67     ['let (either (p x)
  68                   (any inner (let-bindings x))
  69                   (any inner (let-body x)))]
  70     ['app (either (p x)
  71                   (any inner x))]
  72     ['lambda (either (p x)
  73                      (inner (lambda-body x)))]
  74     ['if (either (p x) (any inner (cdr x)))]
  75     ['stack (either (p x) (inner (caddr x)))]
  76     [else (p x)]))
  77
  78 (define let-bindings cadr)
  79 (define let-body cddr)
  80
  81                                         ; (let ([(foo a b) (foo 123 345)]) a)
  82                                         ;   |
  83                                         ;   v
  84                                         ; (let ([a (foo~0 (foo 123 345)]
  85                                         ;       [b (foo~1 (foo 123 345)]) a)
  86 (define (expand-pattern-matches program)
  87   (define (go x)
  88     (define (pattern-match binding)
  89       (let ([binding-name (car binding)]
  90             [body (cadr binding)])
  91         (if (eqv? (ast-type binding-name) 'var)
  92             (list (list binding-name body))
  93
  94             (let* ([sum-name (car binding-name)]
  95                    [destructor (lambda (i) (dtor-name sum-name i))]
  96                    [products (cdr binding-name)]
  97
  98                    [data-layouts (program-data-layouts program)]
  99
 100                    [type (data-tor-type data-layouts sum-name)]
 101
 102                    [sum (assoc sum-name (cdr (assoc type data-layouts)))]
 103
 104                    [expected-number (length (cdr sum))])
 105
 106                                         ; assert that there is the correct number of bindings
 107               (when (not (= (length products)
 108                             expected-number))
 109                 (error #f (format "Got ~a bindings: expected ~a for ~a"
 110                                (length products)
 111                                expected-number
 112                                binding)))
 113
 114               (flat-map (lambda (y i)
 115                           (pattern-match (list y `(,(destructor i) ,body))))
 116                         products
 117                         (range 0 (length products)))))))
 118     (case (ast-type x)
 119       ['let `(let ,(flat-map pattern-match (let-bindings x))
 120                ,@(map go (let-body x)))]
 121       [else (ast-traverse go x)]))
 122   (program-map-exprs go program))
 123
 124 (define (lambda? x)
 125   (and (list? x) (eq? (car x) 'lambda)))
 126
 127 (define (statement-type x)
 128   (cond
 129    [(and (list? x)
 130          (eqv? (car x) 'data)) 'data]
 131    [(and (list? x)
 132          (eqv? (car x) 'define)) 'define]
 133    [else 'expr]))
 134
 135
 136                                         ; (A ((foo (Int Bool))
 137                                         ;     (bar (Bool)))
 138 (define (program-data-layouts program)
 139   (map (lambda (x) (cons (car x) (cdr x))) ; convert to assoc list
 140        (map cdr (filter (lambda (x) (eqv? (statement-type x) 'data))
 141                         program))))
 142
 143 (define (program-defines program)
 144   (filter (lambda (x) (eqv? (statement-type x) 'defines))
 145           program))
 146
 147 (define (program-map-exprs f program)
 148   (map (lambda (x)
 149          (case (statement-type x)
 150            ['expr (f x)]
 151            [else x]))
 152        program))
 153
 154 (define (program-body program)
 155   ; hack to have multi-expression bodies
 156   `(let ()
 157      ,@(filter (lambda (x) (eqv? (statement-type x) 'expr))
 158                program)))
 159
 160 (define (data-tor-type data-layouts tor)
 161   (let* ([tors (flat-map data-tors data-layouts)]
 162          [info (cadr (assoc tor tors))])
 163     (car info)))
 164
 165                                         ; a data tor is either a constructor or destructor for an ADT
 166                                         ; data-tors returns constructors and destructors for a data-layout
 167                                         ; (data A (foo Int Bool)
 168                                         ;         (bar Bool))
 169                                         ;        |
 170                                         ;        v
 171                                         ; (foo   . ((A foo constructor) . (abs Int (abs Bool A))))
 172                                         ; (foo~0 . ((A foo 0)           . (abs A Int)))
 173                                         ; (foo~1 . ((A foo 1)           . (abs A Bool)))
 174                                         ; (bar   . ((A bar constructor) . (abs Bool A)))
 175                                         ; (bar~0 . ((A bar 0)           . (abs A Bool)))
 176                                         ;  ------+-------------------------------------
 177                                         ;  tor   | info                 | type
 178
 179 (define (data-tors data-layout)
 180   (define (constructor-type t products)
 181     (fold-right (lambda (x acc) `(abs ,x ,acc)) t products))
 182
 183   (define (destructor ctor-name prod-type part-type index)
 184     (let ([name (dtor-name ctor-name index)])
 185       (cons name (cons (list prod-type ctor-name index) `(abs ,prod-type ,part-type)))))
 186
 187   (let ([type-name (car data-layout)]
 188         [ctors (cdr data-layout)])
 189     (fold-right
 190      (lambda (ctor acc)
 191        (let* ([ctor-name (car ctor)]
 192               [products (cdr ctor)]
 193
 194               [maker (cons ctor-name (cons (list type-name ctor-name 'constructor) (constructor-type type-name products)))]
 195
 196               [dtors (map (lambda (t i) (destructor ctor-name type-name t i))
 197                           products
 198                           (range 0 (length products)))])
 199          (cons maker (append dtors acc))))
 200      '()
 201      ctors)))
 202
 203                                         ; creates a type environment for a given adt definition
 204 (define (data-tors-type-env data-layout)
 205   (map (lambda (x) (cons (car x) (cddr x))) (data-tors data-layout)))
 206
 207 (define (dtor-name ctor-name index)
 208   (string->symbol
 209    (string-append (symbol->string ctor-name)
 210                   "~"
 211                   (number->string index))))
 212
 213 ; for use in normalized form
 214 (define lambda-arg caadr)
 215 ; for use elsewhere
 216 (define lambda-args cadr)
 217 (define lambda-body caddr)
 218
 219 (define (references prog)
 220   (ast-collect
 221    (lambda (x)
 222      (case (ast-type x)
 223        ['var (list x)]
 224        [else '()]))
 225    prog))
 226
 227 (define (graph bs)
 228   (define (go bs orig-bs)
 229     (if (null? bs)
 230         '(() . ())
 231         (let* [(bind (car bs))
 232
 233                (vert (car bind))
 234                (refs (filter ; only count a reference if its a binding
 235                       (lambda (x) (assoc x orig-bs))
 236                       (references (cdr bind))))
 237                (edges (map (lambda (x) (cons vert x))
 238                            refs))
 239
 240                (rest (if (null? (cdr bs))
 241                          (cons '() '())
 242                          (go (cdr bs) orig-bs)))
 243                (total-verts (cons vert (car rest)))
 244                (total-edges (append edges (cdr rest)))]
 245           (cons total-verts total-edges))))
 246   (go bs bs))
 247
 248 (define (successors graph v)
 249   (define (go v E)
 250     (if (null? E)
 251         '()
 252         (if (eqv? v (caar E))
 253             (cons (cdar E) (go v (cdr E)))
 254             (go v (cdr E)))))
 255   (go v (cdr graph)))
 256
 257                                         ; takes in a graph (pair of vertices, edges)
 258                                         ; returns a list of strongly connected components
 259
 260                                         ; ((x y w) . ((x . y) (x . w) (w . x))
 261
 262                                         ; =>
 263                                         ; .->x->y
 264                                         ; |  |
 265                                         ; |  v
 266                                         ; .--w
 267
 268                                         ; ((x w) (y))
 269
 270                                         ; this uses tarjan's algorithm, to get reverse
 271                                         ; topological sorting for free
 272 (define (sccs graph)
 273
 274   (let* ([indices (make-hash-table)]
 275          [lowlinks (make-hash-table)]
 276          [on-stack (make-hash-table)]
 277          [current 0]
 278          [stack '()]
 279          [result '()])
 280
 281     (define (index v)
 282       (get-hash-table indices v #f))
 283     (define (lowlink v)
 284       (get-hash-table lowlinks v #f))
 285
 286     (letrec
 287         ([strong-connect
 288           (lambda (v)
 289             (begin
 290               (put-hash-table! indices v current)
 291               (put-hash-table! lowlinks v current)
 292               (set! current (+ current 1))
 293               (push! stack v)
 294               (put-hash-table! on-stack v #t)
 295
 296               (for-each
 297                (lambda (w)
 298                  (if (not (hashtable-contains? indices w))
 299                                         ; successor w has not been visited, recurse
 300                      (begin
 301                        (strong-connect w)
 302                        (put-hash-table! lowlinks
 303                                         v
 304                                         (min (lowlink v) (lowlink w))))
 305                                         ; successor w has been visited
 306                      (when (get-hash-table on-stack w #f)
 307                        (put-hash-table! lowlinks v (min (lowlink v) (index w))))))
 308                (successors graph v))
 309
 310               (when (= (index v) (lowlink v))
 311                 (let ([scc
 312                        (let new-scc ()
 313                          (let ([w (pop! stack)])
 314                            (put-hash-table! on-stack w #f)
 315                            (if (eqv? w v)
 316                                (list w)
 317                                (cons w (new-scc)))))])
 318                   (set! result (cons scc result))))))])
 319       (for-each
 320        (lambda (v)
 321          (when (not (hashtable-contains? indices v)) ; v.index == -1
 322            (strong-connect v)))
 323        (car graph)))
 324     result))
 325
 326
 327                                         ; utils
 328
 329 (define (range s n)
 330   (if (= 0 n) '()
 331       (append (range s (- n 1))
 332               (list (+ s (- n 1))))))
 333
 334 (define (flat-map f . xs) (fold-left append '() (apply map (cons f xs))))
 335 (define (repeat x n) (if (<= n 0) '()
 336                          (cons x (repeat x (- n 1)))))
 337
 338
 339 (define-syntax push!
 340   (syntax-rules ()
 341     ((_ s x) (set! s (cons x s)))))
 342
 343 (define-syntax pop!
 344   (syntax-rules ()
 345     ((_ s) (let ([x (car s)])
 346              (set! s (cdr s))
 347              x))))