pbrfrag.glsl

   1 #version 330
   2
   3 #define mdot(x, y) (max(dot(x, y), 0.f))
   4
   5 in vec3 worldPos, normal;
   6 in vec2 texCoords;
   7
   8 uniform vec3 camPos;
   9
  10 struct Material {
  11         sampler2D albedoMap;
  12         sampler2D normalMap;
  13         sampler2D metallicRoughnessMap;
  14         sampler2D aoMap;
  15         bool hasAlbedo, hasNormal, hasMetallicRoughness, hasAo;
  16 };
  17 uniform Material mat;
  18
  19 uniform samplerCube irradianceMap;
  20 uniform samplerCube prefilterMap;
  21 uniform sampler2D brdfMap;
  22
  23 out vec4 fragColor;
  24
  25 uniform int numLights;
  26 uniform vec3 lightPositions[8];
  27 uniform vec3 lightColors[8];
  28
  29 const float PI = 3.14159265359;
  30
  31 vec3 fresnelSchlick(float cosTheta, vec3 F0) {
  32         return F0 + (1.f - F0) * pow(1.f - cosTheta, 5.f);
  33 }
  34
  35 vec3 fresnelSchlickRoughness(float cosTheta, vec3 F0, float roughness) {
  36         return F0 + (max(vec3(1.f - roughness), F0) - F0) * pow(1.f - cosTheta, 5.f);
  37 }
  38
  39 float distributionGGX(vec3 N, vec3 H, float roughness) {
  40         float a = roughness * roughness;
  41         float NdotH = mdot(N, H);
  42         float denom = (NdotH * NdotH) * ((a * a) - 1.f) + 1.f;
  43         denom = PI * denom * denom;
  44         return (a * a) / denom;
  45 }
  46
  47 float geometrySchlickGGX(float NdotV, float roughness) {
  48         float r = roughness + 1.f;
  49         float k = (r * r) / 8.f;
  50         return NdotV / (NdotV * (1.f - k) + k);
  51 }
  52
  53 float geometrySmith(vec3 N, vec3 V, vec3 L, float roughness) {
  54         float ggx1 = geometrySchlickGGX(mdot(N, L), roughness);
  55         float ggx2 = geometrySchlickGGX(mdot(N, V), roughness);
  56         return ggx1 * ggx2;
  57 }
  58
  59 vec3 getNormalFromMap() {
  60         vec3 tangentNormal = vec3(0, 0, 1);
  61         if (mat.hasNormal)
  62                 tangentNormal = texture(mat.normalMap, texCoords).xyz * 2.f - 1.f;
  63         vec3 Q1 = dFdx(worldPos);
  64     vec3 Q2 = dFdy(worldPos);
  65     vec2 st1 = dFdx(texCoords);
  66     vec2 st2 = dFdy(texCoords);
  67
  68     vec3 N = normalize(normal);
  69     vec3 T = normalize(Q1 * st2.t - Q2 * st1.t);
  70     vec3 B = -normalize(cross(N, T));
  71     mat3 TBN = mat3(T, B, N);
  72
  73     return normalize(TBN * tangentNormal);
  74 }
  75
  76 void main() {
  77         vec3 albedo = vec3(1);
  78         if (mat.hasAlbedo)
  79                 albedo = pow(texture(mat.albedoMap, texCoords).rgb, vec3(2.2));
  80
  81         vec3 normal = getNormalFromMap();
  82
  83         float metallic = 0, roughness = 1;
  84         if (mat.hasMetallicRoughness) {
  85                 metallic = texture(mat.metallicRoughnessMap, texCoords).b;
  86                 roughness = texture(mat.metallicRoughnessMap, texCoords).g;
  87         }
  88         float ao = mat.hasAo ? texture(mat.aoMap, texCoords).r : 1;
  89
  90         vec3 N = normalize(normal);
  91         vec3 V = normalize(camPos - worldPos);
  92
  93         vec3 F0 = mix(vec3(0.04), albedo, metallic);
  94
  95         vec3 R = reflect(-V, N);
  96
  97         // reflectance
  98         vec3 Lo = vec3(0.f);
  99         for (int i = 0; i < numLights; i++) {
 100                 vec3 L = normalize(lightPositions[i] - worldPos);
 101                 vec3 H = normalize(V + L);
 102
 103                 // calculate radiance
 104                 float dist = length(lightPositions[i] - worldPos);
 105                 float attenuation = 5.f / (dist * dist);
 106                 vec3 radiance = lightColors[i] * attenuation;
 107
 108                 // cook-torrance brdf
 109                 vec3 F = fresnelSchlick(mdot(H, V), F0);
 110                 float NDF = distributionGGX(N, H, roughness);
 111                 float G = geometrySmith(N, V, L, roughness);
 112
 113                 float denom = 4.f * mdot(N, V) * mdot(N, L);
 114                 vec3 specular = (NDF * G * F) / max(denom, 0.0000001);
 115
 116                 vec3 kS = F; // fresnel = reflection ratio
 117                 vec3 kD = vec3(1.f) - kS;
 118                 kD *= 1.f - metallic;
 119
 120                 Lo += (kD * albedo / PI + specular) * radiance * mdot(N, L);
 121         }
 122
 123         vec3 F = fresnelSchlickRoughness(mdot(N, V), F0, roughness);
 124
 125         vec3 kS = F;
 126         vec3 kD = (1.f - kS) * (1.f - metallic);
 127
 128         vec3 irradiance = texture(irradianceMap, N).rgb;
 129         vec3 diffuse = irradiance * albedo;
 130
 131         const float maxReflectionLoD = 4.f;
 132         vec3 prefilteredColor = textureLod(prefilterMap, R, roughness * maxReflectionLoD).rgb;
 133         vec2 envBRDF = texture(brdfMap, vec2(mdot(N, V), roughness)).rg;
 134         vec3 specular = prefilteredColor * (F * envBRDF.x + envBRDF.y);
 135
 136         vec3 ambient = (kD * diffuse + specular) * ao;
 137         vec3 color = ambient + Lo;
 138
 139         color = color / (color + vec3(1.f)); // map to HDR
 140         color = pow(color, vec3(1.f / 2.2)); // gamma correction
 141
 142         fragColor = vec4(color, 1.f);
 143 }