pbrfrag.glsl

   1 #version 330
   2
   3 #define mdot(x, y) (max(dot(x, y), 0.f))
   4
   5 in vec3 worldPos, normal;
   6 in vec2 texCoords;
   7
   8 uniform vec3 camPos;
   9
  10 uniform sampler2D albedoMap;
  11 uniform sampler2D normalMap;
  12 uniform sampler2D metallicMap;
  13 uniform sampler2D roughnessMap;
  14 uniform sampler2D aoMap;
  15 uniform samplerCube irradianceMap;
  16
  17 out vec4 fragColor;
  18
  19 uniform vec3 lightPositions[4];
  20 uniform vec3 lightColors[4];
  21
  22 const float PI = 3.14159265359;
  23
  24 vec3 fresnelSchlick(float cosTheta, vec3 F0) {
  25         return F0 + (1.f - F0) * pow(1.f - cosTheta, 5.f);
  26 }
  27
  28 vec3 fresnelSchlickRoughness(float cosTheta, vec3 F0, float roughness) {
  29         return F0 + (max(vec3(1.f - roughness), F0) - F0) * pow(1.f - cosTheta, 5.f);
  30 }
  31
  32 float distributionGGX(vec3 N, vec3 H, float roughness) {
  33         float a = roughness * roughness;
  34         float NdotH = mdot(N, H);
  35         float denom = (NdotH * NdotH) * ((a * a) - 1.f) + 1.f;
  36         denom = PI * denom * denom;
  37         return (a * a) / denom;
  38 }
  39
  40 float geometrySchlickGGX(float NdotV, float roughness) {
  41         float r = roughness + 1.f;
  42         float k = (r * r) / 8.f;
  43         return NdotV / (NdotV * (1.f - k) + k);
  44 }
  45
  46 float geometrySmith(vec3 N, vec3 V, vec3 L, float roughness) {
  47         float ggx1 = geometrySchlickGGX(mdot(N, L), roughness);
  48         float ggx2 = geometrySchlickGGX(mdot(N, V), roughness);
  49         return ggx1 * ggx2;
  50 }
  51
  52 vec3 getNormalFromMap() {
  53         vec3 tangentNormal = texture(normalMap, texCoords).xyz * 2.f - 1.f;
  54         vec3 Q1 = dFdx(worldPos);
  55     vec3 Q2 = dFdy(worldPos);
  56     vec2 st1 = dFdx(texCoords);
  57     vec2 st2 = dFdy(texCoords);
  58
  59     vec3 N = normalize(normal);
  60     vec3 T = normalize(Q1 * st2.t - Q2 * st1.t);
  61     vec3 B = -normalize(cross(N, T));
  62     mat3 TBN = mat3(T, B, N);
  63
  64     return normalize(TBN * tangentNormal);
  65 }
  66
  67 void main() {
  68         vec3 albedo = pow(texture(albedoMap, texCoords).rgb, vec3(2.2));
  69         vec3 normal = getNormalFromMap();
  70         float metallic = texture(metallicMap, texCoords).r;
  71         float roughness = texture(roughnessMap, texCoords).r;
  72         float ao = texture(aoMap, texCoords).r;
  73
  74         vec3 N = normalize(normal);
  75         vec3 V = normalize(camPos - worldPos);
  76
  77         vec3 F0 = mix(vec3(0.04), albedo, metallic);
  78
  79         // reflectance
  80         vec3 Lo = vec3(0.f);
  81         for (int i = 0; i < lightPositions.length(); i++) {
  82                 vec3 L = normalize(lightPositions[i] - worldPos);
  83                 vec3 H = normalize(V + L);
  84
  85                 // calculate radiance
  86                 float dist = length(lightPositions[i] - worldPos);
  87                 float attenuation = 5.f / (dist * dist);
  88                 vec3 radiance = lightColors[i] * attenuation;
  89
  90                 // cook-torrance brdf
  91                 vec3 F = fresnelSchlick(mdot(H, V), F0);
  92                 float NDF = distributionGGX(N, H, roughness);
  93                 float G = geometrySmith(N, V, L, roughness);
  94
  95                 float denom = 4.f * mdot(N, V) * mdot(N, L);
  96                 vec3 specular = (NDF * G * F) / max(denom, 0.0000001);
  97
  98                 vec3 kS = F; // fresnel = reflection ratio
  99                 vec3 kD = vec3(1.f) - kS;
 100                 kD *= 1.f - metallic;
 101
 102                 Lo += (kD * albedo / PI + specular) * radiance * mdot(N, L);
 103         }
 104
 105         vec3 kD = 1.f - fresnelSchlickRoughness(mdot(N, V), F0, roughness);
 106         vec3 diffuse = texture(irradianceMap, N).rgb * albedo;
 107         vec3 ambient = (kD * diffuse) * ao;
 108         vec3 color = ambient + Lo;
 109
 110         color = color / (color + vec3(1.f)); // map to HDR
 111         color = pow(color, vec3(1.f / 2.2)); // gamma correction
 112
 113         fragColor = vec4(color, 1.f);
 114 }