codegen.scm

   1 (load "typecheck.scm")
   2 (load "ast.scm")
   3
   4 (define (emit . s)
   5   (begin
   6     (apply printf s)
   7     (display "\n")))
   8
   9 (define (codegen-add xs si env)
  10   (define (go ys)
  11     (if (null? ys)
  12       (emit "movq ~a(%rbp), %rax" si)
  13       (begin
  14         (let ((y (car ys)))
  15              (if (integer? y)
  16                  (emit "addq $~a, ~a(%rbp)" y si)
  17                  (begin
  18                    (codegen-expr y (- si wordsize) env)
  19                    (emit "addq %rax, ~a(%rbp)" si))))
  20         (go (cdr ys)))))
  21   (begin
  22                                         ; use si(%rbp) as the accumulator
  23     (emit "movq $0, ~a(%rbp)" si)
  24     (go xs)))
  25
  26 (define (codegen-binop opcode)
  27   (lambda (a b si env)
  28     (codegen-expr b si env)
  29     (emit "movq %rax, ~a(%rbp)" si)
  30     (codegen-expr a (- si wordsize) env)
  31     (emit "~a ~a(%rbp), %rax" opcode si)))
  32
  33 (define codegen-sub (codegen-binop "sub"))
  34
  35 (define codegen-mul (codegen-binop "imul"))
  36
  37 (define (codegen-not x si env)
  38   (codegen-expr x si env)
  39   (emit "notq %rax")
  40   (emit "andq $1, %rax"))
  41
  42 (define (codegen-eq a b si env)
  43   (codegen-expr a si env)
  44   (emit "movq %rax, ~a(%rbp)" si)
  45   (codegen-expr b (- si wordsize) env)
  46   (emit "subq ~a(%rbp), %rax" si)
  47   (emit "not %rax")
  48   (emit "andq $1, %rax"))
  49
  50 (define (codegen-print x si env)
  51   (codegen-expr x si env) ; x should be a static-string, producing a label
  52
  53                       ; make a copy of string address since %rax and %rdi are clobbered
  54   (emit "mov %rax, %rbx")
  55
  56                       ; get the length of the null terminated string
  57   (emit "mov %rax, %rdi")
  58   (emit "xor %al, %al")   ; set %al to 0
  59   (emit "mov $-1, %rcx") ; max search length = max int = -1
  60   (emit "cld")           ; clear direction flag, search up in memory
  61   (emit "repne scasb")   ; scan string, %rcx = -strlen - 1 - 1
  62
  63   (emit "not %rcx")      ; -%rcx = strlen + 1
  64   (emit "dec %rcx")
  65
  66   (emit "mov %rcx, %rdx") ; number of bytes
  67   (emit "mov %rbx, %rsi") ; addr of string
  68   (emit "mov $1, %rax") ; file handle 1 (stdout)
  69   (emit "mov $1, %rdi") ; syscall 1 (write)
  70   (emit "syscall"))
  71
  72 (define (range s n)
  73   (if (= 0 n) '()
  74       (append (range s (- n 1))
  75               (list (+ s (- n 1))))))
  76
  77 (define wordsize 8)
  78
  79 (define (codegen-let bindings body si env)
  80   (let* ((stack-offsets (map (lambda (x) (- si (* x wordsize)))
  81                              (range 0 (length bindings))))
  82          (inner-si (- si (* (length bindings) wordsize)))
  83          (names (map car bindings))
  84          (exprs (map cadr bindings))
  85
  86          ; recursive let bindings: build environment as we go
  87          (inner-env (fold-left
  88                      (lambda (env name expr offset)
  89                        (codegen-expr expr inner-si env)
  90                        (emit "movq %rax, ~a(%rbp)" offset)
  91                        (cons (cons name offset) env))
  92                      env names exprs stack-offsets)))
  93     (for-each (lambda (form)
  94                 (codegen-expr form inner-si inner-env))
  95               body)))
  96
  97 (define (codegen-var name si env)
  98   (when (not (assoc name env))
  99     (error #f (format "Variable ~a is not bound" name)))
 100   (let ((offset (cdr (assoc name env))))
 101     (emit "movq ~a(%rbp), %rax" offset)))
 102
 103 (define cur-lambda 0)
 104 (define (fresh-lambda)
 105   (set! cur-lambda (+ 1 cur-lambda))
 106   (format "_lambda~a" (- cur-lambda 1)))
 107
 108                                         ; for now we can only call closures
 109 (define (codegen-call closure args si env)
 110   (when (not (eq? (ast-type closure) 'closure))
 111     (error #f (format "~a is not a closure" closure)))
 112   (let* ((captured (caddr closure))
 113          (label (cadr closure))
 114          (argument-start (length captured)))
 115
 116                                         ; first move the captured variables into param registers
 117     (for-each
 118      (lambda (e i)
 119        (emit "movq ~a(%rbp), ~a"
 120              (cdr (assoc e env)) ; offset of the var
 121              (param-register i)))
 122      captured (range 0 (length captured)))
 123
 124
 125                                         ; then codegen the arguments and move them into the next param registers
 126     (for-each
 127      (lambda (e i)
 128        (begin
 129          (codegen-expr e si env)
 130                                         ; move result to correct param register
 131          (emit "movq %rax, ~a" (param-register i))))
 132      args (range argument-start (length args)))
 133
 134     (emit "addq $~a, %rsp" si) ; adjust the stack pointer to account all the stuff we put in the env
 135     (emit "callq ~a" label)
 136     (emit "subq $~a, %rsp" si)))
 137
 138 (define (codegen-lambda l)
 139   (let* ((label (car l))
 140          (args (cadr l))
 141          (captured (caddr l))
 142          (body (cadddr l))
 143 ; params = what actually gets passed
 144          (params (append captured args))
 145
 146          (param-registers (map param-register
 147                                (range 0 (length params))))
 148          (stack-offsets (map (lambda (i)
 149                                (* (- wordsize) i))
 150                              (range 1 (length params))))
 151
 152          (copy-insts (map (lambda (r o)
 153                             (format "movq ~a, ~a(%rbp)" r o))
 154                           param-registers stack-offsets))
 155
 156          (env (map cons params stack-offsets)))
 157     (emit "~a:" label)
 158     (display "## lambda body: ")
 159     (display body)
 160     (newline)
 161     (display "## environment: ")
 162     (display env)
 163     (newline)
 164
 165     (emit "push %rbp") ; preserve caller's base pointer
 166     (emit "movq %rsp, %rbp") ; set up our own base pointer
 167
 168     (for-each emit copy-insts)
 169     (codegen-expr body (* (- wordsize) (+ 1 (length params))) env)
 170
 171     (emit "pop %rbp") ; restore caller's base pointer
 172     (emit "ret")))
 173
 174 (define cur-label 0)
 175 (define (fresh-label)
 176   (set! cur-label (+ 1 cur-label))
 177   (format "label~a" (- cur-label 1)))
 178
 179 (define (codegen-if cond then else si env)
 180   (codegen-expr cond si env)
 181   (emit "cmpq $0, %rax")
 182   (let ((exit-label (fresh-label))
 183         (else-label (fresh-label)))
 184     (emit "je ~a" else-label)
 185     (codegen-expr then si env)
 186     (emit "jmp ~a" exit-label)
 187     (emit "~a:" else-label)
 188     (codegen-expr else si env)
 189     (emit "~a:" exit-label)))
 190
 191 (define (codegen-expr e si env)
 192   (case (ast-type e)
 193     ('builtin e)
 194     ('closure e)
 195     ('app
 196      (let ((callee (codegen-expr (car e) si env)))
 197        (case callee
 198          ('+ (codegen-add (cdr e) si env))
 199          ('- (codegen-sub (cadr e) (caddr e) si env))
 200          ('* (codegen-mul (cadr e) (caddr e) si env))
 201          ('! (codegen-not (cadr e) si env))
 202          ('= (codegen-eq  (cadr e) (caddr e) si env))
 203          ('bool->int (codegen-expr (cadr e) si env))
 204          ('print (codegen-print (cadr e) si env))
 205          (else (codegen-call callee (cdr e) si env)))))
 206
 207     ('let (codegen-let (let-bindings e)
 208                        (let-body e)
 209                        si
 210                        env))
 211
 212     ('var (codegen-var e si env))
 213
 214     ('if (codegen-if (cadr e) (caddr e) (cadddr e) si env))
 215
 216     ('bool-literal (emit "movq $~a, %rax" (if e 1 0)))
 217     ('int-literal (emit "movq $~a, %rax" e))
 218
 219     ('static-string (emit "lea ~a, %rax" (cadr e))) ; move label
 220
 221     (else (error #f "don't know how to codegen this"))))
 222
 223
 224 (define (fold-map f x) (fold-left append '() (map f x)))
 225
 226 (define (free-vars prog)
 227   (define bound '())
 228   (define (collect e)
 229     (case (ast-type e)
 230       ('builtin '()) ; do nothing
 231       ('var (if (memq e bound) '() (list e)))
 232       ('lambda
 233           (set! bound (append (lambda-args e) bound))
 234         (collect (lambda-body e)))
 235
 236       ('app (fold-map collect e))
 237       ('let
 238           (let ((bind-fvs (fold-map (lambda (a)
 239                                       ((set! bound (cons (car a) bound))
 240                                        (collect (cdr a))))
 241                                     (let-bindings cadr)))
 242                 (body-fvs (fold-map collect (let-body e))))
 243             (append bind-fvs body-fvs)))
 244       (else '())))
 245   (collect prog))
 246
 247                                         ; ((lambda (x) (+ x 1)) 42) => {lambda0: (x) (+ x 1)}, (@lambda0 42)
 248 (define (extract-lambdas program)
 249   (define lambdas '())
 250   (define (add-lambda e)
 251     (let* ((label (fresh-lambda))
 252            (args (lambda-args e))
 253            (captured (free-vars e))
 254            (body (extract (lambda-body e)))
 255            (new-lambda (list label args captured body)))
 256       (set! lambdas (cons new-lambda lambdas))
 257       `(closure ,label ,captured))) ; todo: should we string->symbol?
 258   (define (extract e)
 259     (case (ast-type e)
 260       ('lambda (add-lambda e))
 261       ('let `(let ,(map extract (let-bindings e))
 262                ,@(map extract (let-body e))))
 263       ('app (append (list (extract (car e)))
 264                     (map extract (cdr e))))
 265       (else (ast-traverse extract e))))
 266   (let ((transformed (extract program)))
 267     (cons lambdas transformed)))
 268
 269 (define (extract-strings program)
 270   (let ((cur-string 0)
 271         (strings '())) ; assoc list of labels -> string
 272     (define (fresh-string)
 273       (set! cur-string (+ cur-string 1))
 274       (format "string~a" (- cur-string 1)))
 275     (define (extract e)
 276       (case (ast-type e)
 277         ('string-literal
 278          (let ((label (fresh-string)))
 279            (set! strings (cons (cons label e) strings))
 280            `(static-string ,label)))
 281         (else (ast-traverse extract e))))
 282     (let ((transformed (extract program)))
 283       (cons strings transformed))))
 284
 285 (define (emit-string-data s)
 286   (emit "~a:" (car s))
 287   (emit "\t.string \"~a\"" (cdr s)))
 288
 289 ;; (define (amd64-abi f)
 290 ;;                                      ; preserve registers
 291 ;;   (emit "push %rbp")
 292 ;;   ;; (emit "push %rbx")
 293 ;;   ;; (for-each (lambda (i)
 294 ;;   ;;               (emit (string-append
 295 ;;   ;;                      "push %r"
 296 ;;   ;;                      (number->string i))))
 297 ;;   ;;             '(12 13 14 15))
 298
 299 ;;   (emit "movq %rsp, %rbp")              ; set up the base pointer
 300
 301 ;;   (f) ; call stuff
 302 ;;                                      ; restore preserved registers
 303 ;;   ;; (for-each (lambda (i)
 304 ;;   ;;               (emit (string-append
 305 ;;   ;;                      "pop %r"
 306 ;;   ;;                      (number->string i))))
 307 ;;   ;;             '(15 14 13 12))
 308 ;;   ;; (emit "pop %rbx")
 309 ;;   (emit "pop %rbp")
 310 ;;   (emit "ret"))
 311
 312                                         ; 24(%rbp) mem arg 1
 313                                         ; 16(%rbp) mem arg 0          prev frame
 314                                         ; -----------------------
 315                                         ;  8(%rbp) return address     cur frame
 316                                         ;  0(%rbp) prev %rbp
 317                                         ; -8(%rbp) do what you want
 318                                         ;  ...     do what you want
 319                                         ;  0(%rsp) do what you want
 320
 321 (define (param-register n)
 322   (case n
 323     (0 "%rdi")
 324     (1 "%rsi")
 325     (2 "%rdx")
 326     (3 "%rcx")
 327     (4 "%r8")
 328     (5 "%r9")
 329     (else (error #f "need to test out the below"))
 330     (else (format "~a(%rsp)" (- n 6)))))
 331
 332 (define (codegen program)
 333   (let* ((extract-res-0 (extract-strings program))
 334          (strings (car extract-res-0))
 335          (extract-res-1 (extract-lambdas (cdr extract-res-0)))
 336          (lambdas (car extract-res-1))
 337          (xform-prog (cdr extract-res-1)))
 338
 339     (emit "\t.global _start")
 340     (emit "\t.text")
 341 ;    (emit ".p2align 4,,15") is this needed?
 342
 343     (for-each codegen-lambda lambdas)
 344
 345     (emit "_start:")
 346     (emit "movq %rsp, %rbp")            ; set up the base pointer
 347     (codegen-expr xform-prog 0 '())
 348
 349                                         ; exit syscall
 350     (emit "mov %rax, %rdi")
 351     (emit "mov $60, %rax")
 352     (emit "syscall")
 353
 354     (emit "\t.data")
 355
 356     (for-each emit-string-data strings)))
 357
 358 (define (compile-to-binary program output)
 359   (when (not (eq? (typecheck program) 'int)) (error #f "not an int"))
 360   (let ([tmp-path "/tmp/a.s"])
 361     (when (file-exists? tmp-path) (delete-file tmp-path))
 362     (with-output-to-file tmp-path
 363       (lambda () (codegen program)))
 364     (system (format "clang -nostdlib /tmp/a.s -o ~a" output))))