pbrfrag.glsl

   1 #version 330
   2
   3 #define mdot(x, y) (max(dot(x, y), 0.f))
   4
   5 in vec3 worldPos, normal;
   6 in vec2 texCoords;
   7
   8 uniform vec3 camPos;
   9
  10 struct Material {
  11         sampler2D albedoMap;
  12         sampler2D normalMap;
  13         sampler2D metallicRoughnessMap;
  14         sampler2D aoMap;
  15         bool hasAlbedo, hasNormal, hasMetallicRoughness, hasAo;
  16 };
  17 uniform Material mat;
  18
  19 uniform samplerCube irradianceMap;
  20 uniform samplerCube prefilterMap;
  21 uniform sampler2D brdfMap;
  22
  23 out vec4 fragColor;
  24
  25 uniform vec3 lightPositions[6];
  26 uniform vec3 lightColors[6];
  27
  28 const float PI = 3.14159265359;
  29
  30 vec3 fresnelSchlick(float cosTheta, vec3 F0) {
  31         return F0 + (1.f - F0) * pow(1.f - cosTheta, 5.f);
  32 }
  33
  34 vec3 fresnelSchlickRoughness(float cosTheta, vec3 F0, float roughness) {
  35         return F0 + (max(vec3(1.f - roughness), F0) - F0) * pow(1.f - cosTheta, 5.f);
  36 }
  37
  38 float distributionGGX(vec3 N, vec3 H, float roughness) {
  39         float a = roughness * roughness;
  40         float NdotH = mdot(N, H);
  41         float denom = (NdotH * NdotH) * ((a * a) - 1.f) + 1.f;
  42         denom = PI * denom * denom;
  43         return (a * a) / denom;
  44 }
  45
  46 float geometrySchlickGGX(float NdotV, float roughness) {
  47         float r = roughness + 1.f;
  48         float k = (r * r) / 8.f;
  49         return NdotV / (NdotV * (1.f - k) + k);
  50 }
  51
  52 float geometrySmith(vec3 N, vec3 V, vec3 L, float roughness) {
  53         float ggx1 = geometrySchlickGGX(mdot(N, L), roughness);
  54         float ggx2 = geometrySchlickGGX(mdot(N, V), roughness);
  55         return ggx1 * ggx2;
  56 }
  57
  58 vec3 getNormalFromMap() {
  59         vec3 tangentNormal = vec3(0, 0, 1);
  60         if (mat.hasNormal)
  61                 tangentNormal = texture(mat.normalMap, texCoords).xyz * 2.f - 1.f;
  62         vec3 Q1 = dFdx(worldPos);
  63     vec3 Q2 = dFdy(worldPos);
  64     vec2 st1 = dFdx(texCoords);
  65     vec2 st2 = dFdy(texCoords);
  66
  67     vec3 N = normalize(normal);
  68     vec3 T = normalize(Q1 * st2.t - Q2 * st1.t);
  69     vec3 B = -normalize(cross(N, T));
  70     mat3 TBN = mat3(T, B, N);
  71
  72     return normalize(TBN * tangentNormal);
  73 }
  74
  75 void main() {
  76         vec3 albedo = vec3(1);
  77         if (mat.hasAlbedo)
  78                 albedo = pow(texture(mat.albedoMap, texCoords).rgb, vec3(2.2));
  79
  80         vec3 normal = getNormalFromMap();
  81
  82         float metallic = 0, roughness = 1;
  83         if (mat.hasMetallicRoughness) {
  84                 metallic = texture(mat.metallicRoughnessMap, texCoords).b;
  85                 roughness = texture(mat.metallicRoughnessMap, texCoords).g;
  86         }
  87         float ao = mat.hasAo ? texture(mat.aoMap, texCoords).r : 1;
  88
  89         vec3 N = normalize(normal);
  90         vec3 V = normalize(camPos - worldPos);
  91
  92         vec3 F0 = mix(vec3(0.04), albedo, metallic);
  93
  94         vec3 R = reflect(-V, N);
  95
  96         // reflectance
  97         vec3 Lo = vec3(0.f);
  98         for (int i = 0; i < lightPositions.length(); i++) {
  99                 vec3 L = normalize(lightPositions[i] - worldPos);
 100                 vec3 H = normalize(V + L);
 101
 102                 // calculate radiance
 103                 float dist = length(lightPositions[i] - worldPos);
 104                 float attenuation = 5.f / (dist * dist);
 105                 vec3 radiance = lightColors[i] * attenuation;
 106
 107                 // cook-torrance brdf
 108                 vec3 F = fresnelSchlick(mdot(H, V), F0);
 109                 float NDF = distributionGGX(N, H, roughness);
 110                 float G = geometrySmith(N, V, L, roughness);
 111
 112                 float denom = 4.f * mdot(N, V) * mdot(N, L);
 113                 vec3 specular = (NDF * G * F) / max(denom, 0.0000001);
 114
 115                 vec3 kS = F; // fresnel = reflection ratio
 116                 vec3 kD = vec3(1.f) - kS;
 117                 kD *= 1.f - metallic;
 118
 119                 Lo += (kD * albedo / PI + specular) * radiance * mdot(N, L);
 120         }
 121
 122         vec3 F = fresnelSchlickRoughness(mdot(N, V), F0, roughness);
 123
 124         vec3 kS = F;
 125         vec3 kD = (1.f - kS) * (1.f - metallic);
 126
 127         vec3 irradiance = texture(irradianceMap, N).rgb;
 128         vec3 diffuse = irradiance * albedo;
 129
 130         const float maxReflectionLoD = 4.f;
 131         vec3 prefilteredColor = textureLod(prefilterMap, R, roughness * maxReflectionLoD).rgb;
 132         vec2 envBRDF = texture(brdfMap, vec2(mdot(N, V), roughness)).rg;
 133         vec3 specular = prefilteredColor * (F * envBRDF.x + envBRDF.y);
 134
 135         vec3 ambient = (kD * diffuse + specular) * ao;
 136         vec3 color = ambient + Lo;
 137
 138         color = color / (color + vec3(1.f)); // map to HDR
 139         color = pow(color, vec3(1.f / 2.2)); // gamma correction
 140
 141         fragColor = vec4(color, 1.f);
 142 }