ast.scm

   1 (define (ast-type x)
   2   (define (builtin? x)
   3     (case x
   4       ('+ #t)
   5       ('- #t)
   6       ('* #t)
   7       ('! #t)
   8       ('= #t)
   9       ('bool->int #t)
  10       ('print #t)
  11       (else #f)))
  12   (cond
  13    ((list? x)
  14     (case (car x)
  15       ('if 'if)
  16       ('let 'let)
  17       ('lambda 'lambda)
  18       ('closure 'closure) ; only available in codegen
  19       ('static-string 'static-string) ; only available in codegen
  20       ('stack 'stack) ; only available in codegen (tag that value is passed via stack)
  21       (else 'app)))
  22    ((builtin? x) 'builtin)
  23    ((symbol? x) 'var)
  24    ((integer? x) 'int-literal)
  25    ((boolean? x) 'bool-literal)
  26    ((string? x) 'string-literal)))
  27
  28 (define (ast-traverse f x)
  29   (case (ast-type x)
  30     ('let `(let ,(map (lambda (x) (list (car x) (f (cadr x))))
  31                       (let-bindings x))
  32              ,@(map f (let-body x))))
  33     ('app (map f x))
  34     ('lambda `(lambda ,(lambda-args x) ,(f (lambda-body x))))
  35     ('if `(if ,@(map f (cdr x))))
  36     ('stack `(stack ,(cadr x) ,(map f (caddr x))))
  37     (else x)))
  38
  39 (define (ast-collect f x)
  40   (define (inner y) (ast-collect f y))
  41   (case (ast-type x)
  42     ['let (append (f x)
  43                   (flat-map inner (let-bindings x))
  44                   (flat-map inner (let-body x)))]
  45     ['app (append (f x)
  46                   (flat-map inner x))]
  47     ['lambda (append (f x)
  48                      (inner (lambda-body x)))]
  49     ['if (append (f x)
  50                  (flat-map inner (cdr x)))]
  51     ['stack (append (f x)
  52                     (inner (caddr x)))]
  53     [else (f x)]))
  54
  55 (define (ast-find p x)
  56   (define (inner y) (ast-find p y))
  57   (define (any p x) (fold-left
  58                      (lambda (acc y) (if acc #t (p y)))
  59                      #f
  60                      x))
  61   (define (either . fs)
  62     (if (null? fs) #f
  63         (if (car fs) (car fs)
  64             (apply either (cdr fs)))))
  65
  66   (case (ast-type x)
  67     ['let (either (p x)
  68                   (any inner (let-bindings x))
  69                   (any inner (let-body x)))]
  70     ['app (either (p x)
  71                   (any inner x))]
  72     ['lambda (either (p x)
  73                      (inner (lambda-body x)))]
  74     ['if (either (p x) (any inner (cdr x)))]
  75     ['stack (either (p x) (inner (caddr x)))]
  76     [else (p x)]))
  77
  78 (define (let-bindings e)
  79   (define (pattern-match binding body)
  80     (if (eqv? (ast-type binding) 'var)
  81         (list (cons binding body))
  82         (let* ([constructor (car binding)]
  83                [destructor (lambda (i) (dtor-name constructor i))])
  84           (flat-map (lambda (y i)
  85                       (pattern-match y `((,(destructor i) ,@body))))
  86                     (cdr binding)
  87                     (range 0 (length (cdr binding)))))))
  88   (flat-map (lambda (x) (pattern-match (car x) (cdr x))) (cadr e)))
  89 (define let-body cddr)
  90
  91 (define (lambda? x)
  92   (and (list? x) (eq? (car x) 'lambda)))
  93
  94
  95 (define (statement-type x)
  96   (cond
  97    [(and (list? x)
  98          (eqv? (car x) 'data)) 'data]
  99    [(and (list? x)
 100          (eqv? (car x) 'define)) 'define]
 101    [else 'expr]))
 102
 103
 104                                         ; (A ((foo (Int Bool))
 105                                         ;     (bar (Bool)))
 106 (define (program-data-layouts program)
 107   (map (lambda (x) (cons (car x) (cdr x))) ; convert to assoc list
 108        (map cdr (filter (lambda (x) (eqv? (statement-type x) 'data))
 109                         program))))
 110
 111 (define (program-defines program)
 112   (filter (lambda (x) (eqv? (statement-type x) 'defines))
 113           program))
 114
 115 (define (program-body program)
 116   ; hack to have multi-expression bodies
 117   `(let ()
 118      ,@(filter (lambda (x) (eqv? (statement-type x) 'expr))
 119                program)))
 120
 121                                         ; a data tor is either a constructor or destructor for an ADT
 122                                         ; data-tors returns constructors and destructors for a data-layout
 123                                         ; (data A (foo Int Bool)
 124                                         ;         (bar Bool))
 125                                         ;        |
 126                                         ;        v
 127                                         ; (foo   . ((A foo constructor) . (abs Int (abs Bool A))))
 128                                         ; (foo~0 . ((A foo 0)           . (abs A Int)))
 129                                         ; (foo~1 . ((A foo 1)           . (abs A Bool)))
 130                                         ; (bar   . ((A bar constructor) . (abs Bool A)))
 131                                         ; (bar~0 . ((A bar 0)           . (abs A Bool)))
 132                                         ;  ------+-------------------------------------
 133                                         ;  tor   | info                 | type
 134
 135 (define (data-tors data-layout)
 136   (define (constructor-type t products)
 137     (fold-right (lambda (x acc) `(abs ,x ,acc)) t products))
 138
 139   (define (destructor ctor-name prod-type part-type index)
 140     (let ([name (dtor-name ctor-name index)])
 141       (cons name (cons (list prod-type ctor-name index) `(abs ,prod-type ,part-type)))))
 142
 143   (let ([type-name (car data-layout)]
 144         [ctors (cdr data-layout)])
 145     (fold-right
 146      (lambda (ctor acc)
 147        (let* ([ctor-name (car ctor)]
 148               [products (cdr ctor)]
 149
 150               [maker (cons ctor-name (cons (list type-name ctor-name 'constructor) (constructor-type type-name products)))]
 151
 152               [dtors (map (lambda (t i) (destructor ctor-name type-name t i))
 153                           products
 154                           (range 0 (length products)))])
 155          (cons maker (append dtors acc))))
 156      '()
 157      ctors)))
 158
 159                                         ; creates a type environment for a given adt definition
 160 (define (data-tors-type-env data-layout)
 161   (map (lambda (x) (cons (car x) (cddr x))) (data-tors data-layout)))
 162
 163 (define (dtor-name ctor-name index)
 164   (string->symbol
 165    (string-append (symbol->string ctor-name)
 166                   "~"
 167                   (number->string index))))
 168
 169 ; for use in normalized form
 170 (define lambda-arg caadr)
 171 ; for use elsewhere
 172 (define lambda-args cadr)
 173 (define lambda-body caddr)
 174
 175 (define (references prog)
 176   (ast-collect
 177    (lambda (x)
 178      (case (ast-type x)
 179        ['var (list x)]
 180        [else '()]))
 181    prog))
 182
 183 (define (graph bs)
 184   (define (go bs orig-bs)
 185     (if (null? bs)
 186         '(() . ())
 187         (let* [(bind (car bs))
 188
 189                (vert (car bind))
 190                (refs (filter ; only count a reference if its a binding
 191                       (lambda (x) (assoc x orig-bs))
 192                       (references (cdr bind))))
 193                (edges (map (lambda (x) (cons vert x))
 194                            refs))
 195
 196                (rest (if (null? (cdr bs))
 197                          (cons '() '())
 198                          (go (cdr bs) orig-bs)))
 199                (total-verts (cons vert (car rest)))
 200                (total-edges (append edges (cdr rest)))]
 201           (cons total-verts total-edges))))
 202   (go bs bs))
 203
 204 (define (successors graph v)
 205   (define (go v E)
 206     (if (null? E)
 207         '()
 208         (if (eqv? v (caar E))
 209             (cons (cdar E) (go v (cdr E)))
 210             (go v (cdr E)))))
 211   (go v (cdr graph)))
 212
 213                                         ; takes in a graph (pair of vertices, edges)
 214                                         ; returns a list of strongly connected components
 215
 216                                         ; ((x y w) . ((x . y) (x . w) (w . x))
 217
 218                                         ; =>
 219                                         ; .->x->y
 220                                         ; |  |
 221                                         ; |  v
 222                                         ; .--w
 223
 224                                         ; ((x w) (y))
 225
 226                                         ; this uses tarjan's algorithm, to get reverse
 227                                         ; topological sorting for free
 228 (define (sccs graph)
 229
 230   (let* ([indices (make-hash-table)]
 231          [lowlinks (make-hash-table)]
 232          [on-stack (make-hash-table)]
 233          [current 0]
 234          [stack '()]
 235          [result '()])
 236
 237     (define (index v)
 238       (get-hash-table indices v #f))
 239     (define (lowlink v)
 240       (get-hash-table lowlinks v #f))
 241
 242     (letrec
 243         ([strong-connect
 244           (lambda (v)
 245             (begin
 246               (put-hash-table! indices v current)
 247               (put-hash-table! lowlinks v current)
 248               (set! current (+ current 1))
 249               (push! stack v)
 250               (put-hash-table! on-stack v #t)
 251
 252               (for-each
 253                (lambda (w)
 254                  (if (not (hashtable-contains? indices w))
 255                                         ; successor w has not been visited, recurse
 256                      (begin
 257                        (strong-connect w)
 258                        (put-hash-table! lowlinks
 259                                         v
 260                                         (min (lowlink v) (lowlink w))))
 261                                         ; successor w has been visited
 262                      (when (get-hash-table on-stack w #f)
 263                        (put-hash-table! lowlinks v (min (lowlink v) (index w))))))
 264                (successors graph v))
 265
 266               (when (= (index v) (lowlink v))
 267                 (let ([scc
 268                        (let new-scc ()
 269                          (let ([w (pop! stack)])
 270                            (put-hash-table! on-stack w #f)
 271                            (if (eqv? w v)
 272                                (list w)
 273                                (cons w (new-scc)))))])
 274                   (set! result (cons scc result))))))])
 275       (for-each
 276        (lambda (v)
 277          (when (not (hashtable-contains? indices v)) ; v.index == -1
 278            (strong-connect v)))
 279        (car graph)))
 280     result))
 281
 282
 283                                         ; utils
 284
 285 (define (range s n)
 286   (if (= 0 n) '()
 287       (append (range s (- n 1))
 288               (list (+ s (- n 1))))))
 289
 290 (define (flat-map f . xs) (fold-left append '() (apply map (cons f xs))))
 291 (define (repeat x n) (if (<= n 0) '()
 292                          (cons x (repeat x (- n 1)))))
 293
 294
 295 (define-syntax push!
 296   (syntax-rules ()
 297     ((_ s x) (set! s (cons x s)))))
 298
 299 (define-syntax pop!
 300   (syntax-rules ()
 301     ((_ s) (let ([x (car s)])
 302              (set! s (cdr s))
 303              x))))