[scheme.git] / codegen.scm

(load "typecheck.scm")
(load "ast.scm")

(define target 'darwin)

(define (emit . s)
  (begin
    (apply printf s)
    (display "\n")))

(define (codegen-add xs si env)
  (define (go ys)
    (if (null? ys)
        (emit "movq ~a(%rbp), %rax" si)
        (begin
          (let ((y (car ys)))
            (if (integer? y)
                (emit "addq $~a, ~a(%rbp)" y si)
                (begin
                  (codegen-expr y (- si wordsize) env)
                  (emit "addq %rax, ~a(%rbp)" si))))
          (go (cdr ys)))))
  (begin
                                        ; use si(%rbp) as the accumulator
    (emit "movq $0, ~a(%rbp)" si)
    (go xs)))

(define (codegen-binop opcode)
  (lambda (a b si env)
    (codegen-expr b si env)
    (emit "movq %rax, ~a(%rbp)" si)
    (codegen-expr a (- si wordsize) env)
    (emit "~a ~a(%rbp), %rax" opcode si)))

(define codegen-sub (codegen-binop "sub"))

(define codegen-mul (codegen-binop "imul"))

(define (codegen-not x si env)
  (codegen-expr x si env)
  (emit "notq %rax")
  (emit "andq $1, %rax"))

(define (codegen-eq a b si env)
  (codegen-expr a si env)
  (emit "movq %rax, ~a(%rbp)" si)
  (codegen-expr b (- si wordsize) env)
  (emit "subq ~a(%rbp), %rax" si)
  (emit "not %rax")
  (emit "andq $1, %rax"))

                                        ; 'write file handle addr-string num-bytes

(define (codegen-print x si env)
  (codegen-expr x si env) ; x should be a static-string, producing a label

                                        ; make a copy of string address since %rax and %rdi are clobbered
  (emit "mov %rax, %rbx")
  
                                        ; get the length of the null terminated string
  (emit "mov %rax, %rdi")
  (emit "xor %al, %al")   ; set %al to 0
  (emit "mov $-1, %rcx") ; max search length = max int = -1
  (emit "cld")           ; clear direction flag, search up in memory
  (emit "repne scasb")   ; scan string, %rcx = -strlen - 1 - 1
  
  (emit "not %rcx")      ; -%rcx = strlen + 1
  (emit "dec %rcx")

  (case target
    ('darwin
     (emit "movq %rbx, %rsi") ; string addr
     (emit "movq %rcx, %rdx") ; num bytes
     (emit "movq $1, %rdi")   ; file handle (stdout)
     (emit "movq $0x2000004, %rax")) ; syscall 4 (write)
    ('linux
     (emit "mov %rbx, %rsi")  ; string addr
     (emit "mov %rcx, %rdx")  ; num bytes
     (emit "mov $1, %rax")    ; file handle (stdout)
     (emit "mov $1, %rdi"))) ; syscall 1 (write)
  (emit "syscall"))

(define (range s n)
  (if (= 0 n) '()
      (append (range s (- n 1))
              (list (+ s (- n 1))))))

(define wordsize 8)

(define (codegen-let bindings body si env)
  (let* ((stack-offsets (map (lambda (x) (- si (* x wordsize)))
                             (range 0 (length bindings))))
         (inner-si (- si (* (length bindings) wordsize)))
         (names (map car bindings))
         (exprs (map cadr bindings))

                                        ; recursive let bindings: build environment as we go
         (inner-env (fold-left
                     (lambda (env name expr offset)
                       (codegen-expr expr inner-si env)
                       (emit "movq %rax, ~a(%rbp)" offset)
                       (cons (cons name offset) env))
                     env names exprs stack-offsets)))
    (for-each (lambda (form)
                (codegen-expr form inner-si inner-env))
              body)))

(define (codegen-var name si env)
  (when (not (assoc name env))
    (error #f (format "Variable ~a is not bound" name)))
  (let ((offset (cdr (assoc name env))))
    (emit "movq ~a(%rbp), %rax" offset)))

(define cur-lambda 0)
(define (fresh-lambda)
  (set! cur-lambda (+ 1 cur-lambda))
  (format "_lambda~a" (- cur-lambda 1)))

                                        ; a closure on the heap looks like:
                                        ; 0    8         16        24
                                        ; addr var1....  var2....  var3....

(define (codegen-closure label captured si env)
  (let* ((heap-offsets (map (lambda (i) (+ 8 (* 8 i)))
                            (range 0 (length captured))))) ; 4, 12, 20, etc.

    (emit "## creating closure")

    (emit "movq heap_start@GOTPCREL(%rip), %rbx")
    
    (emit "movq (%rbx), %rax")          ; %rax = heap addr of closure


    ; point heap_start to next space
    (emit "addq $~a, (%rbx)" (+ 8 (* 8 (length captured))))

    (emit "## storing address to lambda")
                                        ; store the address to the lambda code
    (emit "movq ~a@GOTPCREL(%rip), %rbx" label)
    (emit "movq %rbx, 0(%rax)")

    (emit "## storing captives")
                                        ; store the captured vars
    (for-each
     (lambda (var-name new-offset)
       (begin
         (emit "movq ~a(%rbp), %rbx" (cdr (assoc var-name env)))
         (emit "movq %rbx, ~a(%rax)" new-offset)))
     captured
     heap-offsets)))

                                        ; for now we can only call closures
(define (codegen-call f args si env)
  (codegen-expr f si env)

  (emit "## starting call")
  
  (emit "movq %rax, ~a(%rbp)" si) ; store address of closure first on stack
  
                                        ; codegen the arguments, store them intermediately
  (for-each
   (lambda (e i)
     (begin
       (emit "## arg no. ~a" (- i 1))
       (codegen-expr e (- si (* wordsize i)) env)
                                        ; store intermediate result on stack
       (emit "movq %rax, ~a(%rbp)" (- si (* wordsize i)))))

   args (range 1 (length args)))

                                        ; now that we have everything we need on the stack,
                                        ; move them into the param registers

  (emit "## moving args into place")
  (for-each
   (lambda (i) (emit "movq ~a(%rbp), ~a"
                     (- si (* wordsize i))
                     (param-register i)))
   (range 1 (length args)))

                                        ; todo: can this be made more efficient
  (emit "movq ~a(%rbp), %rax" si)       ; load back pointer to closure

  (emit "## moving captives into place")
  
                                        ; move captives into first argument
  (emit "movq %rax, %rbx")
  (emit "addq $8, %rbx")
  (emit "movq %rbx, ~a" (param-register 0))

  (emit "## performing call")

  (emit "addq $~a, %rsp" si) ; adjust the stack pointer to account all the stuff we put in the env
  (emit "callq *(%rax)")                ; call closure function
  (emit "subq $~a, %rsp" si))

                                        ; LAMBDAS:
                                        ; 1st param: pointer to captured args
                                        ; 2nd param: 1st arg
                                        ; 3rd param: 2nd arg, etc.

(define (codegen-lambda l)
  (let* ((label (car l))
         (stuff (cdr l))
         (captured (car stuff))
         (args (cadr stuff))
         (body (caddr stuff))
                                        ; params = what actually gets passed
         (params (append captured args))

         (stack-offsets (map (lambda (i)
                               (* (- wordsize) i))
                             (range 0 (length params))))

         (env (map cons params stack-offsets)))
    (emit "~a:" label)

    (display "## lambda captives: ")
    (display captured)
    (newline)
    (display "## lambda args: ")
    (display args)
    (newline)
    (display "## lambda body: ")
    (display body)
    (newline)
    
    (emit "push %rbp") ; preserve caller's base pointer
    
    (emit "movq %rsp, %rbp") ; set up our own base pointer
    (emit "subq $8, %rbp")   

                                        ; load the captured vars onto the stack
    (for-each
     (lambda (i)
       (begin
         (emit "movq ~a(~a), %rbx" i (param-register 0))
         (emit "movq %rbx, ~a(%rbp)" (* (- wordsize) i))))
     (range 0 (length captured)))

                                        ; load the args onto the stack
    (for-each
     (lambda (i)
       (begin
         (emit "movq ~a, %rbx" (param-register (+ 1 i)))
         (emit "movq %rbx, ~a(%rbp)"
               (* (- wordsize)
                  (+ (length captured) i)))))
     (range 0 (length args)))
    
    (codegen-expr body (* (- wordsize) (+ 1 (length params))) env)

    (emit "pop %rbp") ; restore caller's base pointer
    (emit "ret")))

(define (codegen-string label)
  (case target
    ('darwin (emit "movq ~a@GOTPCREL(%rip), %rax" label))
    ('linux  (emit "lea $~a, %rax" label))))

(define cur-label 0)
(define (fresh-label)
  (set! cur-label (+ 1 cur-label))
  (format "label~a" (- cur-label 1)))

(define (codegen-if cond then else si env)
  (codegen-expr cond si env)
  (emit "cmpq $0, %rax")
  (let ((exit-label (fresh-label))
        (else-label (fresh-label)))
    (emit "je ~a" else-label)
    (codegen-expr then si env)
    (emit "jmp ~a" exit-label)
    (emit "~a:" else-label)
    (codegen-expr else si env)
    (emit "~a:" exit-label)))

(define (codegen-expr e si env)
  (case (ast-type e)
    ('closure (codegen-closure (cadr e) (caddr e) si env))
    ('app
     (case (car e)
       ('+ (codegen-add (cdr e) si env))
       ('- (codegen-sub (cadr e) (caddr e) si env))
       ('* (codegen-mul (cadr e) (caddr e) si env))
       ('! (codegen-not (cadr e) si env))
       ('= (codegen-eq  (cadr e) (caddr e) si env))
       ('bool->int (codegen-expr (cadr e) si env))
       ('print (codegen-print (cadr e) si env))
       (else (codegen-call (car e) (cdr e) si env))))

                                        ; this is a builtin being passed around as a variable
    ('builtin (emit "movq $~a, %rax" (builtin-id e)))

    ('let (codegen-let (let-bindings e)
                       (let-body e)
                       si
                       env))

    ('var (codegen-var e si env))

    ('if (codegen-if (cadr e) (caddr e) (cadddr e) si env))
    
    ('bool-literal (emit "movq $~a, %rax" (if e 1 0)))
    ('int-literal (emit "movq $~a, %rax" e))
    
    ('static-string (codegen-string (cadr e)))

    (else (error #f "don't know how to codegen this"))))


(define (fold-map f x) (fold-left append '() (map f x)))

(define (free-vars prog)
  (define bound '())
  (define (collect e)
    (case (ast-type e)
      ('builtin '()) ; do nothing
      ('var (if (memq e bound) '() (list e)))
      ('lambda
          (set! bound (append (lambda-args e) bound))
        (collect (lambda-body e)))

      ('app (fold-map collect e))
      ('let
          (let ((bind-fvs (fold-map (lambda (a)
                                      ((set! bound (cons (car a) bound))
                                       (collect (cdr a))))
                                    (let-bindings cadr)))
                (body-fvs (fold-map collect (let-body e))))
            (append bind-fvs body-fvs)))
      (else '())))
  (collect prog))

                                        ; ((lambda (x) (+ x y)) 42) => ((closure lambda1 (y)) 42)
                                        ;                              [(lambda1 . ((y), (x), (+ x y))]
                                        ; for builtins, this generates a closure if it is used
                                        ; outside of an immediate app
                                        ; but only one closure for each builtin

(define (extract-lambdas program)
  (define lambdas '())
  (define (add-lambda e)
    (let* ((label (fresh-lambda))
           (args (lambda-args e))
           (captured (free-vars e))
           (body (extract (lambda-body e)))
           (new-lambda (cons label (list captured args body))))
      (set! lambdas (cons new-lambda lambdas))
      `(closure ,label ,captured))) ; todo: should we string->symbol?

  (define (find-builtin-lambda e)
    (let [(l (assq (builtin-name e) lambdas))]
      (if l `(closure ,(car l) ,(caadr l)) #f)))

  (define (builtin-name e)
    (case e
      ('+ "_add")
      ('- "_sub")
      ('* "_mul")
      ('bool->int "_bool2int")
      (else (error #f "fill this out"))))
  (define (builtin-args e)
    (case e
      ('+ '(x y))
      ('- '(x y))
      ('* '(x y))
      ('bool->int '(x))
      (else (error #f "fill this out"))))

  (define (add-builtin-lambda e)
    (let* [(label (builtin-name e))
           (captured '())
           (args (builtin-args e))
           (body `(,e ,@args))
           (new-lambda (cons label (list captured args body)))]
      (set! lambdas (cons new-lambda lambdas))
      `(closure ,label ,captured)))
  
  (define (extract e)
    (case (ast-type e)
      ('lambda (add-lambda e))
      ('let `(let ,(map extract (let-bindings e))
               ,@(map extract (let-body e))))
      ('app (append
                                        ; if a builtin is used as a function, don't generate lambda
             (if (eqv? 'builtin (ast-type (car e)))
                 (list (car e))
                 (list (extract (car e))))
             (map extract (cdr e))))
      
      ('builtin
       (if (find-builtin-lambda e)
           (find-builtin-lambda e)
           (add-builtin-lambda e)))

      
      (else (ast-traverse extract e))))
  (let ((transformed (extract program)))
    (cons lambdas transformed)))

(define (extract-strings program)
  (let ((cur-string 0)
        (strings '())) ; assoc list of labels -> string
    (define (fresh-string)
      (set! cur-string (+ cur-string 1))
      (format "string~a" (- cur-string 1)))
    (define (extract e)
      (case (ast-type e)
        ('string-literal
         (let ((label (fresh-string)))
           (set! strings (cons (cons label e) strings))
           `(static-string ,label)))
        (else (ast-traverse extract e))))
    (let ((transformed (extract program)))
      (cons strings transformed))))

(define (emit-string-data s)
  (emit "~a:" (car s))
  (emit "\t.string \"~a\"" (cdr s)))

;; (define (amd64-abi f)
;;                                      ; preserve registers
;;   (emit "push %rbp")
;;   ;; (emit "push %rbx")
;;   ;; (for-each (lambda (i)
;;   ;;               (emit (string-append
;;   ;;                      "push %r"
;;   ;;                      (number->string i))))
;;   ;;             '(12 13 14 15))

;;   (emit "movq %rsp, %rbp")              ; set up the base pointer

;;   (f) ; call stuff
;;                                      ; restore preserved registers
;;   ;; (for-each (lambda (i)
;;   ;;               (emit (string-append
;;   ;;                      "pop %r"
;;   ;;                      (number->string i))))
;;   ;;             '(15 14 13 12))
;;   ;; (emit "pop %rbx")
;;   (emit "pop %rbp")
;;   (emit "ret"))

                                        ; 24(%rbp) mem arg 1
                                        ; 16(%rbp) mem arg 0          prev frame
                                        ; -----------------------
                                        ;  8(%rbp) return address     cur frame
                                        ;  0(%rbp) prev %rbp
                                        ; -8(%rbp) do what you want
                                        ;  ...     do what you want
                                        ;  0(%rsp) do what you want

(define (param-register n)
  (case n
    (0 "%rdi")
    (1 "%rsi")
    (2 "%rdx")
    (3 "%rcx")
    (4 "%r8")
    (5 "%r9")
    (else (error #f "need to test out the below"))
    (else (format "~a(%rsp)" (- n 6)))))

(define (initialize-heap)
  (let ((mmap
         (case target
           ('darwin "0x20000c5")
           ('linux "9"))))
                                        ; allocate some heap memory
    (emit "mov $~a, %rax" mmap) ; mmap
    (emit "xor %rdi, %rdi")  ; addr = null
    (emit "movq $1024, %rsi")   ; length = 1kb
    (emit "movq $0x3, %rdx") ; prot = read | write = 0x2 | 0x1
                                        ;    flags = anonymous | private
    (case target
      ('darwin (emit "movq $0x1002, %r10")) ; anon = 0x1000, priv = 0x02
      ('linux (emit "movq $0x22, %r10")))   ; anon = 0x20,   priv = 0x02
    (emit "movq $-1, %r8") ; fd = -1
    (emit "xor %r9, %r9") ; offset = 0
    (emit "syscall")
                                        ; %rax now contains pointer to the start of the heap
                                        ; keep track of it

    (emit "movq heap_start@GOTPCREL(%rip), %rsi")
    (emit "movq %rax, (%rsi)")))

(define (codegen program)
  (let* ((extract-res-0 (extract-strings program))
         (strings (car extract-res-0))
         (extract-res-1 (extract-lambdas (cdr extract-res-0)))
         (lambdas (car extract-res-1))
         (xform-prog (cdr extract-res-1)))

    (emit "\t.global _start")
    (emit "\t.text")
                                        ;    (emit ".p2align 4,,15") is this needed?

    (for-each codegen-lambda lambdas)

    (emit "_start:")

    (initialize-heap)

    (emit "movq %rsp, %rbp")            ; set up the base pointer
    (codegen-expr xform-prog 0 '())

                                        ; exit syscall
    (emit "mov %rax, %rdi")
    (case target
      ('darwin (emit "movq $0x2000001, %rax"))
      ('linux (emit "mov $60, %rax")))
    (emit "syscall")

    (emit ".data")

    (emit "heap_start:")
    (emit "\t.quad 0")

    (for-each emit-string-data strings)))

(define (compile-to-binary program output t)
  (set! target t)
  (when (not (eq? (typecheck program) 'int)) (error #f "not an int"))
  (let ([tmp-path "/tmp/a.s"])
    (when (file-exists? tmp-path) (delete-file tmp-path))
    (with-output-to-file tmp-path
      (lambda () (codegen program)))

    (case target
      ('darwin
       (system "as /tmp/a.s -o /tmp/a.o")
       (system (format "ld /tmp/a.o -e _start -macosx_version_min 10.14 -static -o ~a" output)))
      ('linux
       (system "as /tmp/a.s -o /tmp/a.o")
       (system (format "ld /tmp/a.o -o ~a" output))))))

; NOTES
; syscalls in linux and darwin use the following arguments for syscall instruction:
; %rax = syscall #
; %rdi = 1st arg
; %rsi = 2nd arg
; %rdx = 3rd arg
; %r10 = 4th arg
; %r8  = 5th arg
; %r9  = 6th arg

; on darwin, the syscall is offset by 0x2000000
; https://opensource.apple.com/source/xnu/xnu-2782.20.48/bsd/kern/syscalls.master
; documentation for most syscalls: /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX.sdk/usr/include/sys