pbrfrag.glsl

   1 #version 330
   2
   3 #define mdot(x, y) (max(dot(x, y), 0.f))
   4
   5 in vec3 worldPos, normal;
   6 in vec2 texCoords;
   7
   8 uniform vec3 camPos;
   9
  10 uniform sampler2D albedoMap;
  11 uniform sampler2D normalMap;
  12 uniform sampler2D metallicMap;
  13 uniform sampler2D roughnessMap;
  14 uniform sampler2D aoMap;
  15 uniform samplerCube irradianceMap;
  16 uniform samplerCube prefilterMap;
  17 uniform sampler2D brdfMap;
  18
  19 out vec4 fragColor;
  20
  21 uniform vec3 lightPositions[4];
  22 uniform vec3 lightColors[4];
  23
  24 const float PI = 3.14159265359;
  25
  26 vec3 fresnelSchlick(float cosTheta, vec3 F0) {
  27         return F0 + (1.f - F0) * pow(1.f - cosTheta, 5.f);
  28 }
  29
  30 vec3 fresnelSchlickRoughness(float cosTheta, vec3 F0, float roughness) {
  31         return F0 + (max(vec3(1.f - roughness), F0) - F0) * pow(1.f - cosTheta, 5.f);
  32 }
  33
  34 float distributionGGX(vec3 N, vec3 H, float roughness) {
  35         float a = roughness * roughness;
  36         float NdotH = mdot(N, H);
  37         float denom = (NdotH * NdotH) * ((a * a) - 1.f) + 1.f;
  38         denom = PI * denom * denom;
  39         return (a * a) / denom;
  40 }
  41
  42 float geometrySchlickGGX(float NdotV, float roughness) {
  43         float r = roughness + 1.f;
  44         float k = (r * r) / 8.f;
  45         return NdotV / (NdotV * (1.f - k) + k);
  46 }
  47
  48 float geometrySmith(vec3 N, vec3 V, vec3 L, float roughness) {
  49         float ggx1 = geometrySchlickGGX(mdot(N, L), roughness);
  50         float ggx2 = geometrySchlickGGX(mdot(N, V), roughness);
  51         return ggx1 * ggx2;
  52 }
  53
  54 vec3 getNormalFromMap() {
  55         vec3 tangentNormal = texture(normalMap, texCoords).xyz * 2.f - 1.f;
  56         vec3 Q1 = dFdx(worldPos);
  57     vec3 Q2 = dFdy(worldPos);
  58     vec2 st1 = dFdx(texCoords);
  59     vec2 st2 = dFdy(texCoords);
  60
  61     vec3 N = normalize(normal);
  62     vec3 T = normalize(Q1 * st2.t - Q2 * st1.t);
  63     vec3 B = -normalize(cross(N, T));
  64     mat3 TBN = mat3(T, B, N);
  65
  66     return normalize(TBN * tangentNormal);
  67 }
  68
  69 void main() {
  70         vec3 albedo = pow(texture(albedoMap, texCoords).rgb, vec3(2.2));
  71         vec3 normal = getNormalFromMap();
  72         float metallic = texture(metallicMap, texCoords).r;
  73         float roughness = texture(roughnessMap, texCoords).r;
  74         float ao = texture(aoMap, texCoords).r;
  75
  76         vec3 N = normalize(normal);
  77         vec3 V = normalize(camPos - worldPos);
  78
  79         vec3 F0 = mix(vec3(0.04), albedo, metallic);
  80
  81         vec3 R = reflect(-V, N);
  82
  83         // reflectance
  84         vec3 Lo = vec3(0.f);
  85         for (int i = 0; i < lightPositions.length(); i++) {
  86                 vec3 L = normalize(lightPositions[i] - worldPos);
  87                 vec3 H = normalize(V + L);
  88
  89                 // calculate radiance
  90                 float dist = length(lightPositions[i] - worldPos);
  91                 float attenuation = 5.f / (dist * dist);
  92                 vec3 radiance = lightColors[i] * attenuation;
  93
  94                 // cook-torrance brdf
  95                 vec3 F = fresnelSchlick(mdot(H, V), F0);
  96                 float NDF = distributionGGX(N, H, roughness);
  97                 float G = geometrySmith(N, V, L, roughness);
  98
  99                 float denom = 4.f * mdot(N, V) * mdot(N, L);
 100                 vec3 specular = (NDF * G * F) / max(denom, 0.0000001);
 101
 102                 vec3 kS = F; // fresnel = reflection ratio
 103                 vec3 kD = vec3(1.f) - kS;
 104                 kD *= 1.f - metallic;
 105
 106                 Lo += (kD * albedo / PI + specular) * radiance * mdot(N, L);
 107         }
 108
 109         vec3 F = fresnelSchlickRoughness(mdot(N, V), F0, roughness);
 110
 111         vec3 kS = F;
 112         vec3 kD = (1.f - kS) * (1.f - metallic);
 113
 114         vec3 irradiance = texture(irradianceMap, N).rgb;
 115         vec3 diffuse = irradiance * albedo;
 116
 117         const float maxReflectionLoD = 4.f;
 118         vec3 prefilteredColor = textureLod(prefilterMap, R, roughness * maxReflectionLoD).rgb;
 119         vec2 envBRDF = texture(brdfMap, vec2(mdot(N, V), roughness)).rg;
 120         vec3 specular = prefilteredColor * (F * envBRDF.x + envBRDF.y);
 121
 122         vec3 ambient = (kD * diffuse + specular) * ao;
 123         vec3 color = ambient + Lo;
 124
 125         color = color / (color + vec3(1.f)); // map to HDR
 126         color = pow(color, vec3(1.f / 2.2)); // gamma correction
 127
 128         fragColor = vec4(color, 1.f);
 129 }