X-Git-Url: https://git.lukelau.me/?a=blobdiff_plain;f=src%2FLanguage%2FHaskell%2FLSP%2FTest%2FParsing.hs;h=acd458c77a76df9e65dfb4e8ec1952681ff89969;hb=8802accf03b0bd9f063e5563ed769b23c6750fd8;hp=2e829f372284373fa6d5673f9509e140c250387e;hpb=12ac9c23d054e92a82146320e2b061c11a87e3f1;p=lsp-test.git

diff --git a/src/Language/Haskell/LSP/Test/Parsing.hs b/src/Language/Haskell/LSP/Test/Parsing.hs
index 2e829f3..acd458c 100644
--- a/src/Language/Haskell/LSP/Test/Parsing.hs
+++ b/src/Language/Haskell/LSP/Test/Parsing.hs
@@ -1,131 +1,219 @@
 {-# LANGUAGE MultiParamTypeClasses #-}
-{-# LANGUAGE FlexibleInstances #-}
+{-# LANGUAGE EmptyCase #-}
+{-# LANGUAGE TypeOperators #-}
 {-# LANGUAGE ScopedTypeVariables #-}
+{-# LANGUAGE PolyKinds #-}
+{-# LANGUAGE KindSignatures #-}
+{-# LANGUAGE DataKinds #-}
+{-# LANGUAGE GADTs #-}
+{-# LANGUAGE LambdaCase #-}
 {-# LANGUAGE RankNTypes #-}
-module Language.Haskell.LSP.Test.Parsing where
+{-# LANGUAGE OverloadedStrings #-}
+
+module Language.Haskell.LSP.Test.Parsing
+  ( -- $receiving
+    satisfy
+  , satisfyMaybe
+  , message
+  , responseForId
+  , customRequest
+  , customNotification
+  , anyRequest
+  , anyResponse
+  , anyNotification
+  , anyMessage
+  , loggingNotification
+  , publishDiagnosticsNotification
+  ) where
 
 import Control.Applicative
-import Control.Concurrent.Chan
-import Control.Concurrent.MVar
-import Control.Monad.Trans.Class
+import Control.Concurrent
+import Control.Lens
 import Control.Monad.IO.Class
-import Control.Monad.Trans.Reader
-import Control.Monad.Trans.State
-import Data.Aeson
-import qualified Data.ByteString.Lazy.Char8 as B
-import Data.Conduit hiding (await)
-import Data.Conduit.Parser
-import Data.Maybe
-import Language.Haskell.LSP.Messages
+import Control.Monad
+import Data.Conduit.Parser hiding (named)
+import qualified Data.Conduit.Parser (named)
+import Data.GADT.Compare
+import qualified Data.Text as T
+import Data.Typeable
 import Language.Haskell.LSP.Types
-import Language.Haskell.LSP.Test.Decoding
-import Language.Haskell.LSP.Test.Messages
-import System.IO
-
-data SessionContext = SessionContext
-  {
-    serverIn :: Handle,
-    rootDir :: FilePath,
-    messageChan :: Chan FromServerMessage,
-    requestMap :: MVar RequestMap
-  }
-
-newtype SessionState = SessionState
-  {
-    curReqId :: LspId
-  }
-
-type ParserStateReader a s r m = ConduitParser a (StateT s (ReaderT r m))
-
--- | A session representing one instance of launching and connecting to a server.
+import Language.Haskell.LSP.Test.Session
+
+-- $receiving
+-- To receive a message, specify the method of the message to expect:
+--
+-- @
+-- msg1 <- message SWorkspaceApplyEdit
+-- msg2 <- message STextDocumentHover
+-- @
 --
--- You can send and receive messages to the server within 'Session' via 'getMessage',
--- 'sendRequest' and 'sendNotification'.
+-- 'Language.Haskell.LSP.Test.Session' is actually just a parser
+-- that operates on messages under the hood. This means that you
+-- can create and combine parsers to match speicifc sequences of
+-- messages that you expect.
+--
+-- For example, if you wanted to match either a definition or
+-- references request:
+--
+-- > defOrImpl = message STextDocumentDefinition
+-- >          <|> message STextDocumentReferences
+--
+-- If you wanted to match any number of telemetry
+-- notifications immediately followed by a response:
 --
 -- @
--- runSession \"path\/to\/root\/dir\" $ do
---   docItem <- getDocItem "Desktop/simple.hs" "haskell"
---   sendNotification TextDocumentDidOpen (DidOpenTextDocumentParams docItem)
---   diagnostics <- getMessage :: Session PublishDiagnosticsNotification
+-- logThenDiags =
+--  skipManyTill (message STelemetryEvent)
+--               anyResponse
 -- @
-type Session = ParserStateReader FromServerMessage SessionState SessionContext IO
 
--- | Matches if the message is a notification.
-anyNotification :: Monad m => ConduitParser FromServerMessage m FromServerMessage
-anyNotification = satisfy isServerNotification
+-- | Consumes and returns the next message, if it satisfies the specified predicate.
+--
+-- @since 0.5.2.0
+satisfy :: (FromServerMessage -> Bool) -> Session FromServerMessage
+satisfy pred = satisfyMaybe (\msg -> if pred msg then Just msg else Nothing)
 
-notification :: forall m a. (Monad m, FromJSON a) => ConduitParser FromServerMessage m (NotificationMessage ServerMethod a)
-notification = do
-  let parser = decode . encodeMsg :: FromServerMessage -> Maybe (NotificationMessage ServerMethod a)
-  x <- satisfy (isJust . parser)
-  return $ fromJust $ decode $ encodeMsg x
+-- | Consumes and returns the result of the specified predicate if it returns `Just`.
+--
+-- @since 0.6.1.0
+satisfyMaybe :: (FromServerMessage -> Maybe a) -> Session a
+satisfyMaybe pred = satisfyMaybeM (pure . pred)
+
+satisfyMaybeM :: (FromServerMessage -> Session (Maybe a)) -> Session a
+satisfyMaybeM pred = do 
+  
+  skipTimeout <- overridingTimeout <$> get
+  timeoutId <- getCurTimeoutId
+  unless skipTimeout $ do
+    chan <- asks messageChan
+    timeout <- asks (messageTimeout . config)
+    void $ liftIO $ forkIO $ do
+      threadDelay (timeout * 1000000)
+      writeChan chan (TimeoutMessage timeoutId)
+
+  x <- Session await
+
+  unless skipTimeout (bumpTimeoutId timeoutId)
+
+  modify $ \s -> s { lastReceivedMessage = Just x }
+
+  res <- pred x
+
+  case res of
+    Just a -> do
+      logMsg LogServer x
+      return a
+    Nothing -> empty
+
+named :: T.Text -> Session a -> Session a
+named s (Session x) = Session (Data.Conduit.Parser.named s x)
+
+mEq :: SServerMethod m1 -> SServerMethod m2 -> Maybe (m1 :~~: m2)
+mEq m1 m2 = case (splitServerMethod m1, splitServerMethod m2) of
+  (IsServerNot, IsServerNot) -> do
+    Refl <- geq m1 m2
+    pure HRefl
+  (IsServerReq, IsServerReq) -> do
+    Refl <- geq m1 m2
+    pure HRefl
+  _ -> Nothing
+
+mEqClient :: SClientMethod m1 -> SClientMethod m2 -> Maybe (m1 :~~: m2)
+mEqClient m1 m2 = case (splitClientMethod m1, splitClientMethod m2) of
+  (IsClientNot, IsClientNot) -> do
+    Refl <- geq m1 m2
+    pure HRefl
+  (IsClientReq, IsClientReq) -> do
+    Refl <- geq m1 m2
+    pure HRefl
+  _ -> Nothing
+
+-- | Matches non-custom messages
+message :: SServerMethod m -> Session (ServerMessage m)
+message m1 = named (T.pack $ show m1) $ satisfyMaybe $ \case
+  FromServerMess m2 msg -> do
+    HRefl <- mEq m1 m2
+    pure msg
+  _ -> Nothing
+
+customRequest :: T.Text -> Session (ServerMessage (CustomMethod :: Method FromServer Request))
+customRequest m = named m $ satisfyMaybe $ \case
+  FromServerMess m1 msg -> case splitServerMethod m1 of
+    IsServerEither -> case msg of
+      ReqMess _ | m1 == SCustomMethod m -> Just msg
+      _ -> Nothing
+    _ -> Nothing
+  _ -> Nothing
+
+customNotification :: T.Text -> Session (ServerMessage (CustomMethod :: Method FromServer Notification))
+customNotification m = named m $ satisfyMaybe $ \case
+  FromServerMess m1 msg -> case splitServerMethod m1 of
+    IsServerEither -> case msg of
+      NotMess _ | m1 == SCustomMethod m -> Just msg
+      _ -> Nothing
+    _ -> Nothing
+  _ -> Nothing
 
--- | Matches if the message is a request.
-anyRequest :: Monad m => ConduitParser FromServerMessage m FromServerMessage
-anyRequest = satisfy isServerRequest
+-- | Matches if the message is a notification.
+anyNotification :: Session FromServerMessage
+anyNotification = named "Any notification" $ satisfy $ \case
+  FromServerMess m msg -> case splitServerMethod m of
+    IsServerNot -> True
+    IsServerEither -> case msg of
+      NotMess _ -> True
+      _ -> False
+    _ -> False
+  FromServerRsp _ _ -> False
 
-request :: forall m a b. (Monad m, FromJSON a, FromJSON b) => ConduitParser FromServerMessage m (RequestMessage ServerMethod a b)
-request = do
-  let parser = decode . encodeMsg :: FromServerMessage -> Maybe (RequestMessage ServerMethod a b)
-  x <- satisfy (isJust . parser)
-  return $ fromJust $ decode $ encodeMsg x
+-- | Matches if the message is a request.
+anyRequest :: Session FromServerMessage
+anyRequest = named "Any request" $ satisfy $ \case
+  FromServerMess m _ -> case splitServerMethod m of
+    IsServerReq -> True
+    _ -> False
+  FromServerRsp _ _ -> False
 
 -- | Matches if the message is a response.
-anyResponse :: Monad m => ConduitParser FromServerMessage m FromServerMessage
-anyResponse = satisfy isServerResponse
-
-response :: forall m a. (Monad m, FromJSON a) => ConduitParser FromServerMessage m (ResponseMessage a)
-response = do
-  let parser = decode . encodeMsg :: FromServerMessage -> Maybe (ResponseMessage a)
-  x <- satisfy (isJust . parser)
-  return $ fromJust $ decode $ encodeMsg x
-
--- | A version of encode that encodes FromServerMessages as if they
--- weren't wrapped.
-encodeMsg :: FromServerMessage -> B.ByteString
-encodeMsg = encode . genericToJSON (defaultOptions { sumEncoding = UntaggedValue })
+anyResponse :: Session FromServerMessage
+anyResponse = named "Any response" $ satisfy $ \case
+  FromServerMess _ _ -> False
+  FromServerRsp _ _ -> True
+
+-- | Matches a response for a specific id.
+responseForId :: SMethod (m :: Method FromClient Request) -> LspId m -> Session (ResponseMessage m)
+responseForId m lid = named (T.pack $ "Response for id: " ++ show lid) $ do
+  satisfyMaybe $ \msg -> do
+    case msg of
+      FromServerMess _ _ -> Nothing
+      FromServerRsp m' rspMsg@(ResponseMessage _ lid' _) ->
+        case mEqClient m m' of
+          Just HRefl -> do
+            guard (lid' == Just lid)
+            pure rspMsg
+          Nothing
+            | SCustomMethod tm <- m
+            , SCustomMethod tm' <- m'
+            , tm == tm'
+            , lid' == Just lid -> pure rspMsg
+          _ -> empty
+
+-- | Matches any type of message.
+anyMessage :: Session FromServerMessage
+anyMessage = satisfy (const True)
 
 -- | Matches if the message is a log message notification or a show message notification/request.
-loggingNotification :: Monad m => ConduitParser FromServerMessage m FromServerMessage
-loggingNotification = satisfy shouldSkip
+loggingNotification :: Session FromServerMessage
+loggingNotification = named "Logging notification" $ satisfy shouldSkip
   where
-    shouldSkip (NotLogMessage _) = True
-    shouldSkip (NotShowMessage _) = True
-    shouldSkip (ReqShowMessage _) = True
+    shouldSkip (FromServerMess SWindowLogMessage _) = True
+    shouldSkip (FromServerMess SWindowShowMessage _) = True
+    shouldSkip (FromServerMess SWindowShowMessageRequest _) = True
     shouldSkip _ = False
 
-publishDiagnosticsNotification :: Monad m => ConduitParser FromServerMessage m PublishDiagnosticsNotification
-publishDiagnosticsNotification = do
-  NotPublishDiagnostics diags <- satisfy test
-  return diags
-  where test (NotPublishDiagnostics _) = True
-        test _ = False
-
-satisfy :: Monad m => (a -> Bool) -> ConduitParser a m a
-satisfy pred = do
-  x <- await
-  if pred x
-    then return x
-    else empty
-
-chanSource :: MonadIO m => Chan o -> ConduitT i o m b
-chanSource c = do
-  x <- liftIO $ readChan c
-  yield x
-  chanSource c
-
-runSession' :: Chan FromServerMessage -> SessionContext -> SessionState -> Session a -> IO (a, SessionState)
-runSession' chan context state session = runReaderT (runStateT conduit state) context
-  where conduit = runConduit $ chanSource chan .| runConduitParser session
-
-get :: Monad m => ParserStateReader a s r m s
-get = lift Control.Monad.Trans.State.get
-
-put :: Monad m => s -> ParserStateReader a s r m ()
-put = lift . Control.Monad.Trans.State.put
-
-modify :: Monad m => (s -> s) -> ParserStateReader a s r m ()
-modify = lift . Control.Monad.Trans.State.modify
-
-ask :: Monad m => ParserStateReader a s r m r
-ask = lift $ lift Control.Monad.Trans.Reader.ask
+-- | Matches a 'Language.Haskell.LSP.Test.PublishDiagnosticsNotification'
+-- (textDocument/publishDiagnostics) notification.
+publishDiagnosticsNotification :: Session PublishDiagnosticsNotification
+publishDiagnosticsNotification = named "Publish diagnostics notification" $
+  satisfyMaybe $ \msg -> case msg of
+    FromServerMess STextDocumentPublishDiagnostics diags -> Just diags
+    _ -> Nothing