ast.scm

   1 (define (ast-type x)
   2   (define (builtin? x)
   3     (case x
   4       ('+ #t)
   5       ('- #t)
   6       ('* #t)
   7       ('! #t)
   8       ('= #t)
   9       ('bool->int #t)
  10       ('print #t)
  11       (else #f)))
  12   (cond
  13    ((list? x)
  14     (case (car x)
  15       ('if 'if)
  16       ('let 'let)
  17       ('lambda 'lambda)
  18       ('closure 'closure) ; only available in codegen
  19       ('static-string 'static-string) ; only available in codegen
  20       ('stack 'stack) ; only available in codegen (tag that value is passed via stack)
  21       (else 'app)))
  22    ((builtin? x) 'builtin)
  23    ((symbol? x) 'var)
  24    ((integer? x) 'int-literal)
  25    ((boolean? x) 'bool-literal)
  26    ((string? x) 'string-literal)))
  27
  28 (define (ast-traverse f x)
  29   (case (ast-type x)
  30     ('let `(let ,(map (lambda (x) (list (car x) (f (cadr x))))
  31                       (let-bindings x))
  32              ,@(map f (let-body x))))
  33     ('app (map f x))
  34     ('lambda `(lambda ,(lambda-args x) ,(f (lambda-body x))))
  35     ('if `(if ,@(map f (cdr x))))
  36     ('stack `(stack ,(cadr x) ,(map f (caddr x))))
  37     (else x)))
  38
  39 (define (ast-collect f x)
  40   (define (inner y) (ast-collect f y))
  41   (case (ast-type x)
  42     ['let (append (f x)
  43                   (flat-map inner (let-bindings x))
  44                   (flat-map inner (let-body x)))]
  45     ['app (append (f x)
  46                   (flat-map inner x))]
  47     ['lambda (append (f x)
  48                      (inner (lambda-body x)))]
  49     ['if (append (f x)
  50                  (flat-map inner (cdr x)))]
  51     ['stack (append (f x)
  52                     (inner (caddr x)))]
  53     [else (f x)]))
  54
  55 (define (ast-find p x)
  56   (define (inner y) (ast-find p y))
  57   (define (any p x) (fold-left
  58                      (lambda (acc y) (if acc #t (p y)))
  59                      #f
  60                      x))
  61   (define (either . fs)
  62     (if (null? fs) #f
  63         (if (car fs) (car fs)
  64             (apply either (cdr fs)))))
  65
  66   (case (ast-type x)
  67     ['let (either (p x)
  68                   (any inner (let-bindings x))
  69                   (any inner (let-body x)))]
  70     ['app (either (p x)
  71                   (any inner x))]
  72     ['lambda (either (p x)
  73                      (inner (lambda-body x)))]
  74     ['if (either (p x) (any inner (cdr x)))]
  75     ['stack (either (p x) (inner (caddr x)))]
  76     [else (p x)]))
  77
  78 (define let-bindings cadr)
  79 (define let-body cddr)
  80
  81                                         ; (let ([(foo a b) (foo 123 345)]) a)
  82                                         ;   |
  83                                         ;   v
  84                                         ; (let ([a (foo~0 (foo 123 345)]
  85                                         ;       [b (foo~1 (foo 123 345)]) a)
  86 (define (expand-pattern-matches program)
  87   (define (go x)
  88     (define (pattern-match binding)
  89       (let ([binding-name (car binding)]
  90             [body (cadr binding)])
  91         (if (eqv? (ast-type binding-name) 'var)
  92             (list (list binding-name body))
  93
  94             (let* ([sum-name (car binding-name)]
  95                    [destructor (lambda (i) (dtor-name sum-name i))]
  96                    [products (cdr binding-name)]
  97
  98                    [data-layouts (program-data-layouts program)]
  99
 100                    [type (data-tor-type data-layouts sum-name)]
 101
 102                    [sums (cdr (assoc type data-layouts))]
 103                    [sum (assoc sum-name sums)]
 104
 105                    [expected-number (length (cdr sum))])
 106
 107                                         ; assert that we only do a let pattern match on an ADT with exactly one sum
 108               (when (not (= 1 (length sums)))
 109                 (error #f (format "Cannot pattern match a ~a in a let since it has ~a possible constructors"
 110                                   type
 111                                   (length sums))))
 112
 113                                         ; assert that there is the correct number of bindings
 114               (when (not (= (length products)
 115                             expected-number))
 116                 (error #f (format "Got ~a bindings: expected ~a for ~a"
 117                                (length products)
 118                                expected-number
 119                                binding)))
 120
 121               (flat-map (lambda (y i)
 122                           (pattern-match (list y `(,(destructor i) ,body))))
 123                         products
 124                         (range 0 (length products)))))))
 125     (case (ast-type x)
 126       ['let `(let ,(flat-map pattern-match (let-bindings x))
 127                ,@(map go (let-body x)))]
 128       [else (ast-traverse go x)]))
 129   (program-map-exprs go program))
 130
 131 (define (lambda? x)
 132   (and (list? x) (eq? (car x) 'lambda)))
 133
 134 (define (statement-type x)
 135   (cond
 136    [(and (list? x)
 137          (eqv? (car x) 'data)) 'data]
 138    [(and (list? x)
 139          (eqv? (car x) 'define)) 'define]
 140    [else 'expr]))
 141
 142
 143                                         ; (A ((foo (Int Bool))
 144                                         ;     (bar (Bool)))
 145 (define (program-data-layouts program)
 146   (map (lambda (x) (cons (car x) (cdr x))) ; convert to assoc list
 147        (map cdr (filter (lambda (x) (eqv? (statement-type x) 'data))
 148                         program))))
 149
 150 (define (program-defines program)
 151   (filter (lambda (x) (eqv? (statement-type x) 'defines))
 152           program))
 153
 154 (define (program-map-exprs f program)
 155   (map (lambda (x)
 156          (case (statement-type x)
 157            ['expr (f x)]
 158            [else x]))
 159        program))
 160
 161 (define (program-body program)
 162   ; hack to have multi-expression bodies
 163   `(let ()
 164      ,@(filter (lambda (x) (eqv? (statement-type x) 'expr))
 165                program)))
 166
 167 (define (data-tor-type data-layouts tor)
 168   (let* ([tors (flat-map data-tors data-layouts)]
 169          [info (cadr (assoc tor tors))])
 170     (car info)))
 171
 172                                         ; a data tor is either a constructor or destructor for an ADT
 173                                         ; data-tors returns constructors and destructors for a data-layout
 174                                         ; (data A (foo Int Bool)
 175                                         ;         (bar Bool))
 176                                         ;        |
 177                                         ;        v
 178                                         ; (foo   . ((A foo constructor) . (abs Int (abs Bool A))))
 179                                         ; (foo~0 . ((A foo 0)           . (abs A Int)))
 180                                         ; (foo~1 . ((A foo 1)           . (abs A Bool)))
 181                                         ; (bar   . ((A bar constructor) . (abs Bool A)))
 182                                         ; (bar~0 . ((A bar 0)           . (abs A Bool)))
 183                                         ;  ------+-------------------------------------
 184                                         ;  tor   | info                 | type
 185
 186 (define (data-tors data-layout)
 187   (define (constructor-type t products)
 188     (fold-right (lambda (x acc) `(abs ,x ,acc)) t products))
 189
 190   (define (destructor ctor-name prod-type part-type index)
 191     (let ([name (dtor-name ctor-name index)])
 192       (cons name (cons (list prod-type ctor-name index) `(abs ,prod-type ,part-type)))))
 193
 194   (let ([type-name (car data-layout)]
 195         [ctors (cdr data-layout)])
 196     (fold-right
 197      (lambda (ctor acc)
 198        (let* ([ctor-name (car ctor)]
 199               [products (cdr ctor)]
 200
 201               [maker (cons ctor-name (cons (list type-name ctor-name 'constructor) (constructor-type type-name products)))]
 202
 203               [dtors (map (lambda (t i) (destructor ctor-name type-name t i))
 204                           products
 205                           (range 0 (length products)))])
 206          (cons maker (append dtors acc))))
 207      '()
 208      ctors)))
 209
 210                                         ; creates a type environment for a given adt definition
 211 (define (data-tors-type-env data-layout)
 212   (map (lambda (x) (cons (car x) (cddr x))) (data-tors data-layout)))
 213
 214 (define (dtor-name ctor-name index)
 215   (string->symbol
 216    (string-append (symbol->string ctor-name)
 217                   "~"
 218                   (number->string index))))
 219
 220 ; for use in normalized form
 221 (define lambda-arg caadr)
 222 ; for use elsewhere
 223 (define lambda-args cadr)
 224 (define lambda-body caddr)
 225
 226 (define (references prog)
 227   (ast-collect
 228    (lambda (x)
 229      (case (ast-type x)
 230        ['var (list x)]
 231        [else '()]))
 232    prog))
 233
 234 (define (graph bs)
 235   (define (go bs orig-bs)
 236     (if (null? bs)
 237         '(() . ())
 238         (let* [(bind (car bs))
 239
 240                (vert (car bind))
 241                (refs (filter ; only count a reference if its a binding
 242                       (lambda (x) (assoc x orig-bs))
 243                       (references (cdr bind))))
 244                (edges (map (lambda (x) (cons vert x))
 245                            refs))
 246
 247                (rest (if (null? (cdr bs))
 248                          (cons '() '())
 249                          (go (cdr bs) orig-bs)))
 250                (total-verts (cons vert (car rest)))
 251                (total-edges (append edges (cdr rest)))]
 252           (cons total-verts total-edges))))
 253   (go bs bs))
 254
 255 (define (successors graph v)
 256   (define (go v E)
 257     (if (null? E)
 258         '()
 259         (if (eqv? v (caar E))
 260             (cons (cdar E) (go v (cdr E)))
 261             (go v (cdr E)))))
 262   (go v (cdr graph)))
 263
 264                                         ; takes in a graph (pair of vertices, edges)
 265                                         ; returns a list of strongly connected components
 266
 267                                         ; ((x y w) . ((x . y) (x . w) (w . x))
 268
 269                                         ; =>
 270                                         ; .->x->y
 271                                         ; |  |
 272                                         ; |  v
 273                                         ; .--w
 274
 275                                         ; ((x w) (y))
 276
 277                                         ; this uses tarjan's algorithm, to get reverse
 278                                         ; topological sorting for free
 279 (define (sccs graph)
 280
 281   (let* ([indices (make-hash-table)]
 282          [lowlinks (make-hash-table)]
 283          [on-stack (make-hash-table)]
 284          [current 0]
 285          [stack '()]
 286          [result '()])
 287
 288     (define (index v)
 289       (get-hash-table indices v #f))
 290     (define (lowlink v)
 291       (get-hash-table lowlinks v #f))
 292
 293     (letrec
 294         ([strong-connect
 295           (lambda (v)
 296             (begin
 297               (put-hash-table! indices v current)
 298               (put-hash-table! lowlinks v current)
 299               (set! current (+ current 1))
 300               (push! stack v)
 301               (put-hash-table! on-stack v #t)
 302
 303               (for-each
 304                (lambda (w)
 305                  (if (not (hashtable-contains? indices w))
 306                                         ; successor w has not been visited, recurse
 307                      (begin
 308                        (strong-connect w)
 309                        (put-hash-table! lowlinks
 310                                         v
 311                                         (min (lowlink v) (lowlink w))))
 312                                         ; successor w has been visited
 313                      (when (get-hash-table on-stack w #f)
 314                        (put-hash-table! lowlinks v (min (lowlink v) (index w))))))
 315                (successors graph v))
 316
 317               (when (= (index v) (lowlink v))
 318                 (let ([scc
 319                        (let new-scc ()
 320                          (let ([w (pop! stack)])
 321                            (put-hash-table! on-stack w #f)
 322                            (if (eqv? w v)
 323                                (list w)
 324                                (cons w (new-scc)))))])
 325                   (set! result (cons scc result))))))])
 326       (for-each
 327        (lambda (v)
 328          (when (not (hashtable-contains? indices v)) ; v.index == -1
 329            (strong-connect v)))
 330        (car graph)))
 331     result))
 332
 333
 334                                         ; utils
 335
 336 (define (range s n)
 337   (if (= 0 n) '()
 338       (append (range s (- n 1))
 339               (list (+ s (- n 1))))))
 340
 341 (define (flat-map f . xs) (fold-left append '() (apply map (cons f xs))))
 342 (define (repeat x n) (if (<= n 0) '()
 343                          (cons x (repeat x (- n 1)))))
 344
 345
 346 (define-syntax push!
 347   (syntax-rules ()
 348     ((_ s x) (set! s (cons x s)))))
 349
 350 (define-syntax pop!
 351   (syntax-rules ()
 352     ((_ s) (let ([x (car s)])
 353              (set! s (cdr s))
 354              x))))