ast.scm

   1 (load "utils.scm")
   2
   3 (define (ast-type x)
   4   (define (builtin? x)
   5     (case x
   6       ('+ #t)
   7       ('- #t)
   8       ('* #t)
   9       ('! #t)
  10       ('= #t)
  11       ('bool->int #t)
  12       ('print #t)
  13       (else #f)))
  14   (cond
  15    ((list? x)
  16     (case (car x)
  17       ('if 'if)
  18       ('let 'let)
  19       ('lambda 'lambda)
  20       ('case 'case)
  21       ('closure 'closure) ; only available in codegen
  22       ('static-string 'static-string) ; only available in codegen
  23       ('stack 'stack) ; only available in codegen (tag that value is passed via stack)
  24       (else 'app)))
  25    ((builtin? x) 'builtin)
  26    ((symbol? x) 'var)
  27    ((integer? x) 'int-literal)
  28    ((string? x) 'string-literal)))
  29
  30 (define (ast-traverse f x)
  31   (case (ast-type x)
  32     ('let `(let ,(map (lambda (x) (list (car x) (f (cadr x))))
  33                       (let-bindings x))
  34              ,@(map f (let-body x))))
  35     ('app (map f x))
  36     ('lambda `(lambda ,(lambda-args x) ,(f (lambda-body x))))
  37     ('if `(if ,@(map f (cdr x))))
  38     ('case `(case ,(f (case-switch x))
  39               ,@(map (lambda (x)
  40                        (list (car x) (f (cadr x))))
  41                      (case-cases x))))
  42     ('stack `(stack ,(cadr x) ,(f (caddr x))))
  43     (else x)))
  44
  45 (define (ast-collect f x)
  46   (define (inner y) (ast-collect f y))
  47   (case (ast-type x)
  48     ['let (append (f x)
  49                   (flat-map inner (let-bindings x))
  50                   (flat-map inner (let-body x)))]
  51     ['app (append (f x)
  52                   (flat-map inner x))]
  53     ['lambda (append (f x)
  54                      (inner (lambda-body x)))]
  55     ['if (append (f x)
  56                  (flat-map inner (cdr x)))]
  57     ['case (append (f x)
  58                    (inner (case-switch x))
  59                    (flat-map inner (map cadr (case-cases x))))]
  60     ['stack (append (f x)
  61                     (inner (caddr x)))]
  62     [else (f x)]))
  63
  64 (define (ast-find p x)
  65   (define (inner y) (ast-find p y))
  66
  67   (case (ast-type x)
  68     ['let (or (p x)
  69               (any inner (let-bindings x))
  70               (any inner (let-body x)))]
  71     ['app (or (p x)
  72               (any inner x))]
  73     ['lambda (or (p x)
  74                  (inner (lambda-body x)))]
  75     ['if (or (p x) (any inner (cdr x)))]
  76     ['case (or (p x)
  77                (any inner (map cadr (case-cases x)))
  78                (inner (case-switch x)))]
  79     ['stack (or (p x) (inner (caddr x)))]
  80     [else (p x)]))
  81
  82 (define let-bindings cadr)
  83 (define let-body cddr)
  84
  85 (define case-switch cadr)
  86 (define case-cases cddr)
  87
  88 (define (constructor? data-layouts x)
  89   (and (eqv? (ast-type x) 'var)
  90        (assoc x (flat-map cdr data-layouts))))
  91
  92 (define (all-cases data-layouts type)
  93   (let ([sums (assoc type data-layouts)])
  94     (if sums
  95         (flat-map (lambda (sum)
  96                     (let* ([sum-name (car sum)]
  97                            [products (cdr sum)]
  98                            [product-cases (map (lambda (y) (all-cases data-layouts y)) products)])
  99                       (if (null? product-cases)
 100                           (list sum-name) ; singletons aren't enclosed in a list [(foo x) 42] vs [foo 42]
 101                           (apply combinations (cons (list sum-name) product-cases)))))
 102                   (cdr sums))
 103         '(:binding))))
 104
 105                                         ; does a cover b
 106 (define (case-covers? data-layouts a b)
 107   (let ([a-binding? (and (eqv? (ast-type a) 'var) (not (constructor? data-layouts a)))])
 108     (if (eqv? ':binding b)
 109         a-binding?
 110         (if a-binding?
 111             #t
 112             (if (eqv? (ast-type b) 'var)
 113                 (eqv? b a)
 114                 (all (map (lambda (p q)
 115                             (case-covers? data-layouts p q))
 116                           (cdr a) (cdr b))))))))
 117
 118 (define (verify-cases data-layouts annotated-program)
 119
 120   ;; (define (check-pattern switch-type pat)
 121
 122   ;;   (define (impossible-match)
 123   ;;     (error "Can't pattern match ~a with ~a" switch-type (ann-expr pat)))
 124
 125   ;;   (if (assoc switch-type data-layouts)
 126   ;;    (begin
 127   ;;      (let ([sums (cdr (assoc switch-type data-layouts))])
 128   ;;        (unless (eqv? (ast-type (ann-expr pat)) 'var) (impossible-match))
 129   ;;        (unless (assoc (car (ann-expr pat)) sums) (impossible-match))
 130   ;;        (unless
 131   ;;      )
 132   ;;      (begin
 133   ;;     (unless (assoc switch-type allowed-match-ast-types)
 134   ;;       (error #f "Can't pattern match on ~a" switch-type))
 135
 136   ;;     (let ([allowed (cdr (assoc switch-type allowed-match-ast-types))])
 137   ;;       (unless (assoc (ast-type (ann-expr pat)) allowed) (impossible-match)))))))
 138
 139
 140   (let ([expr (ann-expr annotated-program)])
 141     (case (ast-type expr)
 142       ['case
 143           (let* ([switch-type (ann-type (case-switch expr))]
 144                  [cases (map car (case-cases expr))]
 145                  [case-covered?
 146                   (lambda (x) (any (lambda (y) (case-covers? data-layouts y x)) cases))])
 147             (unless (all (map case-covered? (all-cases data-layouts switch-type)))
 148               (error #f "not all cases covered")))]
 149       [else (ast-traverse (lambda (x) (verify-cases data-layouts x)) expr)])))
 150
 151
 152                                         ; (let ([(foo a b) (foo 123 345)]) a)
 153                                         ;   |
 154                                         ;   v
 155                                         ; (let ([a (foo~0 (foo 123 345)]
 156                                         ;       [b (foo~1 (foo 123 345)]) a)
 157 (define (expand-pattern-matches program)
 158   (define (go x)
 159     (define (let-pattern-match binding)
 160       (let ([binding-name (car binding)]
 161             [body (cadr binding)])
 162         (if (eqv? (ast-type binding-name) 'var)
 163             (list (list binding-name body))
 164
 165             (let* ([sum-name (car binding-name)]
 166                    [destructor (lambda (i) (dtor-name sum-name i))]
 167                    [products (cdr binding-name)]
 168
 169                    [data-layouts (program-data-layouts program)]
 170
 171                    [type (data-tor-type data-layouts sum-name)]
 172
 173                    [sums (cdr (assoc type data-layouts))]
 174                    [sum (assoc sum-name sums)]
 175
 176                    [expected-number (length (cdr sum))])
 177
 178                                         ; assert that we only do a let pattern match on an ADT with exactly one sum
 179               (when (not (= 1 (length sums)))
 180                 (error #f (format "Cannot pattern match a ~a in a let since it has ~a possible constructors"
 181                                   type
 182                                   (length sums))))
 183
 184                                         ; assert that there is the correct number of bindings
 185               (when (not (= (length products)
 186                             expected-number))
 187                 (error #f (format "Got ~a bindings: expected ~a for ~a"
 188                                (length products)
 189                                expected-number
 190                                binding)))
 191
 192               (flat-map (lambda (y i)
 193                           (let-pattern-match (list y `(,(destructor i) ,body))))
 194                         products
 195                         (range 0 (length products)))))))
 196
 197     (case (ast-type x)
 198       ['let `(let ,(flat-map let-pattern-match (let-bindings x))
 199                ,@(map go (let-body x)))]
 200       [else (ast-traverse go x)]))
 201   (program-map-exprs go program))
 202
 203 (define (lambda? x)
 204   (and (list? x) (eq? (car x) 'lambda)))
 205
 206 (define (statement-type x)
 207   (cond
 208    [(and (list? x)
 209          (eqv? (car x) 'data)) 'data]
 210    [(and (list? x)
 211          (eqv? (car x) 'define)) 'define]
 212    [else 'expr]))
 213
 214
 215                                         ; (A ((foo (Int Bool))
 216                                         ;     (bar (Bool)))
 217 (define (program-data-layouts program)
 218   (map (lambda (x) (cons (car x) (cdr x))) ; convert to assoc list
 219        (map cdr (filter (lambda (x) (eqv? (statement-type x) 'data))
 220                         program))))
 221
 222 (define (program-defines program)
 223   (filter (lambda (x) (eqv? (statement-type x) 'defines))
 224           program))
 225
 226 (define (program-map-exprs f program)
 227   (map (lambda (x)
 228          (case (statement-type x)
 229            ['expr (f x)]
 230            [else x]))
 231        program))
 232
 233 (define (program-body program)
 234   ; hack to have multi-expression bodies
 235   `(let ()
 236      ,@(filter (lambda (x) (eqv? (statement-type x) 'expr))
 237                program)))
 238
 239 (define (data-tor-type data-layouts tor)
 240   (let* ([tors (flat-map data-tors data-layouts)]
 241          [info (cadr (assoc tor tors))])
 242     (car info)))
 243
 244                                         ; a data tor is either a constructor or destructor for an ADT
 245                                         ; data-tors returns constructors and destructors for a data-layout
 246                                         ; (data A (foo Int Bool)
 247                                         ;         (bar Bool))
 248                                         ;        |
 249                                         ;        v
 250                                         ; (foo   . ((A foo constructor) . (abs Int (abs Bool A))))
 251                                         ; (foo~0 . ((A foo 0 Int)       . (abs A Int)))
 252                                         ; (foo~1 . ((A foo 1 Bool)      . (abs A Bool)))
 253                                         ; (bar   . ((A bar constructor) . (abs Bool A)))
 254                                         ; (bar~0 . ((A bar 0 Bool)      . (abs A Bool)))
 255                                         ;  ------+-------------------------------------
 256                                         ;  tor   | info                 | type
 257
 258 (define (data-tors data-layout)
 259   (define (constructor-type t products)
 260     (fold-right (lambda (x acc) `(abs ,x ,acc)) t products))
 261
 262   (define (destructor ctor-name prod-type part-type index)
 263     (let* ([name (dtor-name ctor-name index)]
 264            [info (list prod-type ctor-name index part-type)])
 265       (cons name (cons info `(abs ,prod-type ,part-type)))))
 266
 267   (let ([type-name (car data-layout)]
 268         [ctors (cdr data-layout)])
 269     (fold-right
 270      (lambda (ctor acc)
 271        (let* ([ctor-name (car ctor)]
 272               [products (cdr ctor)]
 273
 274               [maker (cons ctor-name (cons (list type-name ctor-name 'constructor) (constructor-type type-name products)))]
 275
 276               [dtors (map (lambda (t i) (destructor ctor-name type-name t i))
 277                           products
 278                           (range 0 (length products)))])
 279          (cons maker (append dtors acc))))
 280      '()
 281      ctors)))
 282
 283                                         ; creates a type environment for a given adt definition
 284 (define (data-tors-type-env data-layout)
 285   (map (lambda (x) (cons (car x) (cddr x))) (data-tors data-layout)))
 286
 287 (define (dtor-name ctor-name index)
 288   (string->symbol
 289    (string-append (symbol->string ctor-name)
 290                   "~"
 291                   (number->string index))))
 292
 293 ; for use in normalized form
 294 (define lambda-arg caadr)
 295 ; for use elsewhere
 296 (define lambda-args cadr)
 297 (define lambda-body caddr)
 298
 299 (define (references prog)
 300   (ast-collect
 301    (lambda (x)
 302      (case (ast-type x)
 303        ['var (list x)]
 304        [else '()]))
 305    prog))
 306
 307 (define (graph bs)
 308   (define (go bs orig-bs)
 309     (if (null? bs)
 310         '(() . ())
 311         (let* [(bind (car bs))
 312
 313                (vert (car bind))
 314                (refs (filter ; only count a reference if its a binding
 315                       (lambda (x) (assoc x orig-bs))
 316                       (references (cdr bind))))
 317                (edges (map (lambda (x) (cons vert x))
 318                            refs))
 319
 320                (rest (if (null? (cdr bs))
 321                          (cons '() '())
 322                          (go (cdr bs) orig-bs)))
 323                (total-verts (cons vert (car rest)))
 324                (total-edges (append edges (cdr rest)))]
 325           (cons total-verts total-edges))))
 326   (go bs bs))
 327
 328 (define (successors graph v)
 329   (define (go v E)
 330     (if (null? E)
 331         '()
 332         (if (eqv? v (caar E))
 333             (cons (cdar E) (go v (cdr E)))
 334             (go v (cdr E)))))
 335   (go v (cdr graph)))
 336
 337                                         ; takes in a graph (pair of vertices, edges)
 338                                         ; returns a list of strongly connected components
 339
 340                                         ; ((x y w) . ((x . y) (x . w) (w . x))
 341
 342                                         ; =>
 343                                         ; .->x->y
 344                                         ; |  |
 345                                         ; |  v
 346                                         ; .--w
 347
 348                                         ; ((x w) (y))
 349
 350                                         ; this uses tarjan's algorithm, to get reverse
 351                                         ; topological sorting for free
 352 (define (sccs graph)
 353
 354   (let* ([indices (make-hash-table)]
 355          [lowlinks (make-hash-table)]
 356          [on-stack (make-hash-table)]
 357          [current 0]
 358          [stack '()]
 359          [result '()])
 360
 361     (define (index v)
 362       (get-hash-table indices v #f))
 363     (define (lowlink v)
 364       (get-hash-table lowlinks v #f))
 365
 366     (letrec
 367         ([strong-connect
 368           (lambda (v)
 369             (begin
 370               (put-hash-table! indices v current)
 371               (put-hash-table! lowlinks v current)
 372               (set! current (+ current 1))
 373               (push! stack v)
 374               (put-hash-table! on-stack v #t)
 375
 376               (for-each
 377                (lambda (w)
 378                  (if (not (hashtable-contains? indices w))
 379                                         ; successor w has not been visited, recurse
 380                      (begin
 381                        (strong-connect w)
 382                        (put-hash-table! lowlinks
 383                                         v
 384                                         (min (lowlink v) (lowlink w))))
 385                                         ; successor w has been visited
 386                      (when (get-hash-table on-stack w #f)
 387                        (put-hash-table! lowlinks v (min (lowlink v) (index w))))))
 388                (successors graph v))
 389
 390               (when (= (index v) (lowlink v))
 391                 (let ([scc
 392                        (let new-scc ()
 393                          (let ([w (pop! stack)])
 394                            (put-hash-table! on-stack w #f)
 395                            (if (eqv? w v)
 396                                (list w)
 397                                (cons w (new-scc)))))])
 398                   (set! result (cons scc result))))))])
 399       (for-each
 400        (lambda (v)
 401          (when (not (hashtable-contains? indices v)) ; v.index == -1
 402            (strong-connect v)))
 403        (car graph)))
 404     result))