codegen.scm

   1 (load "typecheck.scm")
   2 (load "ast.scm")
   3 (load "platform.scm")
   4
   5 (define target host-os)
   6
   7 (define (emit . s)
   8   (begin
   9     (apply printf s)
  10     (display "\n")))
  11
  12 (define wordsize 8)
  13
  14 (define (stack-type? data-layouts type)
  15   (if (assoc type data-layouts) #t #f))
  16
  17
  18 (define (type-size data-layouts type)
  19
  20   (define (adt-size adt)
  21     (let ([sizes
  22            (map (lambda (sum)
  23                   (fold-left (lambda (acc x) (+ acc (type-size data-layouts x)))
  24                              wordsize ; one word needed to store tag
  25                              (cdr sum)))
  26                 (cdr adt))])
  27       (apply max sizes)))
  28
  29   (case type
  30     ['Int wordsize]
  31     ['Bool wordsize]
  32     [else
  33      (let ([adt (assoc type data-layouts)])
  34        (if adt
  35            (adt-size adt)
  36            (error #f "unknown size" type)))]))
  37
  38                                         ; returns the size of an expression's result in bytes
  39 (define (expr-size dls e)
  40   (if (eqv? (ast-type e) 'stack)
  41       (type-size dls (cadr e))
  42       wordsize))
  43
  44 (define (on-stack? expr)
  45   (case (ast-type expr)
  46     ['stack (cadr expr)]
  47     [else #f]))
  48
  49                                         ; does a movsq for something on the stack
  50                                         ; src points to the start stack index, but not the top of that index
  51                                         ; likewise for dst
  52                                         ; | ...  |
  53                                         ; +------+ <-- to here
  54                                         ; | tag0 |
  55                                         ; +------+ <-- src (size = 16)
  56                                         ; |  42  |
  57                                         ; +------+ <-- start copying from here...
  58 (define (emit-stack-copy src dst size)
  59   (let ([size-to-copy (- size wordsize)])
  60     (emit "leaq ~a(%rbp), %rsi" (- src size-to-copy))
  61     (emit "leaq ~a(%rbp), %rdi" (- dst size-to-copy))
  62     (emit "movq $~a, %rcx" (/ size wordsize))
  63     (emit "rep movsq")))
  64
  65
  66                                         ; an environment consists of adt layouts in scope,
  67                                         ; and any bound variables.
  68                                         ; bound variables are an assoc list with their stack offset
  69 (define make-env list)
  70 (define env-data-layouts car)
  71 (define env-bindings cadr)
  72
  73 (define (codegen-add xs si env)
  74   (define (go ys)
  75     (if (null? ys)
  76         (emit "movq ~a(%rbp), %rax" si)
  77         (begin
  78           (let ((y (car ys)))
  79             (if (integer? y)
  80                 (emit "addq $~a, ~a(%rbp)" y si)
  81                 (begin
  82                   (codegen-expr y (- si wordsize) env)
  83                   (emit "addq %rax, ~a(%rbp)" si))))
  84           (go (cdr ys)))))
  85   (begin
  86                                         ; use si(%rbp) as the accumulator
  87     (emit "movq $0, ~a(%rbp)" si)
  88     (go xs)))
  89
  90 (define (codegen-binop opcode)
  91   (lambda (a b si env)
  92     (codegen-expr b si env)
  93     (emit "movq %rax, ~a(%rbp)" si)
  94     (codegen-expr a (- si wordsize) env)
  95     (emit "~a ~a(%rbp), %rax" opcode si)))
  96
  97 (define codegen-sub (codegen-binop "sub"))
  98
  99 (define codegen-mul (codegen-binop "imul"))
 100
 101 (define (codegen-not x si env)
 102   (codegen-expr x si env)
 103   (emit "notq %rax")
 104   (emit "andq $1, %rax"))
 105
 106 (define (codegen-eq a b si env)
 107   (codegen-expr a si env)
 108   (emit "movq %rax, ~a(%rbp)" si)
 109   (codegen-expr b (- si wordsize) env)
 110   (emit "## ~a = ~b" a b)
 111   (emit "cmpq ~a(%rbp), %rax" si)
 112   (emit "sete %al"))
 113
 114                                         ; 'write file handle addr-string num-bytes
 115
 116 (define (codegen-print x si env)
 117   (codegen-expr x si env) ; x should be a static-string, producing a label
 118
 119                                         ; make a copy of string address since %rax and %rdi are clobbered
 120   (emit "mov %rax, %rbx")
 121
 122                                         ; get the length of the null terminated string
 123   (emit "mov %rax, %rdi")
 124   (emit "xor %al, %al")   ; set %al to 0
 125   (emit "mov $-1, %rcx") ; max search length = max int = -1
 126   (emit "cld")           ; clear direction flag, search up in memory
 127   (emit "repne scasb")   ; scan string, %rcx = -strlen - 1 - 1
 128
 129   (emit "not %rcx")      ; -%rcx = strlen + 1
 130   (emit "dec %rcx")
 131
 132   (emit "movq %rbx, %rsi") ; string addr
 133   (emit "movq %rcx, %rdx") ; num bytes
 134   (emit "movq $1, %rdi")   ; file handle (stdout)
 135   (case target
 136     ('darwin (emit "mov $0x2000004, %rax")) ; syscall 4 (write)
 137     ('linux  (emit "mov $1, %rax"))) ; syscall 1 (write)
 138   (emit "syscall"))
 139
 140 (define (codegen-let bindings body si env)
 141
 142                                         ; is this a closure that captures itself?
 143                                         ; e.g. (let ([x 3] [f (closure lambda0 (f x))]) (f))
 144   (define (self-captive-closure? name expr)
 145     (and (eqv? (ast-type expr) 'closure)
 146          (memv name (caddr expr))))
 147
 148   ;; (define (emit-scc scc env)
 149   ;;   ; acc is a pair of the env and list of touchups
 150   ;;   (define (emit-binding acc binding)
 151   ;;     (let ([binding-name (car binding)]
 152   ;;        [binding-body (cadr binding)]
 153
 154   ;;        [other-bindings (filter
 155   ;;                         (lambda (x) (not (eqv? binding-name x)))
 156   ;;                         scc)]
 157   ;;        [mutually-recursives
 158   ;;         (filter
 159   ;;          (lambda (other-binding)
 160   ;;            (memv other-binding (references binding-body)))
 161   ;;          other-bindings)]
 162
 163   ;;        [new-touchups (append touchups (cdr acc))])
 164
 165   ;;                                    ; TODO: assert that the only mutually recursives are closures
 166   ;;    (for-each
 167   ;;     (lambda (binding)
 168   ;;       (when (not (eqv? (ast-type (cadr binding))
 169
 170   ;;    (emit "asdf")
 171   ;;    (cons new-env new-touchups)
 172   ;;    ))
 173
 174   ;;   (fold-left emit-binding (cons env '()) scc))))
 175                                         ; assoc map of binding name to size
 176
 177
 178   (define dls (env-data-layouts env))
 179
 180   (define stack-sizes
 181     (map (lambda (binding) (cons (car binding) (expr-size dls (cadr binding))))
 182          bindings))
 183
 184                                         ; assoc map of binding name to offset
 185   (define stack-offsets
 186                                         ; 2  4  2  8  6
 187     (let* ([totals                      ; 2  6  8  16 22
 188             (reverse (fold-left (lambda (acc x)
 189                                   (if (null? acc)
 190                                       (list x)
 191                                       (cons (+ x (car acc)) acc)))
 192                                 '()
 193                                 (map cdr stack-sizes)))]
 194                                         ; 0  2  6  8  16
 195            [relative-offsets (map - totals (map cdr stack-sizes))]
 196            [absolute-offsets (map (lambda (x) (- si x)) relative-offsets)])
 197       (map cons (map car stack-sizes) absolute-offsets)))
 198
 199   (let* (
 200                                         ; the stack index used when codegening binding body and main body
 201                                         ; -> stack ->
 202                                         ; [stack-offsets | inner-si]
 203          [inner-si (- si (fold-left + 0 (map cdr stack-sizes)))]
 204
 205          [get-offset (lambda (n) (cdr (assoc n stack-offsets)))]
 206
 207          [inner-env
 208           (fold-left
 209            (lambda (env comps)
 210              (let* ([scc-binding-offsets
 211                      (fold-left
 212                       (lambda (acc name)
 213                         (cons (cons name (get-offset name))
 214                               acc))
 215                       (env-bindings env)
 216                       comps)]
 217                     [scc-env (make-env (env-data-layouts env) scc-binding-offsets)])
 218                (for-each
 219                 (lambda (name)
 220                   (let* ([expr (cadr (assoc name bindings))]
 221                          [size (expr-size dls expr)])
 222                     (emit "## generating ~a with scc-env ~a" name scc-env)
 223                     (if (self-captive-closure? name expr)
 224                                         ; if self-captive, insert a flag into the environment to let
 225                                         ; codegen-closure realise this!
 226                         (codegen-expr expr
 227                                       inner-si
 228                                       (make-env
 229                                        (env-data-layouts scc-env)
 230                                        (cons (cons name 'self-captive)
 231                                              (env-bindings scc-env))))
 232                         (codegen-expr expr inner-si scc-env))
 233
 234                     (if (on-stack? expr)
 235                                                   ; copy over whatevers on the stack
 236                         (emit-stack-copy inner-si (get-offset name) size)
 237                         (emit "movq %rax, ~a(%rbp)" (get-offset name)))))
 238                 comps)
 239                scc-env))
 240            env
 241            (reverse (sccs (graph bindings))))])
 242
 243     (for-each (lambda (form)
 244                 (codegen-expr form inner-si inner-env))
 245               body)))
 246
 247 (define (codegen-var e si env)
 248   (let* ([stack-type (on-stack? e)]
 249          [name (if stack-type (caddr e) e)]
 250
 251          [dls (env-data-layouts env)]
 252
 253          [singleton? (and stack-type
 254                         (assoc name
 255                                (cdr (assoc stack-type dls))))]
 256
 257          [stack-offset (assoc name (env-bindings env))])
 258     (when (and (not stack-offset) (not singleton?))
 259       (error #f (format "Variable ~a is not bound" name)))
 260
 261     (if (on-stack? e)
 262         (if singleton?
 263                                         ; singletons don't need to be in the environment
 264                                         ; just copy over the tag
 265             (emit "movq $~a, ~a(%rbp)"
 266                   (data-sum-tag (env-data-layouts env)
 267                                 stack-type
 268                                 name)
 269                   si)
 270             (emit-stack-copy (cdr stack-offset) si (type-size dls stack-type)))
 271         (emit "movq ~a(%rbp), %rax" (cdr stack-offset)))))
 272
 273 (define cur-lambda 0)
 274 (define (fresh-lambda)
 275   (set! cur-lambda (+ 1 cur-lambda))
 276   (format "_lambda~a" (- cur-lambda 1)))
 277
 278                                         ; a closure on the heap looks like:
 279                                         ; 0    8         16        24
 280                                         ; addr var1....  var2....  var3....
 281
 282 (define (codegen-closure label captured si env)
 283   (let* ((heap-offsets (map (lambda (i) (+ 8 (* 8 i)))
 284                             (range 0 (length captured))))) ; 4, 12, 20, etc.
 285
 286     (emit "## creating closure")
 287
 288     (emit "movq heap_start@GOTPCREL(%rip), %rbx")
 289
 290     (emit "movq (%rbx), %rax")          ; %rax = heap addr of closure
 291
 292
 293                                         ; point heap_start to next space
 294     (emit "addq $~a, (%rbx)" (+ 8 (* 8 (length captured))))
 295
 296     (emit "## storing address to lambda")
 297                                         ; store the address to the lambda code
 298     (emit "movq ~a@GOTPCREL(%rip), %rbx" label)
 299     (emit "movq %rbx, 0(%rax)")
 300
 301     (emit "## storing captives")
 302                                         ; store the captured vars
 303     (for-each
 304      (lambda (var-name heap-offset)
 305        (let ([stack-offset (cdr (assoc var-name (env-bindings env)))])
 306          (emit "### captive ~a" var-name)
 307          (if (eqv? stack-offset 'self-captive)
 308                                         ; captive refers to this closure:
 309                                         ; move heap addr of this closure to stack!
 310              (emit "movq %rax, ~a(%rax)" heap-offset)
 311              (begin
 312                (emit "movq ~a(%rbp), %rbx" stack-offset)
 313                (emit "movq %rbx, ~a(%rax)" heap-offset)))))
 314      captured
 315      heap-offsets)))
 316
 317                                         ; for now we can only call closures
 318 (define (codegen-call f args si env)
 319   (codegen-expr f si env)
 320
 321   (emit "## starting call")
 322
 323   (emit "movq %rax, ~a(%rbp)" si) ; store address of closure first on stack
 324
 325                                         ; codegen the arguments, store them intermediately
 326   (for-each
 327    (lambda (e i)
 328      (begin
 329        (emit "## arg no. ~a" (- i 1))
 330        (codegen-expr e (- si (* wordsize i)) env)
 331                                         ; store intermediate result on stack
 332        (emit "movq %rax, ~a(%rbp)" (- si (* wordsize i)))))
 333
 334    args (range 1 (length args)))
 335
 336                                         ; now that we have everything we need on the stack,
 337                                         ; move them into the param registers
 338
 339   (emit "## moving args into place")
 340   (for-each
 341    (lambda (i) (emit "movq ~a(%rbp), ~a"
 342                      (- si (* wordsize i))
 343                      (param-register i)))
 344    (range 1 (length args)))
 345
 346                                         ; todo: can this be made more efficient
 347   (emit "movq ~a(%rbp), %rax" si)       ; load back pointer to closure
 348
 349   (emit "## moving captives into place")
 350
 351                                         ; move captives into first argument
 352   (emit "movq %rax, %rbx")
 353   (emit "addq $8, %rbx")
 354   (emit "movq %rbx, ~a" (param-register 0))
 355
 356   (emit "## performing call")
 357
 358   (emit "addq $~a, %rsp" si) ; adjust the stack pointer to account all the stuff we put in the env
 359   (emit "callq *(%rax)")                ; call closure function
 360   (emit "subq $~a, %rsp" si))
 361
 362                                         ; LAMBDAS:
 363                                         ; 1st param: pointer to captured args
 364                                         ; 2nd param: 1st arg
 365                                         ; 3rd param: 2nd arg, etc.
 366
 367 (define (codegen-lambda l)
 368   (let* ((label (car l))
 369          (stuff (cdr l))
 370          (captives (car stuff))
 371          (args (cadr stuff))
 372          (body (caddr stuff))
 373                                         ; params = what actually gets passed
 374          (params (append captives args))
 375
 376          (stack-offsets (map (lambda (i)
 377                                (* (- wordsize) (+ 1 i)))
 378                              (range 0 (length params))))
 379
 380          [bindings (map cons params stack-offsets)]
 381          [env (make-env '() bindings)])
 382     (emit "~a:" label)
 383
 384     (display "## lambda captives: ")
 385     (display captives)
 386     (newline)
 387     (display "## lambda args: ")
 388     (display args)
 389     (newline)
 390     (display "## lambda body: ")
 391     (display body)
 392     (newline)
 393
 394     (emit "push %rbp") ; preserve caller's base pointer
 395
 396     (emit "movq %rsp, %rbp") ; set up our own base pointer
 397
 398                                         ; load the captured vars onto the stack
 399     (for-each
 400      (lambda (i)
 401        (begin
 402          (emit "# loading captive ~a" (list-ref captives i))
 403          (emit "movq ~a(~a), %rbx" (* wordsize i) (param-register 0))
 404          (emit "movq %rbx, ~a(%rbp)" (* (- wordsize) (+ 1 i)))))
 405      (range 0 (length captives)))
 406
 407                                         ; load the args onto the stack
 408     (for-each
 409      (lambda (i)
 410        (begin
 411          (emit "movq ~a, %rbx" (param-register (+ 1 i)))
 412          (emit "movq %rbx, ~a(%rbp)"
 413                (* (- wordsize)
 414                   (+ 1 (length captives) i)))))
 415      (range 0 (length args)))
 416
 417     (codegen-expr body (* (- wordsize) (+ 1 (length params))) env)
 418
 419     (emit "pop %rbp") ; restore caller's base pointer
 420     (emit "ret")))
 421
 422 (define cur-label 0)
 423 (define (fresh-label)
 424   (set! cur-label (+ 1 cur-label))
 425   (format "label~a" (- cur-label 1)))
 426
 427 (define (codegen-if cond then else si env)
 428   (codegen-expr cond si env)
 429   (emit "cmpq $0, %rax")
 430   (let ((exit-label (fresh-label))
 431         (else-label (fresh-label)))
 432     (emit "je ~a" else-label)
 433     (codegen-expr then si env)
 434     (emit "jmp ~a" exit-label)
 435     (emit "~a:" else-label)
 436     (codegen-expr else si env)
 437     (emit "~a:" exit-label)))
 438
 439 (define (codegen-case switch cases si env)
 440   (define dls (env-data-layouts env))
 441   (define exit-label (fresh-label))
 442
 443
 444                                         ; checks if equal and returns assoc list of bindings
 445   (define (check-equal jne-label type inner-offset x)
 446
 447                                         ; (foo a 2 (bar x)) -> ((2 Int 1) ((bar x) A 2))
 448                                         ; sum: foo
 449     (define (comparibles sum)
 450       (if (not (list? sum))
 451           '()
 452           (let ([product-types (cdr (assoc sum (cdr (assoc type dls))))])
 453             (filter (lambda (x) (not (eqv? 'var (ast-type (car x)))))
 454                     (map (lambda (x t i) (list x t i))
 455                          (cdr x)
 456                          product-types
 457                          (range 0 (length product-types)))))))
 458
 459     (let ([sums (assoc type dls)])
 460       (if sums
 461           (let* ([sum (if (list? x) (car x) x)] ; can sometimes be a singleton
 462                  [tag (data-sum-tag dls type sum)])
 463                                         ; the tag is at the top (beginning) of the adt on the stack
 464             (emit "cmpq $~a, ~a(%rbp)" tag inner-offset)
 465             (emit "jne ~a" jne-label)
 466             (flat-map
 467              (lambda (cmpx cmpt cmpi)
 468                (check-equal jne-label
 469                             cmpt
 470                             (- inner-offset (data-product-offset dls type sum i))
 471                             cmpx))
 472              (comparibles sum)))
 473           (if (eqv? 'var (ast-type x))
 474               (list (cons x inner-offset))
 475               (begin
 476                 (emit "cmp $~a, ~a(%rbp)" x inner-offset)
 477                 (emit "jne ~a" jne-label)
 478                 '() )))))
 479
 480   (define (codegen-adt-match type case)
 481     (let* ([match (car case)]
 482            [expr (cadr case)]
 483            [next-section-label (fresh-label)]
 484            [inner-si (- si (type-size dls type))]
 485            [new-env (append (check-equal next-section-label type si match)
 486                             env)])
 487
 488       (codegen-expr expr inner-si new-env)
 489       (emit "jmp ~a" exit-label)
 490
 491       (emit "~a:" next-section-label)))
 492
 493   (define (codegen-literal-match case)
 494     (let ([next-section-label (fresh-label)])
 495       (emit "cmpq $~a, %rax" (car case))
 496       (emit "jne ~a" next-section-label)
 497       (codegen-expr (cadr case) si env)
 498       (emit "jmp ~a" exit-label)
 499       (emit "~a:" next-section-label)))
 500
 501                                         ; generate the switch
 502                                         ; (and store it on the stack if not a stack value)
 503   (codegen-expr switch si env)
 504
 505   (if (eqv? 'stack (ast-type switch))
 506                                         ; adt pattern match
 507       (for-each (lambda (x) (codegen-adt-match (cadr switch) x)) cases)
 508       (for-each codegen-literal-match cases))
 509   (emit "~a:" exit-label))
 510
 511
 512 (define (data-tor env e)
 513   (if (not (list? e)) #f
 514       (assoc (car e) (flat-map data-tors (env-data-layouts env)))))
 515
 516                                         ; returns the internal offset in bytes of a product within an ADT
 517                                         ; given the constructor layout
 518                                         ; constructor-layout: (foo (Int Bool))
 519 (define (data-product-offset data-layouts type sum index)
 520   (let* ([products (cdr (assoc sum (cdr (assoc type data-layouts))))]
 521          [to-traverse (list-head products index)])
 522     (fold-left
 523      (lambda (acc t) (+ acc (type-size data-layouts t)))
 524      wordsize ; skip the tag in the first word
 525      to-traverse)))
 526
 527 (define (data-sum-tag data-layouts type sum)
 528
 529   (define (go acc sums)
 530     (when (null? sums) (error #f "data-sum-tag no sum for type" sum type))
 531     (if (eqv? sum (car sums))
 532         acc
 533         (go (+ 1 acc) (cdr sums))))
 534   (let* ([type-sums (cdr (assoc type data-layouts))])
 535     (go 0 (map car type-sums))))
 536
 537 (define (codegen-data-tor e si env)
 538
 539   (define dls (env-data-layouts env))
 540
 541   (define (codegen-destructor tor)
 542     (let* ([res (codegen-expr (cadr e) si env)]
 543            [info (cadr tor)]
 544            [type (car info)]
 545            [sum (cadr info)]
 546            [index (caddr info)]
 547            [product-type (cadddr info)]
 548            [product-type-size (type-size dls product-type)]
 549
 550            [safe-space-offset (- si (type-size dls type))]
 551
 552            [inner-offset (- si (data-product-offset dls type sum index))])
 553
 554       (when (not (on-stack? (cadr e)))
 555         (error #f "trying to destruct something that isn't a stack expression"))
 556       (emit "# deconstructing")
 557
 558       (if (stack-type? (env-data-layouts env) product-type)
 559                                         ; if copying from the stack, need to first copy
 560                                         ; to a safe space above to avoid overwriting
 561                                         ; the original result on the stack
 562                                         ; this is bad. please remove this in the rewrite.
 563           (begin
 564             (emit-stack-copy inner-offset safe-space-offset product-type-size)
 565             (emit-stack-copy safe-space-offset si product-type-size))
 566           (emit "movq ~a(%rbp), %rax" inner-offset))))
 567
 568   (define (codegen-constructor tor)
 569     (let* ([info (cadr tor)]
 570            [type (car info)]
 571            [sum (cadr info)]
 572            [constructor (car e)]
 573
 574            [args (cdr e)]
 575
 576            [tag (data-sum-tag (env-data-layouts env)
 577                               type
 578                               sum)]
 579
 580            [inner-si (- si (type-size dls type))]
 581
 582            [product-types (cdr (assoc sum (cdr (assoc type dls))))]
 583
 584            [insert-product
 585             (lambda (expr i product-type)
 586               (let ([dest-offset
 587                      (- si (data-product-offset dls type sum i))]
 588                     [product-size (type-size dls product-type)])
 589                 (codegen-expr expr inner-si env)
 590                 (if (on-stack? expr)
 591                     (emit-stack-copy inner-si dest-offset product-size)
 592                     (emit "movq %rax, ~a(%rbp)" dest-offset))))])
 593
 594                                         ; emit the tag
 595       (emit "movq $~a, ~a(%rbp)" tag si)
 596                                         ; generate products
 597       (for-each insert-product args (range 0 (length args)) product-types)))
 598
 599   (let* ([tor (data-tor env e)]
 600          [constructor (eqv? 'constructor (caddr (cadr tor)))])
 601     (if constructor
 602         (codegen-constructor tor)
 603         (codegen-destructor tor))))
 604
 605 (define (codegen-expr e si env)
 606   (emit "# ~a" e)
 607   (case (ast-type e)
 608     ('closure (codegen-closure (cadr e) (caddr e) si env))
 609     ('app
 610      (case (car e)
 611        ('+ (codegen-add (cdr e) si env))
 612        ('- (codegen-sub (cadr e) (caddr e) si env))
 613        ('* (codegen-mul (cadr e) (caddr e) si env))
 614        ('! (codegen-not (cadr e) si env))
 615        ('= (codegen-eq  (cadr e) (caddr e) si env))
 616        ('bool->int (codegen-expr (cadr e) si env))
 617        ('print (codegen-print (cadr e) si env))
 618        (else
 619         (if (data-tor env e)
 620             (codegen-data-tor e si env)
 621             (codegen-call (car e) (cdr e) si env)))))
 622
 623                                         ; this is a builtin being passed around as a variable
 624                                         ; this should have been converted to a closure!
 625     ('builtin (error #f "passing about a builtin!" e))
 626
 627     ('let (codegen-let (let-bindings e)
 628                        (let-body e)
 629                        si
 630                        env))
 631
 632     ('var (codegen-var e si env))
 633
 634     ('if (codegen-if (cadr e) (caddr e) (cadddr e) si env))
 635     ('case (codegen-case (case-switch e) (case-cases e) si env))
 636
 637     ('bool-literal (emit "movq $~a, %rax" (if e 1 0)))
 638     ('int-literal (emit "movq $~a, %rax" e))
 639
 640     ('static-string (emit "movq ~a@GOTPCREL(%rip), %rax"
 641                           (cadr e)))
 642
 643     ('stack (case (ast-type (caddr e))
 644               ['var (codegen-var e si env)]
 645               [else (codegen-expr (caddr e) si env)]))
 646
 647     (else (error #f "don't know how to codegen this")))
 648   (emit "# done ~a" e))
 649
 650                                         ; takes in a expr annotated with types and returns a type-less AST
 651                                         ; with stack values wrapped
 652 (define (annotate-stack-values data-layouts ann-e)
 653   (define (stack-type? type)
 654     (assoc type data-layouts))
 655   (define (strip e)
 656     (ast-traverse strip (ann-expr e)))
 657   (let* ([e (ann-expr ann-e)]
 658          [type (ann-type ann-e)])
 659     (if (stack-type? type)
 660         `(stack ,type
 661                 ,(ast-traverse (lambda (x) (annotate-stack-values data-layouts x)) e))
 662         (ast-traverse (lambda (x)
 663                         (annotate-stack-values data-layouts x))
 664                       e))))
 665
 666 (define (free-vars prog)
 667   (define bound '())
 668   (define (collect e)
 669     (case (ast-type e)
 670       ('builtin '()) ; do nothing
 671       ('var (if (memv e bound) '() (list e)))
 672       ('lambda
 673           (begin
 674             (set! bound (append (lambda-args e) bound))
 675             (collect (lambda-body e))))
 676
 677       ('app (flat-map collect e))
 678       ('if (flat-map collect (cdr e)))
 679       ('let
 680           (let ([bind-fvs (flat-map (lambda (a)
 681                                       (begin
 682                                         (set! bound (cons (car a) bound))
 683                                         (collect (cdr a))))
 684                                     (let-bindings e))])
 685             (append bind-fvs (flat-map collect (let-body e)))))
 686       (else '())))
 687   (collect prog))
 688
 689                                         ; ((lambda (x) (+ x y)) 42) => ((closure lambda1 (y)) 42)
 690                                         ;                              [(lambda1 . ((y), (x), (+ x y))]
 691                                         ; for builtins, this generates a closure if it is used
 692                                         ; outside of an immediate app
 693                                         ; but only one closure for each builtin
 694
 695 (define (extract-lambdas program)
 696   (define lambdas '())
 697   (define (add-lambda e)
 698     (let* ((label (fresh-lambda))
 699            (args (lambda-args e))
 700            (captured (free-vars e))
 701            (body (extract (lambda-body e)))
 702            (new-lambda (cons label (list captured args body))))
 703       (set! lambdas (cons new-lambda lambdas))
 704       `(closure ,label ,captured))) ; todo: should we string->symbol?
 705
 706   (define (find-builtin-lambda e)
 707     (let [(l (assq (builtin-name e) lambdas))]
 708       (if l `(closure ,(car l) ,(caadr l)) #f)))
 709
 710   (define (builtin-name e)
 711     (case e
 712       ('+ "_add")
 713       ('- "_sub")
 714       ('* "_mul")
 715       ('! "_not")
 716       ('= "_eq")
 717       ('bool->int "_bool2int")
 718       ('print "_print")
 719       (else (error #f "don't know this builtin"))))
 720   (define (builtin-args e)
 721     (case e
 722       ('+ '(x y))
 723       ('- '(x y))
 724       ('* '(x y))
 725       ('! '(x))
 726       ('= '(x y))
 727       ('bool->int '(x))
 728       ('print '(x))
 729       (else (error #f "don't know this builtin"))))
 730
 731   (define (add-builtin-lambda e)
 732     (let* [(label (builtin-name e))
 733            (captured '())
 734            (args (builtin-args e))
 735            (body `(,e ,@args))
 736            (new-lambda (cons label (list captured args body)))]
 737       (set! lambdas (cons new-lambda lambdas))
 738       `(closure ,label ,captured)))
 739
 740   (define (extract e)
 741     (case (ast-type e)
 742       ('lambda (add-lambda e))
 743       ('let `(let ,(map (lambda (b) `(,(car b) ,@(extract (cdr b)))) (let-bindings e))
 744                ,@(map extract (let-body e))))
 745       ('app (append
 746                                         ; if a builtin is used as a function, don't generate lambda
 747              (if (eqv? 'builtin (ast-type (car e)))
 748                  (list (car e))
 749                  (list (extract (car e))))
 750              (map extract (cdr e))))
 751
 752       ('builtin
 753        (if (find-builtin-lambda e)
 754            (find-builtin-lambda e)
 755            (add-builtin-lambda e)))
 756
 757
 758       (else (ast-traverse extract e))))
 759   (let ((transformed (extract program)))
 760     (cons lambdas transformed)))
 761
 762 (define (extract-strings program)
 763   (let ((cur-string 0)
 764         (strings '())) ; assoc list of labels -> string
 765     (define (fresh-string)
 766       (set! cur-string (+ cur-string 1))
 767       (format "string~a" (- cur-string 1)))
 768     (define (extract e)
 769       (case (ast-type e)
 770         ('string-literal
 771          (let ((label (fresh-string)))
 772            (set! strings (cons (cons label e) strings))
 773            `(static-string ,label)))
 774         (else (ast-traverse extract e))))
 775     (let ((transformed (extract program)))
 776       (cons strings transformed))))
 777
 778 (define (emit-string-data s)
 779   (emit "~a:" (car s))
 780   (emit "\t.string \"~a\"" (cdr s)))
 781
 782                                         ; 24(%rbp) mem arg 1
 783                                         ; 16(%rbp) mem arg 0          prev frame
 784                                         ; -----------------------
 785                                         ;  8(%rbp) return address     cur frame
 786                                         ;  0(%rbp) prev %rbp
 787                                         ; -8(%rbp) do what you want
 788                                         ;  ...     do what you want
 789                                         ;  0(%rsp) do what you want
 790
 791 (define (param-register n)
 792   (case n
 793     (0 "%rdi")
 794     (1 "%rsi")
 795     (2 "%rdx")
 796     (3 "%rcx")
 797     (4 "%r8")
 798     (5 "%r9")
 799     (else (error #f "need to test out the below"))
 800     (else (format "~a(%rsp)" (- n 6)))))
 801
 802 (define (initialize-heap)
 803   (let ((mmap
 804          (case target
 805            ('darwin "0x20000c5")
 806            ('linux "9"))))
 807                                         ; allocate some heap memory
 808     (emit "mov $~a, %rax" mmap) ; mmap
 809     (emit "xor %rdi, %rdi")  ; addr = null
 810     (emit "movq $1024, %rsi")   ; length = 1kb
 811     (emit "movq $0x3, %rdx") ; prot = read | write = 0x2 | 0x1
 812                                         ;    flags = anonymous | private
 813     (case target
 814       ('darwin (emit "movq $0x1002, %r10")) ; anon = 0x1000, priv = 0x02
 815       ('linux (emit "movq $0x22, %r10")))   ; anon = 0x20,   priv = 0x02
 816     (emit "movq $-1, %r8") ; fd = -1
 817     (emit "xor %r9, %r9") ; offset = 0
 818     (emit "syscall")
 819                                         ; %rax now contains pointer to the start of the heap
 820                                         ; keep track of it
 821
 822     (emit "movq heap_start@GOTPCREL(%rip), %rsi")
 823     (emit "movq %rax, (%rsi)")))
 824
 825 (define (codegen program)
 826   (set! cur-label 0)
 827   (set! cur-lambda 0)
 828   (let* ([data-layouts (program-data-layouts program)]
 829
 830          [pattern-matched (expand-pattern-matches program)]
 831          [type-annotated (annotate-types pattern-matched)]
 832          [stack-annotated (annotate-stack-values data-layouts
 833                                                  type-annotated)]
 834
 835          (strings-res (extract-strings stack-annotated))
 836          (strings (car strings-res))
 837          (lambdas-res (extract-lambdas (cdr strings-res)))
 838          (lambdas (car lambdas-res))
 839          (xform-prog (cdr lambdas-res)))
 840
 841     (emit "\t.global _start")
 842     (emit "\t.text")
 843                                         ;    (emit ".p2align 4,,15") is this needed?
 844
 845     (for-each codegen-lambda lambdas)
 846
 847     (emit "_start:")
 848
 849     (initialize-heap)
 850
 851     (emit "movq %rsp, %rbp")            ; set up the base pointer
 852
 853     (codegen-expr xform-prog (- wordsize) (make-env data-layouts '()))
 854
 855                                         ; exit syscall
 856     (emit "mov %rax, %rdi")
 857     (case target
 858       ('darwin (emit "movq $0x2000001, %rax"))
 859       ('linux (emit "mov $60, %rax")))
 860     (emit "syscall")
 861
 862     (emit ".data")
 863
 864     (emit "heap_start:")
 865     (emit "\t.quad 0")
 866
 867     (for-each emit-string-data strings)))
 868
 869 (define (compile-to-binary program output t)
 870   (set! target t)
 871   (when (not (eq? (typecheck program) 'Int)) (error #f "not an Int"))
 872   (let ([tmp-path "/tmp/a.s"])
 873     (when (file-exists? tmp-path) (delete-file tmp-path))
 874     (with-output-to-file tmp-path
 875       (lambda () (codegen program)))
 876
 877     (case target
 878       ('darwin
 879        (system "as /tmp/a.s -o /tmp/a.o")
 880        (system (format "ld /tmp/a.o -e _start -macosx_version_min 10.14 -static -o ~a" output)))
 881       ('linux
 882        (system "as /tmp/a.s -o /tmp/a.o")
 883        (system (format "ld /tmp/a.o -o ~a" output))))))
 884
 885 ; NOTES
 886 ; syscalls in linux and darwin use the following arguments for syscall instruction:
 887 ; %rax = syscall #
 888 ; %rdi = 1st arg
 889 ; %rsi = 2nd arg
 890 ; %rdx = 3rd arg
 891 ; %r10 = 4th arg
 892 ; %r8  = 5th arg
 893 ; %r9  = 6th arg
 894
 895 ; on darwin, unix/posix syscalls are offset by 0x2000000 (syscall classes)
 896 ; https://opensource.apple.com/source/xnu/xnu-2782.20.48/bsd/kern/syscalls.master
 897 ; documentation for most syscalls: /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX.sdk/usr/include/sys