#version 330

#define mdot(x, y) (max(dot(x, y), 0.f))

in vec3 worldPos, normal;
in vec2 texCoords;

uniform vec3 camPos;

uniform sampler2D albedoMap;
uniform sampler2D normalMap;
uniform sampler2D metallicMap;
uniform sampler2D roughnessMap;
uniform sampler2D aoMap;
uniform samplerCube irradianceMap;

out vec4 fragColor;

uniform vec3 lightPositions[4];
uniform vec3 lightColors[4];

const float PI = 3.14159265359;

vec3 fresnelSchlick(float cosTheta, vec3 F0) {
	return F0 + (1.f - F0) * pow(1.f - cosTheta, 5.f);
}

vec3 fresnelSchlickRoughness(float cosTheta, vec3 F0, float roughness) {
	return F0 + (max(vec3(1.f - roughness), F0) - F0) * pow(1.f - cosTheta, 5.f);
}

float distributionGGX(vec3 N, vec3 H, float roughness) {
	float a = roughness * roughness;
	float NdotH = mdot(N, H);
	float denom = (NdotH * NdotH) * ((a * a) - 1.f) + 1.f;
	denom = PI * denom * denom;
	return (a * a) / denom;
}

float geometrySchlickGGX(float NdotV, float roughness) {
	float r = roughness + 1.f;
	float k = (r * r) / 8.f;
	return NdotV / (NdotV * (1.f - k) + k);
}

float geometrySmith(vec3 N, vec3 V, vec3 L, float roughness) {
	float ggx1 = geometrySchlickGGX(mdot(N, L), roughness);
	float ggx2 = geometrySchlickGGX(mdot(N, V), roughness);
	return ggx1 * ggx2;
}

vec3 getNormalFromMap() {
	vec3 tangentNormal = texture(normalMap, texCoords).xyz * 2.f - 1.f;
	vec3 Q1 = dFdx(worldPos);
    vec3 Q2 = dFdy(worldPos);
    vec2 st1 = dFdx(texCoords);
    vec2 st2 = dFdy(texCoords);

    vec3 N = normalize(normal);
    vec3 T = normalize(Q1 * st2.t - Q2 * st1.t);
    vec3 B = -normalize(cross(N, T));
    mat3 TBN = mat3(T, B, N);

    return normalize(TBN * tangentNormal);
}

void main() {
	vec3 albedo = pow(texture(albedoMap, texCoords).rgb, vec3(2.2));
	vec3 normal = getNormalFromMap();
	float metallic = texture(metallicMap, texCoords).r;
	float roughness = texture(roughnessMap, texCoords).r;
	float ao = texture(aoMap, texCoords).r;

	vec3 N = normalize(normal);
	vec3 V = normalize(camPos - worldPos);

	vec3 F0 = mix(vec3(0.04), albedo, metallic);

	// reflectance
	vec3 Lo = vec3(0.f);
	for (int i = 0; i < lightPositions.length(); i++) {
		vec3 L = normalize(lightPositions[i] - worldPos);
		vec3 H = normalize(V + L);

		// calculate radiance
		float dist = length(lightPositions[i] - worldPos);
		float attenuation = 5.f / (dist * dist);
		vec3 radiance = lightColors[i] * attenuation;

		// cook-torrance brdf
		vec3 F = fresnelSchlick(mdot(H, V), F0);
		float NDF = distributionGGX(N, H, roughness);
		float G = geometrySmith(N, V, L, roughness);

		float denom = 4.f * mdot(N, V) * mdot(N, L);
		vec3 specular = (NDF * G * F) / max(denom, 0.0000001);

		vec3 kS = F; // fresnel = reflection ratio
		vec3 kD = vec3(1.f) - kS;
		kD *= 1.f - metallic;

		Lo += (kD * albedo / PI + specular) * radiance * mdot(N, L);
	}

	vec3 kD = 1.f - fresnelSchlickRoughness(mdot(N, V), F0, roughness);
	vec3 diffuse = texture(irradianceMap, N).rgb * albedo;
	vec3 ambient = (kD * diffuse) * ao;
	vec3 color = ambient + Lo;

	color = color / (color + vec3(1.f)); // map to HDR
	color = pow(color, vec3(1.f / 2.2)); // gamma correction

	fragColor = vec4(color, 1.f);
}