ast.scm

   1 (define (ast-type x)
   2   (define (builtin? x)
   3     (case x
   4       ('+ #t)
   5       ('- #t)
   6       ('* #t)
   7       ('! #t)
   8       ('= #t)
   9       ('bool->int #t)
  10       ('print #t)
  11       (else #f)))
  12   (cond
  13    ((list? x)
  14     (case (car x)
  15       ('if 'if)
  16       ('let 'let)
  17       ('lambda 'lambda)
  18       ('closure 'closure) ; only available in codegen
  19       ('static-string 'static-string) ; only available in codegen
  20       ('stack 'stack) ; only available in codegen (tag that value is passed via stack)
  21       (else 'app)))
  22    ((builtin? x) 'builtin)
  23    ((symbol? x) 'var)
  24    ((integer? x) 'int-literal)
  25    ((boolean? x) 'bool-literal)
  26    ((string? x) 'string-literal)))
  27
  28 (define (ast-traverse f x)
  29   (case (ast-type x)
  30     ('let `(let ,(map (lambda (x) (list (car x) (f (cadr x))))
  31                       (let-bindings x))
  32              ,@(map f (let-body x))))
  33     ('app (map f x))
  34     ('lambda `(lambda ,(lambda-args x) ,(f (lambda-body x))))
  35     ('if `(if ,@(map f (cdr x))))
  36     ('stack `(stack ,(cadr x) ,(map f (caddr x))))
  37     (else x)))
  38
  39 (define (ast-collect f x)
  40   (define (inner y) (ast-collect f y))
  41   (case (ast-type x)
  42     ['let (append (f x)
  43                   (flat-map inner (let-bindings x))
  44                   (flat-map inner (let-body x)))]
  45     ['app (append (f x)
  46                   (flat-map inner x))]
  47     ['lambda (append (f x)
  48                      (inner (lambda-body x)))]
  49     ['if (append (f x)
  50                  (flat-map inner (cdr x)))]
  51     ['stack (append (f x)
  52                     (inner (caddr x)))]
  53     [else (f x)]))
  54
  55 (define (ast-find p x)
  56   (define (inner y) (ast-find p y))
  57   (define (any p x) (fold-left
  58                      (lambda (acc y) (if acc #t (p y)))
  59                      #f
  60                      x))
  61   (define (either . fs)
  62     (if (null? fs) #f
  63         (if (car fs) (car fs)
  64             (apply either (cdr fs)))))
  65
  66   (case (ast-type x)
  67     ['let (either (p x)
  68                   (any inner (let-bindings x))
  69                   (any inner (let-body x)))]
  70     ['app (either (p x)
  71                   (any inner x))]
  72     ['lambda (either (p x)
  73                      (inner (lambda-body x)))]
  74     ['if (either (p x) (any inner (cdr x)))]
  75     ['stack (either (p x) (inner (caddr x)))]
  76     [else (p x)]))
  77
  78 (define let-bindings cadr)
  79 (define let-body cddr)
  80
  81                                         ; (let ([(foo a b) (foo 123 345)]) a)
  82                                         ;   |
  83                                         ;   v
  84                                         ; (let ([a (foo~0 (foo 123 345)]
  85                                         ;       [b (foo~1 (foo 123 345)]) a)
  86 (define (expand-pattern-matches x)
  87   (define (pattern-match binding)
  88     (let ([binding-name (car binding)]
  89           [body (cadr binding)])
  90       (if (eqv? (ast-type binding-name) 'var)
  91           (list (list binding-name body))
  92           (let* ([sum-name (car binding-name)]
  93                  [destructor (lambda (i) (dtor-name sum-name i))])
  94             (flat-map (lambda (y i)
  95                         (pattern-match (list y `(,(destructor i) ,body))))
  96                       (cdr binding-name)
  97                       (range 0 (length (cdr binding-name))))))))
  98   (case (ast-type x)
  99       ['let `(let ,(flat-map pattern-match (let-bindings x))
 100                   ,@(map expand-pattern-matches (let-body x)))]
 101       [else (ast-traverse expand-pattern-matches x)]))
 102
 103 (define (lambda? x)
 104   (and (list? x) (eq? (car x) 'lambda)))
 105
 106
 107 (define (statement-type x)
 108   (cond
 109    [(and (list? x)
 110          (eqv? (car x) 'data)) 'data]
 111    [(and (list? x)
 112          (eqv? (car x) 'define)) 'define]
 113    [else 'expr]))
 114
 115
 116                                         ; (A ((foo (Int Bool))
 117                                         ;     (bar (Bool)))
 118 (define (program-data-layouts program)
 119   (map (lambda (x) (cons (car x) (cdr x))) ; convert to assoc list
 120        (map cdr (filter (lambda (x) (eqv? (statement-type x) 'data))
 121                         program))))
 122
 123 (define (program-defines program)
 124   (filter (lambda (x) (eqv? (statement-type x) 'defines))
 125           program))
 126
 127 (define (program-map-exprs f program)
 128   (map (lambda (x)
 129          (case (statement-type x)
 130            ['expr (f x)]
 131            [else x]))
 132        program))
 133
 134 (define (program-body program)
 135   ; hack to have multi-expression bodies
 136   `(let ()
 137      ,@(filter (lambda (x) (eqv? (statement-type x) 'expr))
 138                program)))
 139
 140                                         ; a data tor is either a constructor or destructor for an ADT
 141                                         ; data-tors returns constructors and destructors for a data-layout
 142                                         ; (data A (foo Int Bool)
 143                                         ;         (bar Bool))
 144                                         ;        |
 145                                         ;        v
 146                                         ; (foo   . ((A foo constructor) . (abs Int (abs Bool A))))
 147                                         ; (foo~0 . ((A foo 0)           . (abs A Int)))
 148                                         ; (foo~1 . ((A foo 1)           . (abs A Bool)))
 149                                         ; (bar   . ((A bar constructor) . (abs Bool A)))
 150                                         ; (bar~0 . ((A bar 0)           . (abs A Bool)))
 151                                         ;  ------+-------------------------------------
 152                                         ;  tor   | info                 | type
 153
 154 (define (data-tors data-layout)
 155   (define (constructor-type t products)
 156     (fold-right (lambda (x acc) `(abs ,x ,acc)) t products))
 157
 158   (define (destructor ctor-name prod-type part-type index)
 159     (let ([name (dtor-name ctor-name index)])
 160       (cons name (cons (list prod-type ctor-name index) `(abs ,prod-type ,part-type)))))
 161
 162   (let ([type-name (car data-layout)]
 163         [ctors (cdr data-layout)])
 164     (fold-right
 165      (lambda (ctor acc)
 166        (let* ([ctor-name (car ctor)]
 167               [products (cdr ctor)]
 168
 169               [maker (cons ctor-name (cons (list type-name ctor-name 'constructor) (constructor-type type-name products)))]
 170
 171               [dtors (map (lambda (t i) (destructor ctor-name type-name t i))
 172                           products
 173                           (range 0 (length products)))])
 174          (cons maker (append dtors acc))))
 175      '()
 176      ctors)))
 177
 178                                         ; creates a type environment for a given adt definition
 179 (define (data-tors-type-env data-layout)
 180   (map (lambda (x) (cons (car x) (cddr x))) (data-tors data-layout)))
 181
 182 (define (dtor-name ctor-name index)
 183   (string->symbol
 184    (string-append (symbol->string ctor-name)
 185                   "~"
 186                   (number->string index))))
 187
 188 ; for use in normalized form
 189 (define lambda-arg caadr)
 190 ; for use elsewhere
 191 (define lambda-args cadr)
 192 (define lambda-body caddr)
 193
 194 (define (references prog)
 195   (ast-collect
 196    (lambda (x)
 197      (case (ast-type x)
 198        ['var (list x)]
 199        [else '()]))
 200    prog))
 201
 202 (define (graph bs)
 203   (define (go bs orig-bs)
 204     (if (null? bs)
 205         '(() . ())
 206         (let* [(bind (car bs))
 207
 208                (vert (car bind))
 209                (refs (filter ; only count a reference if its a binding
 210                       (lambda (x) (assoc x orig-bs))
 211                       (references (cdr bind))))
 212                (edges (map (lambda (x) (cons vert x))
 213                            refs))
 214
 215                (rest (if (null? (cdr bs))
 216                          (cons '() '())
 217                          (go (cdr bs) orig-bs)))
 218                (total-verts (cons vert (car rest)))
 219                (total-edges (append edges (cdr rest)))]
 220           (cons total-verts total-edges))))
 221   (go bs bs))
 222
 223 (define (successors graph v)
 224   (define (go v E)
 225     (if (null? E)
 226         '()
 227         (if (eqv? v (caar E))
 228             (cons (cdar E) (go v (cdr E)))
 229             (go v (cdr E)))))
 230   (go v (cdr graph)))
 231
 232                                         ; takes in a graph (pair of vertices, edges)
 233                                         ; returns a list of strongly connected components
 234
 235                                         ; ((x y w) . ((x . y) (x . w) (w . x))
 236
 237                                         ; =>
 238                                         ; .->x->y
 239                                         ; |  |
 240                                         ; |  v
 241                                         ; .--w
 242
 243                                         ; ((x w) (y))
 244
 245                                         ; this uses tarjan's algorithm, to get reverse
 246                                         ; topological sorting for free
 247 (define (sccs graph)
 248
 249   (let* ([indices (make-hash-table)]
 250          [lowlinks (make-hash-table)]
 251          [on-stack (make-hash-table)]
 252          [current 0]
 253          [stack '()]
 254          [result '()])
 255
 256     (define (index v)
 257       (get-hash-table indices v #f))
 258     (define (lowlink v)
 259       (get-hash-table lowlinks v #f))
 260
 261     (letrec
 262         ([strong-connect
 263           (lambda (v)
 264             (begin
 265               (put-hash-table! indices v current)
 266               (put-hash-table! lowlinks v current)
 267               (set! current (+ current 1))
 268               (push! stack v)
 269               (put-hash-table! on-stack v #t)
 270
 271               (for-each
 272                (lambda (w)
 273                  (if (not (hashtable-contains? indices w))
 274                                         ; successor w has not been visited, recurse
 275                      (begin
 276                        (strong-connect w)
 277                        (put-hash-table! lowlinks
 278                                         v
 279                                         (min (lowlink v) (lowlink w))))
 280                                         ; successor w has been visited
 281                      (when (get-hash-table on-stack w #f)
 282                        (put-hash-table! lowlinks v (min (lowlink v) (index w))))))
 283                (successors graph v))
 284
 285               (when (= (index v) (lowlink v))
 286                 (let ([scc
 287                        (let new-scc ()
 288                          (let ([w (pop! stack)])
 289                            (put-hash-table! on-stack w #f)
 290                            (if (eqv? w v)
 291                                (list w)
 292                                (cons w (new-scc)))))])
 293                   (set! result (cons scc result))))))])
 294       (for-each
 295        (lambda (v)
 296          (when (not (hashtable-contains? indices v)) ; v.index == -1
 297            (strong-connect v)))
 298        (car graph)))
 299     result))
 300
 301
 302                                         ; utils
 303
 304 (define (range s n)
 305   (if (= 0 n) '()
 306       (append (range s (- n 1))
 307               (list (+ s (- n 1))))))
 308
 309 (define (flat-map f . xs) (fold-left append '() (apply map (cons f xs))))
 310 (define (repeat x n) (if (<= n 0) '()
 311                          (cons x (repeat x (- n 1)))))
 312
 313
 314 (define-syntax push!
 315   (syntax-rules ()
 316     ((_ s x) (set! s (cons x s)))))
 317
 318 (define-syntax pop!
 319   (syntax-rules ()
 320     ((_ s) (let ([x (car s)])
 321              (set! s (cdr s))
 322              x))))