X-Git-Url: https://git.lukelau.me/?p=opengl.git;a=blobdiff_plain;f=brdffrag.glsl;fp=brdffrag.glsl;h=93403de59ea5e6c7301206ef1d125821cdeaf63b;hp=0000000000000000000000000000000000000000;hb=d80972d96e5fcd444657f937ab2700039efa83d2;hpb=9e43c799021b7bcca324b988aae44e98b05d10b4

diff --git a/brdffrag.glsl b/brdffrag.glsl
new file mode 100644
index 0000000..93403de
--- /dev/null
+++ b/brdffrag.glsl
@@ -0,0 +1,90 @@
+#version 330
+
+in vec2 texCoords;
+out vec4 fragColor;
+
+const float PI = 3.14159265359;
+
+//TODO: Put this in a separate shader program
+float radicalInverse(uint bits) {
+	bits = (bits << 16u) | (bits >> 16u);
+	bits = ((bits & 0x55555555u) << 1u) | ((bits & 0xAAAAAAAAu) >> 1u);
+    bits = ((bits & 0x33333333u) << 2u) | ((bits & 0xCCCCCCCCu) >> 2u);
+    bits = ((bits & 0x0F0F0F0Fu) << 4u) | ((bits & 0xF0F0F0F0u) >> 4u);
+    bits = ((bits & 0x00FF00FFu) << 8u) | ((bits & 0xFF00FF00u) >> 8u);
+    return float(bits) * 2.3283064365386963e-10;
+}
+
+vec2 hammersley(uint i, uint N) {
+	return vec2(float(i) / float(N), radicalInverse(i));
+}
+
+float geometrySchlickGGX(float NdotV, float roughness) {
+	float a = roughness * roughness;
+	float k = (a * a) / 2.f;
+	
+	return NdotV / (NdotV * (1.f - k) + k);
+}
+
+float geometrySmith(vec3 N, vec3 V, vec3 L, float roughness) {
+	float ggx1 = geometrySchlickGGX(max(dot(N, L), 0.f), roughness);
+	float ggx2 = geometrySchlickGGX(max(dot(N, V), 0.f), roughness);
+	return ggx1 * ggx2;
+}
+
+vec3 importanceSampleGGX(vec2 Xi, vec3 N, float roughness) {
+	float a = roughness * roughness;
+
+	float phi = 2.f * PI * Xi.x;
+	float cosTheta = sqrt((1.f - Xi.y) / (1.f + (a * a - 1.f) * Xi.y));
+	float sinTheta = sqrt(1.f - cosTheta * cosTheta);
+
+	// spherical -> cartesian
+	vec3 H = vec3(cos(phi) * sinTheta, sin(phi) * sinTheta, cosTheta);
+
+	vec3 up = abs(N.z) < 0.999 ? vec3(0, 0, 1) : vec3(1, 0, 0);
+	vec3 tangent = normalize(cross(up, N));
+	vec3 bitangent = cross(N, tangent);
+
+	vec3 sampleVec = tangent * H.x + bitangent * H.y + N * H.z;
+	return normalize(sampleVec);
+}
+
+vec2 integrateBRDF(float NdotV, float roughness) {
+	vec3 V = vec3(sqrt(1.f - NdotV * NdotV), 0.f, NdotV);
+
+	float A = 0, B = 0;
+
+	vec3 N = vec3(0, 0, 1);
+
+	const uint sampleCount = 1024u;
+	for (uint i = 0u; i < sampleCount; i++) {
+		vec2 Xi = hammersley(i, sampleCount);
+		vec3 H = importanceSampleGGX(Xi, N, roughness);
+		vec3 L = normalize(2.f * dot(V, H) * H - V);
+
+		float NdotL = max(L.z, 0.f);
+		float NdotH = max(H.z, 0.f);
+		float VdotH = max(dot(V, H), 0.f);
+
+		if (NdotL > 0) {
+			float G = geometrySmith(N, V, L, roughness);
+			float Gvis = (G * VdotH) / (NdotH * NdotV);
+			float Fc = pow(1.f - VdotH, 5.f);
+
+			A += (1.f - Fc) * Gvis;
+			B += Fc * Gvis;
+		}
+	}
+
+	A /= float(sampleCount);
+	B /= float(sampleCount);
+
+	return vec2(A, B);
+}
+
+void main() {
+	fragColor = vec4(integrateBRDF(texCoords.x, texCoords.y), 0, 0);
+}
+
+